lib/librarian/book2html.xslt

   1 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   2     xmlns:wl="http://wolnelektury.pl/functions" >
   3
   4 <xsl:output method="xml" encoding="utf-8" doctype-public="-//W3C//DTD XHTML 1.1//EN" doctype-system="http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd" indent="yes" />
   5
   6 <xsl:template match="text()" />
   7 <xsl:template match="text()" mode="inline">
   8     <xsl:value-of select="wl:substitute_entities(.)" />
   9 </xsl:template>
  10
  11 <xsl:template match="extra|uwaga" />
  12 <xsl:template match="extra|uwaga" mode="inline" />
  13
  14 <xsl:template match="utwor">
  15     <html>
  16         <head>
  17             <title>book2html output</title>
  18             <meta http-equiv="content-type" content="text/html;charset=utf-8"/>
  19             <link rel="stylesheet" href="master.css" type="text/css" media="all" charset="utf-8" />
  20         </head>
  21         <body>
  22             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  23             <xsl:if test="count(descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)])">
  24                 <div id="footnotes">
  25                     <h3>Przypisy</h3>
  26                     <xsl:for-each select="descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)]">
  27                         <div>
  28                             <a name="{concat('footnote-', generate-id(.))}" />
  29                             <a href="{concat('#anchor-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
  30                             <xsl:choose>
  31                                 <xsl:when test="count(akap|akap_cd|strofa) = 0">
  32                                     <p><xsl:apply-templates select="text()|*" mode="inline" /></p>
  33                                 </xsl:when>
  34                                 <xsl:otherwise>
  35                                     <xsl:apply-templates select="text()|*" mode="inline" />
  36                                 </xsl:otherwise>
  37                             </xsl:choose>
  38                         </div>
  39                     </xsl:for-each>
  40                 </div>
  41             </xsl:if>
  42         </body>
  43     </html>
  44 </xsl:template>
  45
  46
  47 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny">
  48     <xsl:if test="nazwa_utworu">
  49         <h1>
  50             <xsl:apply-templates select="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul" mode="header" />
  51         </h1>
  52     </xsl:if>
  53     <xsl:apply-templates />
  54 </xsl:template>
  55
  56 <!-- ======================= -->
  57 <!-- = Header (title page) = -->
  58 <!-- ======================= -->
  59 <xsl:template match="autor_utworu" mode="header">
  60     <span class="author"><xsl:apply-templates mode="inline" /></span>
  61 </xsl:template>
  62
  63 <xsl:template match="nazwa_utworu" mode="header">
  64     <span class="title"><xsl:apply-templates mode="inline" /></span>
  65 </xsl:template>
  66
  67 <xsl:template match="dzielo_nadrzedne" mode="header">
  68     <span class="collection"><xsl:apply-templates mode="inline" /></span>
  69 </xsl:template>
  70
  71 <xsl:template match="podtytul" mode="header">
  72     <span class="subtitle"><xsl:apply-templates mode="inline" /></span>
  73 </xsl:template>
  74
  75 <xsl:template match="nota">
  76     <div class="note"><xsl:apply-templates /></div>
  77 </xsl:template>
  78
  79 <xsl:template match="dedykacja">
  80     <div class="dedication"><xsl:apply-templates /></div>
  81 </xsl:template>
  82
  83 <!-- =================== -->
  84 <!-- = Section headers = -->
  85 <!-- =================== -->
  86 <xsl:template match="naglowek_akt|naglowek_czesc|srodtytul">
  87     <h2><xsl:apply-templates mode="inline" /></h2>
  88 </xsl:template>
  89
  90 <xsl:template match="naglowek_scena|naglowek_rozdzial">
  91     <h3><xsl:apply-templates mode="inline" /></h3>
  92 </xsl:template>
  93
  94 <xsl:template match="naglowek_osoba|naglowek_podrozdzial">
  95     <h4><xsl:apply-templates mode="inline" /></h4>
  96 </xsl:template>
  97
  98 <xsl:template match="miejsce_czas">
  99     <p class="place-and-time"><xsl:apply-templates mode="inline" /></p>
 100 </xsl:template>
 101
 102 <xsl:template match="kwestia">
 103     <div class="kwestia">
 104         <xsl:apply-templates select="strofa|akap" />
 105     </div>
 106 </xsl:template>
 107
 108 <xsl:template match="didaskalia">
 109     <div class="didaskalia"><xsl:apply-templates mode="inline" /></div>
 110 </xsl:template>
 111
 112 <xsl:template match="lista_osob">
 113     <div class="person-list">
 114         <h3><xsl:value-of select="naglowek_listy" /></h3>
 115         <ol>
 116             <xsl:apply-templates select="lista_osoba" />
 117         </ol>
 118     </div>
 119 </xsl:template>
 120
 121 <xsl:template match="lista_osoba">
 122     <li><xsl:apply-templates mode="inline" /></li>
 123 </xsl:template>
 124
 125 <xsl:template match="begin" mode="inline">
 126     <xsl:variable name="mnum" select="concat('m', substring(@id, 2))" />
 127     <span class="theme-begin" fid="{substring(@id, 2)}">
 128         <xsl:value-of select="string(following::motyw[@id=$mnum]/text())" />
 129     </span>
 130 </xsl:template>
 131
 132 <xsl:template match="end" mode="inline">
 133     <span class="theme-end" fid="{substring(@id, 2)}"> </span>
 134 </xsl:template>
 135
 136 <xsl:template match="begin|end">
 137     <xsl:apply-templates select='.' mode="inline" />
 138 </xsl:template>
 139
 140 <xsl:template name="verse">
 141     <xsl:param name="line-content" />
 142     <xsl:param name="line-number" />
 143     <p>
 144         <xsl:choose>
 145             <xsl:when test="name($line-content) = 'wers_akap'">
 146                 <xsl:attribute name="style">indent: 1em</xsl:attribute>
 147             </xsl:when>
 148             <xsl:when test="name($line-content) = 'wers_wciety'">
 149                 <xsl:attribute name="style">indent: 2em</xsl:attribute>
 150             </xsl:when>
 151         </xsl:choose>
 152         <xsl:apply-templates select="$line-content" mode="inline" />
 153     </p>
 154 </xsl:template>
 155
 156 <xsl:template match="pa|pe|pr|pt" mode="inline">
 157     <a name="{concat('anchor-', generate-id(.))}" />
 158     <a href="{concat('#footnote-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
 159 </xsl:template>
 160
 161 <xsl:template match="strofa">
 162     <div class="stanza">
 163         <xsl:choose>
 164             <xsl:when test="count(br) > 0">
 165                 <xsl:call-template name="verse">
 166                     <xsl:with-param name="line-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 167                     <xsl:with-param name="line-number" select="1" />
 168                 </xsl:call-template>
 169                 <xsl:for-each select="br">
 170                                 <!-- Każdy BR "zjada" to co jest za nim -->
 171                     <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 172                     <xsl:call-template name="verse">
 173                         <xsl:with-param name="line-number" select="$lnum+2" />
 174                         <xsl:with-param name="line-content"
 175                             select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 176                     </xsl:call-template>
 177                 </xsl:for-each>
 178             </xsl:when>
 179             <xsl:otherwise>
 180                 <xsl:call-template name="verse">
 181                     <xsl:with-param name="line-content" select="text() | node()" />
 182                     <xsl:with-param name="line-number" select="1" />
 183                  </xsl:call-template>
 184             </xsl:otherwise>
 185         </xsl:choose>
 186     </div>
 187 </xsl:template>
 188
 189 <xsl:template match="akap|akap_dialog|akap_cd">
 190     <p class="paragraph"><xsl:apply-templates mode="inline" /></p>
 191 </xsl:template>
 192
 193 <xsl:template match="motyw" mode="inline" />
 194
 195 <xsl:template match="dlugi_cytat">
 196     <blockquote><xsl:apply-templates /></blockquote>
 197 </xsl:template>
 198
 199 <xsl:template match="motto">
 200     <p class="motto"><xsl:apply-templates mode="inline" /></p>
 201 </xsl:template>
 202
 203 <xsl:template match="motto_podpis">
 204     <p class="motto_podpis"><xsl:apply-templates mode="inline" /></p>
 205 </xsl:template>
 206
 207 <xsl:template match="sekcja_swiatlo">
 208     <hr class="spacer" />
 209 </xsl:template>
 210
 211 </xsl:stylesheet>