librarian/xslt/book2html.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/" >
  11
  12 <xsl:output encoding="utf-8" indent="yes" omit-xml-declaration = "yes" version="2.0" />
  13 <xsl:strip-space  elements="opowiadanie powiesc dramat_wierszowany_l dramat_wierszowany_lp dramat_wspolczesny liryka_l liryka_lp wywiad"/>
  14 <xsl:template match="utwor">
  15     <xsl:choose>
  16         <xsl:when test="@full-page">
  17             <html>
  18             <head>
  19                 <title>Książka z serwisu WolneLektury.pl</title>
  20                 <meta charset="utf-8" />
  21                 <meta name="viewport" content="width=device-width, initial-scale=1, maximum-scale=1" />
  22                 <link href="https://static.wolnelektury.pl/css/compressed/book_text.css" rel="stylesheet" type="text/css" />
  23             </head>
  24             <body>
  25                 <xsl:call-template name="book-text" />
  26             </body>
  27             </html>
  28         </xsl:when>
  29         <xsl:otherwise>
  30             <xsl:call-template name="book-text" />
  31         </xsl:otherwise>
  32     </xsl:choose>
  33 </xsl:template>
  34
  35 <xsl:template name="book-text">
  36     <div id="book-text">
  37         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  38         <xsl:if test="count(descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)])">
  39             <div id="footnotes">
  40                 <h3>Przypisy</h3>
  41                 <xsl:for-each select="descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)]">
  42                     <div>
  43                         <a name="{concat('footnote-', generate-id(.))}" />
  44                         <a href="{concat('#anchor-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
  45                         <xsl:choose>
  46                             <xsl:when test="count(akap|akap_cd|strofa) = 0">
  47                                 <p><xsl:apply-templates select="text()|*" mode="inline" />
  48                                 <xsl:if test="name()='pa'"> [przypis autorski]</xsl:if>
  49                                 </p>
  50                             </xsl:when>
  51                             <xsl:otherwise>
  52                                 <xsl:apply-templates select="text()|*" mode="inline" />
  53                             </xsl:otherwise>
  54                         </xsl:choose>
  55                     </div>
  56                 </xsl:for-each>
  57             </div>
  58         </xsl:if>
  59     </div>
  60 </xsl:template>
  61
  62
  63 <!-- ============================================================================== -->
  64 <!-- = MASTER TAG                                                                 = -->
  65 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
  66 <!-- ============================================================================== -->
  67 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny">
  68     <xsl:apply-templates select="nota_red" mode="special" />
  69     <xsl:if test="nazwa_utworu">
  70         <h1>
  71             <xsl:apply-templates select="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul" mode="header" />
  72             <xsl:call-template name="translators" />
  73         </h1>
  74     </xsl:if>
  75     <xsl:apply-templates />
  76 </xsl:template>
  77
  78
  79 <!-- ==================================================================================== -->
  80 <!-- = BLOCK TAGS                                                                       = -->
  81 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
  82 <!-- ==================================================================================== -->
  83 <xsl:template match="nota">
  84     <div class="note"><xsl:apply-templates /></div>
  85 </xsl:template>
  86
  87 <xsl:template match="lista_osob">
  88     <div class="person-list">
  89         <h3><xsl:value-of select="naglowek_listy" /></h3>
  90         <ol>
  91             <xsl:apply-templates select="lista_osoba" />
  92         </ol>
  93     </div>
  94 </xsl:template>
  95
  96 <xsl:template match="dedykacja">
  97     <div class="dedication"><xsl:apply-templates /></div>
  98 </xsl:template>
  99
 100 <xsl:template match="kwestia">
 101     <div class="kwestia">
 102         <xsl:apply-templates select="strofa|akap|didaskalia" />
 103     </div>
 104 </xsl:template>
 105
 106 <xsl:template match="dlugi_cytat|poezja_cyt">
 107     <blockquote><xsl:apply-templates /></blockquote>
 108 </xsl:template>
 109
 110 <xsl:template match="motto">
 111     <div class="motto"><xsl:apply-templates /></div>
 112 </xsl:template>
 113
 114
 115 <!-- ========================================== -->
 116 <!-- = PARAGRAPH TAGS                         = -->
 117 <!-- = (can contain inline and special tags)  = -->
 118 <!-- ========================================== -->
 119 <!-- Title page -->
 120 <xsl:template match="autor_utworu" mode="header">
 121     <span class="author"><xsl:apply-templates mode="inline" /></span>
 122 </xsl:template>
 123
 124 <xsl:template match="nazwa_utworu" mode="header">
 125     <span class="title"><xsl:apply-templates mode="inline" /></span>
 126 </xsl:template>
 127
 128 <xsl:template match="dzielo_nadrzedne" mode="header">
 129     <span class="collection"><xsl:apply-templates mode="inline" /></span>
 130 </xsl:template>
 131
 132 <xsl:template match="podtytul" mode="header">
 133     <span class="subtitle"><xsl:apply-templates mode="inline" /></span>
 134 </xsl:template>
 135
 136 <!-- Section headers (included in index)-->
 137 <xsl:template match="naglowek_akt|naglowek_czesc|srodtytul">
 138   <xsl:call-template name="section-anchor"/>
 139     <h2><xsl:apply-templates mode="inline" /></h2>
 140 </xsl:template>
 141
 142 <xsl:template match="naglowek_scena|naglowek_rozdzial">
 143     <xsl:call-template name="section-anchor"/>
 144     <h3><xsl:apply-templates mode="inline" /></h3>
 145 </xsl:template>
 146
 147 <xsl:template match="naglowek_osoba|naglowek_podrozdzial">
 148       <xsl:call-template name="section-anchor"/>
 149     <h4><xsl:apply-templates mode="inline" /></h4>
 150 </xsl:template>
 151
 152 <!-- Other paragraph tags -->
 153 <xsl:template match="miejsce_czas">
 154       <xsl:call-template name="section-anchor"/>
 155     <p class="place-and-time"><xsl:apply-templates mode="inline" /></p>
 156 </xsl:template>
 157
 158 <xsl:template match="didaskalia">
 159       <xsl:call-template name="section-anchor"/>
 160     <div class="didaskalia"><xsl:apply-templates mode="inline" /></div>
 161 </xsl:template>
 162
 163 <xsl:template match="lista_osoba">
 164     <li><xsl:apply-templates mode="inline" /></li>
 165 </xsl:template>
 166
 167 <xsl:template match="akap|akap_dialog|akap_cd">
 168     <p class="paragraph">
 169       <xsl:call-template name="section-anchor"/>
 170         <xsl:apply-templates mode="inline" />
 171     </p>
 172 </xsl:template>
 173
 174 <xsl:template match="strofa">
 175     <div class="stanza">
 176       <xsl:call-template name="section-anchor"/>
 177         <xsl:choose>
 178             <xsl:when test="count(br) > 0">
 179                 <xsl:call-template name="verse">
 180                     <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 181                     <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd'][1]" />
 182                 </xsl:call-template>
 183                 <xsl:for-each select="br">
 184                                 <!-- Each BR tag "consumes" text after it -->
 185                     <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 186                     <xsl:call-template name="verse">
 187                         <xsl:with-param name="verse-content"
 188                             select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 189                         <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd')][1]" />
 190                     </xsl:call-template>
 191                 </xsl:for-each>
 192             </xsl:when>
 193             <xsl:otherwise>
 194                 <xsl:call-template name="verse">
 195                     <xsl:with-param name="verse-content" select="text() | node()" />
 196                     <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd[1]" />
 197                  </xsl:call-template>
 198             </xsl:otherwise>
 199         </xsl:choose>
 200     </div>
 201 </xsl:template>
 202
 203 <xsl:template name="verse">
 204     <xsl:param name="verse-content" />
 205     <xsl:param name="verse-type" />
 206     <p class="verse">
 207         <xsl:choose>
 208             <xsl:when test="name($verse-type) = 'wers_akap'">
 209                 <xsl:attribute name="style">padding-left: 1em</xsl:attribute>
 210             </xsl:when>
 211             <xsl:when test="name($verse-type) = 'wers_wciety'">
 212                 <xsl:choose>
 213                     <xsl:when test="$verse-content/@typ">
 214                         <xsl:attribute name="style">padding-left: <xsl:value-of select="$verse-content/@typ" />em</xsl:attribute>
 215                     </xsl:when>
 216                     <xsl:otherwise>
 217                         <xsl:attribute name="style">padding-left: 1em</xsl:attribute>
 218                     </xsl:otherwise>
 219                 </xsl:choose>
 220             </xsl:when>
 221             <xsl:when test="name($verse-type) = 'wers_cd'">
 222                 <xsl:attribute name="style">padding-left: 12em</xsl:attribute>
 223             </xsl:when>
 224         </xsl:choose>
 225         <xsl:apply-templates select="$verse-content" mode="inline" />
 226     </p>
 227 </xsl:template>
 228
 229 <xsl:template match="motto_podpis">
 230     <p class="motto_podpis"><xsl:apply-templates mode="inline" /></p>
 231 </xsl:template>
 232
 233
 234 <!-- ================================================ -->
 235 <!-- = INLINE TAGS                                  = -->
 236 <!-- = (contain other inline tags and special tags) = -->
 237 <!-- ================================================ -->
 238 <!-- Annotations -->
 239 <xsl:template match="pa|pe|pr|pt" mode="inline">
 240     <a name="{concat('anchor-', generate-id(.))}" />
 241     <a href="{concat('#footnote-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
 242 </xsl:template>
 243
 244 <!-- Other inline tags -->
 245 <xsl:template match="mat" mode="inline">
 246     <em class="math"><xsl:apply-templates mode="inline" /></em>
 247 </xsl:template>
 248
 249 <xsl:template match="didask_tekst" mode="inline">
 250     <em class="didaskalia"><xsl:apply-templates mode="inline" /></em>
 251 </xsl:template>
 252
 253 <xsl:template match="slowo_obce" mode="inline">
 254     <em class="foreign-word"><xsl:apply-templates mode="inline" /></em>
 255 </xsl:template>
 256
 257 <xsl:template match="tytul_dziela" mode="inline">
 258     <em class="book-title">
 259         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 260     </em>
 261 </xsl:template>
 262
 263 <xsl:template match="wyroznienie" mode="inline">
 264     <em class="author-emphasis"><xsl:apply-templates mode="inline" /></em>
 265 </xsl:template>
 266
 267 <xsl:template match="osoba" mode="inline">
 268     <em class="person"><xsl:apply-templates mode="inline" /></em>
 269 </xsl:template>
 270
 271
 272 <!-- ============================================== -->
 273 <!-- = STANDALONE TAGS                            = -->
 274 <!-- = (cannot contain any other tags)            = -->
 275 <!-- ============================================== -->
 276 <xsl:template match="sekcja_swiatlo">
 277     <hr class="spacer" />
 278 </xsl:template>
 279
 280 <xsl:template match="sekcja_asterysk">
 281     <p class="spacer-asterisk">*</p>
 282 </xsl:template>
 283
 284 <xsl:template match="separator_linia">
 285     <hr class="spacer-line" />
 286 </xsl:template>
 287
 288
 289 <!-- ================ -->
 290 <!-- = SPECIAL TAGS = -->
 291 <!-- ================ -->
 292 <!-- Themes -->
 293 <xsl:template match="begin" mode="inline">
 294     <xsl:variable name="mnum" select="concat('m', substring(@id, 2))" />
 295     <a name="m{substring(@id, 2)}" class="theme-begin" fid="{substring(@id, 2)}">
 296         <xsl:value-of select="string(following::motyw[@id=$mnum]/text())" />
 297     </a>
 298 </xsl:template>
 299
 300 <xsl:template match="end" mode="inline">
 301     <span class="theme-end" fid="{substring(@id, 2)}"> </span>
 302 </xsl:template>
 303
 304 <xsl:template match="begin|end">
 305     <xsl:apply-templates select='.' mode="inline" />
 306 </xsl:template>
 307
 308 <xsl:template match="motyw" mode="inline" />
 309
 310
 311 <xsl:template match="nota_red" mode="special">
 312     <div id="nota_red">
 313         <xsl:apply-templates />
 314     </div>
 315 </xsl:template>
 316
 317
 318 <xsl:template name="translators">
 319     <xsl:if test="//dc:contributor.translator">
 320         <span class="translator">
 321             <xsl:text>tłum. </xsl:text>
 322             <xsl:for-each select="//dc:contributor.translator">
 323                 <xsl:if test="position() != 1">, </xsl:if>
 324                 <xsl:apply-templates mode="person" />
 325             </xsl:for-each>
 326         </span>
 327     </xsl:if>
 328 </xsl:template>
 329
 330 <xsl:template match="text()" mode="person">
 331     <xsl:value-of select="wl:person_name(.)" />
 332 </xsl:template>
 333
 334
 335 <!-- ================ -->
 336 <!-- = IGNORED TAGS = -->
 337 <!-- ================ -->
 338 <xsl:template match="extra|uwaga" />
 339 <xsl:template match="extra|uwaga" mode="inline" />
 340
 341 <xsl:template match="nota_red" />
 342
 343 <!-- ======== -->
 344 <!-- = TEXT = -->
 345 <!-- ======== -->
 346 <xsl:template match="text()" />
 347 <xsl:template match="text()" mode="inline">
 348     <xsl:value-of select="wl:substitute_entities(.)" />
 349 </xsl:template>
 350
 351 <!-- ========= -->
 352 <!-- = utils = -->
 353 <!-- ========= -->
 354 <xsl:template name="section-anchor">
 355   <!--
 356        this formula works as follows:
 357        - get all ancestors including self
 358        - choose the header (third one from root): utwor/book-type/header
 359        - get all preceding siblings
 360        - count them
 361        - create an <a name="sec123"/> tag.
 362   -->
 363         <a name="{concat('sec', count(ancestor-or-self::*[last()-2]/preceding-sibling::*) + 1)}" />
 364 </xsl:template>
 365
 366 </xsl:stylesheet>