librarian/xslt/book2html.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/" >
  11
  12 <xsl:output encoding="utf-8" indent="yes" omit-xml-declaration = "yes" version="2.0" />
  13 <xsl:strip-space  elements="opowiadanie powiesc dramat_wierszowany_l dramat_wierszowany_lp dramat_wspolczesny liryka_l liryka_lp wywiad"/>
  14 <xsl:template match="utwor">
  15     <xsl:choose>
  16         <xsl:when test="@full-page">
  17             <html>
  18             <head>
  19                 <title>Książka z serwisu WolneLektury.pl</title>
  20                 <meta charset="utf-8" />
  21                 <meta name="viewport" content="width=device-width, initial-scale=1, maximum-scale=1" />
  22                 <link href="https://static.wolnelektury.pl/css/compressed/book_text.css" rel="stylesheet" type="text/css" />
  23             </head>
  24             <body>
  25                 <xsl:call-template name="book-text" />
  26             </body>
  27             </html>
  28         </xsl:when>
  29         <xsl:otherwise>
  30             <xsl:call-template name="book-text" />
  31         </xsl:otherwise>
  32     </xsl:choose>
  33 </xsl:template>
  34
  35 <xsl:template name="book-text">
  36     <div id="book-text">
  37         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  38         <xsl:if test="count(descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)])">
  39             <div id="footnotes">
  40                 <h3>Przypisy</h3>
  41                 <xsl:for-each select="descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)]">
  42                     <div>
  43                         <xsl:attribute name="class">fn-<xsl:value-of select="name()" /></xsl:attribute>
  44                         <a name="{concat('footnote-', generate-id(.))}" />
  45                         <a href="{concat('#anchor-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
  46                         <xsl:choose>
  47                             <xsl:when test="count(akap|akap_cd|strofa) = 0">
  48                                 <p><xsl:apply-templates select="text()|*" mode="inline" />
  49                                 <xsl:if test="name()='pa'"> [przypis autorski]</xsl:if>
  50                                 <xsl:if test="name()='pt'"> [przypis tłumacza]</xsl:if>
  51                                 <xsl:if test="name()='pr'"> [przypis redakcyjny]</xsl:if>
  52                                 <xsl:if test="name()='pe'"> [przypis edytorski]</xsl:if>
  53                                 </p>
  54                             </xsl:when>
  55                             <xsl:otherwise>
  56                                 <xsl:apply-templates select="text()|*" mode="inline" />
  57                             </xsl:otherwise>
  58                         </xsl:choose>
  59                     </div>
  60                 </xsl:for-each>
  61             </div>
  62         </xsl:if>
  63     </div>
  64 </xsl:template>
  65
  66
  67 <!-- ============================================================================== -->
  68 <!-- = MASTER TAG                                                                 = -->
  69 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
  70 <!-- ============================================================================== -->
  71 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny">
  72     <xsl:apply-templates select="nota_red" mode="special" />
  73     <xsl:if test="nazwa_utworu">
  74         <h1>
  75             <xsl:apply-templates select="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul" mode="header" />
  76             <xsl:call-template name="translators" />
  77         </h1>
  78     </xsl:if>
  79     <xsl:apply-templates />
  80 </xsl:template>
  81
  82
  83 <!-- ==================================================================================== -->
  84 <!-- = BLOCK TAGS                                                                       = -->
  85 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
  86 <!-- ==================================================================================== -->
  87 <xsl:template match="nota">
  88     <div class="note"><xsl:apply-templates /></div>
  89 </xsl:template>
  90
  91 <xsl:template match="lista_osob">
  92     <div class="person-list">
  93         <h3><xsl:value-of select="naglowek_listy" /></h3>
  94         <ol>
  95             <xsl:apply-templates select="lista_osoba" />
  96         </ol>
  97     </div>
  98 </xsl:template>
  99
 100 <xsl:template match="dedykacja">
 101     <div class="dedication"><xsl:apply-templates /></div>
 102 </xsl:template>
 103
 104 <xsl:template match="kwestia">
 105     <div class="kwestia">
 106         <xsl:apply-templates select="strofa|akap|didaskalia" />
 107     </div>
 108 </xsl:template>
 109
 110 <xsl:template match="dlugi_cytat|poezja_cyt">
 111     <blockquote><xsl:apply-templates /></blockquote>
 112 </xsl:template>
 113
 114 <xsl:template match="motto">
 115     <div class="motto"><xsl:apply-templates /></div>
 116 </xsl:template>
 117
 118 <xsl:template match="ilustr" mode="inline">
 119     <xsl:apply-templates select="."/>
 120 </xsl:template>
 121
 122 <xsl:template match="ilustr">
 123     <img>
 124         <xsl:attribute name="src">
 125             <xsl:value-of select="$gallery" /><xsl:value-of select="@src" />
 126         </xsl:attribute>
 127         <xsl:attribute name="alt">
 128             <xsl:value-of select="@alt" />
 129         </xsl:attribute>
 130         <xsl:attribute name="title">
 131             <xsl:value-of select="@alt" />
 132         </xsl:attribute>
 133     </img>
 134 </xsl:template>
 135
 136
 137 <!-- ========================================== -->
 138 <!-- = PARAGRAPH TAGS                         = -->
 139 <!-- = (can contain inline and special tags)  = -->
 140 <!-- ========================================== -->
 141 <!-- Title page -->
 142 <xsl:template match="autor_utworu" mode="header">
 143     <span class="author"><xsl:apply-templates mode="inline" /></span>
 144 </xsl:template>
 145
 146 <xsl:template match="nazwa_utworu" mode="header">
 147     <span class="title"><xsl:apply-templates mode="inline" /></span>
 148 </xsl:template>
 149
 150 <xsl:template match="dzielo_nadrzedne" mode="header">
 151     <span class="collection"><xsl:apply-templates mode="inline" /></span>
 152 </xsl:template>
 153
 154 <xsl:template match="podtytul" mode="header">
 155     <span class="subtitle"><xsl:apply-templates mode="inline" /></span>
 156 </xsl:template>
 157
 158 <!-- Section headers (included in index)-->
 159 <xsl:template match="naglowek_akt|naglowek_czesc|srodtytul">
 160   <xsl:call-template name="section-anchor"/>
 161     <h2><xsl:apply-templates mode="inline" /></h2>
 162 </xsl:template>
 163
 164 <xsl:template match="naglowek_scena|naglowek_rozdzial">
 165     <xsl:call-template name="section-anchor"/>
 166     <h3><xsl:apply-templates mode="inline" /></h3>
 167 </xsl:template>
 168
 169 <xsl:template match="naglowek_osoba|naglowek_podrozdzial">
 170       <xsl:call-template name="section-anchor"/>
 171     <h4><xsl:apply-templates mode="inline" /></h4>
 172 </xsl:template>
 173
 174 <!-- Other paragraph tags -->
 175 <xsl:template match="miejsce_czas">
 176       <xsl:call-template name="section-anchor"/>
 177     <p class="place-and-time"><xsl:apply-templates mode="inline" /></p>
 178 </xsl:template>
 179
 180 <xsl:template match="didaskalia">
 181       <xsl:call-template name="section-anchor"/>
 182     <div class="didaskalia"><xsl:apply-templates mode="inline" /></div>
 183 </xsl:template>
 184
 185 <xsl:template match="lista_osoba">
 186     <li><xsl:apply-templates mode="inline" /></li>
 187 </xsl:template>
 188
 189 <xsl:template match="akap|akap_dialog|akap_cd">
 190     <p class="paragraph">
 191       <xsl:call-template name="section-anchor"/>
 192         <xsl:apply-templates mode="inline" />
 193     </p>
 194 </xsl:template>
 195
 196 <xsl:template match="strofa">
 197     <div class="stanza">
 198       <xsl:call-template name="section-anchor"/>
 199         <xsl:choose>
 200             <xsl:when test="count(br) > 0">
 201                 <xsl:call-template name="verse">
 202                     <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 203                     <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd'][1]" />
 204                 </xsl:call-template>
 205                 <xsl:for-each select="br">
 206                                 <!-- Each BR tag "consumes" text after it -->
 207                     <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 208                     <xsl:call-template name="verse">
 209                         <xsl:with-param name="verse-content"
 210                             select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 211                         <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd')][1]" />
 212                     </xsl:call-template>
 213                 </xsl:for-each>
 214             </xsl:when>
 215             <xsl:otherwise>
 216                 <xsl:call-template name="verse">
 217                     <xsl:with-param name="verse-content" select="text() | node()" />
 218                     <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd[1]" />
 219                  </xsl:call-template>
 220             </xsl:otherwise>
 221         </xsl:choose>
 222     </div>
 223 </xsl:template>
 224
 225 <xsl:template name="verse">
 226     <xsl:param name="verse-content" />
 227     <xsl:param name="verse-type" />
 228     <p class="verse">
 229         <xsl:choose>
 230             <xsl:when test="name($verse-type) = 'wers_akap'">
 231                 <xsl:attribute name="style">padding-left: 1em</xsl:attribute>
 232             </xsl:when>
 233             <xsl:when test="name($verse-type) = 'wers_wciety'">
 234                 <xsl:choose>
 235                     <xsl:when test="$verse-content/@typ">
 236                         <xsl:attribute name="style">padding-left: <xsl:value-of select="$verse-content/@typ" />em</xsl:attribute>
 237                     </xsl:when>
 238                     <xsl:otherwise>
 239                         <xsl:attribute name="style">padding-left: 1em</xsl:attribute>
 240                     </xsl:otherwise>
 241                 </xsl:choose>
 242             </xsl:when>
 243             <xsl:when test="name($verse-type) = 'wers_cd'">
 244                 <xsl:attribute name="style">padding-left: 12em</xsl:attribute>
 245             </xsl:when>
 246         </xsl:choose>
 247         <xsl:apply-templates select="$verse-content" mode="inline" />
 248     </p>
 249 </xsl:template>
 250
 251 <xsl:template match="motto_podpis">
 252     <p class="motto_podpis"><xsl:apply-templates mode="inline" /></p>
 253 </xsl:template>
 254
 255 <xsl:template match="tabela|tabelka">
 256     <table><xsl:apply-templates /></table>
 257 </xsl:template>
 258 <xsl:template match="wiersz">
 259     <tr><xsl:apply-templates /></tr>
 260 </xsl:template>
 261 <xsl:template match="kol">
 262     <td><xsl:apply-templates mode="inline" /></td>
 263 </xsl:template>
 264
 265 <xsl:template match="mat">
 266     <math xmlns="http://www.w3.org/1998/Math/MathML"><xsl:copy-of select="*" /></math>
 267 </xsl:template>
 268
 269
 270 <!-- ================================================ -->
 271 <!-- = INLINE TAGS                                  = -->
 272 <!-- = (contain other inline tags and special tags) = -->
 273 <!-- ================================================ -->
 274 <!-- Annotations -->
 275 <xsl:template match="pa|pe|pr|pt" mode="inline">
 276     <a name="{concat('anchor-', generate-id(.))}" />
 277     <a href="{concat('#footnote-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
 278 </xsl:template>
 279
 280 <!-- Other inline tags -->
 281 <xsl:template match="mat" mode="inline">
 282     <math xmlns="http://www.w3.org/1998/Math/MathML"><xsl:copy-of select="*" /></math>
 283 </xsl:template>
 284
 285 <xsl:template match="didask_tekst" mode="inline">
 286     <em class="didaskalia"><xsl:apply-templates mode="inline" /></em>
 287 </xsl:template>
 288
 289 <xsl:template match="slowo_obce" mode="inline">
 290     <em class="foreign-word"><xsl:apply-templates mode="inline" /></em>
 291 </xsl:template>
 292
 293 <xsl:template match="tytul_dziela" mode="inline">
 294     <em class="book-title">
 295         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 296     </em>
 297 </xsl:template>
 298
 299 <xsl:template match="wyroznienie" mode="inline">
 300     <em class="author-emphasis"><xsl:apply-templates mode="inline" /></em>
 301 </xsl:template>
 302
 303 <xsl:template match="osoba" mode="inline">
 304     <em class="person"><xsl:apply-templates mode="inline" /></em>
 305 </xsl:template>
 306
 307
 308 <!-- ============================================== -->
 309 <!-- = STANDALONE TAGS                            = -->
 310 <!-- = (cannot contain any other tags)            = -->
 311 <!-- ============================================== -->
 312 <xsl:template match="sekcja_swiatlo">
 313     <hr class="spacer" />
 314 </xsl:template>
 315
 316 <xsl:template match="sekcja_asterysk">
 317     <p class="spacer-asterisk">*</p>
 318 </xsl:template>
 319
 320 <xsl:template match="separator_linia">
 321     <hr class="spacer-line" />
 322 </xsl:template>
 323
 324
 325 <!-- ================ -->
 326 <!-- = SPECIAL TAGS = -->
 327 <!-- ================ -->
 328 <!-- Themes -->
 329 <xsl:template match="begin" mode="inline">
 330     <xsl:variable name="mnum" select="concat('m', substring(@id, 2))" />
 331     <a name="m{substring(@id, 2)}" class="theme-begin" fid="{substring(@id, 2)}">
 332         <xsl:value-of select="string(following::motyw[@id=$mnum]/text())" />
 333     </a>
 334 </xsl:template>
 335
 336 <xsl:template match="end" mode="inline">
 337     <span class="theme-end" fid="{substring(@id, 2)}"> </span>
 338 </xsl:template>
 339
 340 <xsl:template match="begin|end">
 341     <xsl:apply-templates select='.' mode="inline" />
 342 </xsl:template>
 343
 344 <xsl:template match="motyw" mode="inline" />
 345
 346
 347 <xsl:template match="nota_red" mode="special">
 348     <div id="nota_red">
 349         <xsl:apply-templates />
 350     </div>
 351 </xsl:template>
 352
 353
 354 <xsl:template name="translators">
 355     <xsl:if test="//dc:contributor.translator">
 356         <span class="translator">
 357             <xsl:text>tłum. </xsl:text>
 358             <xsl:for-each select="//dc:contributor.translator">
 359                 <xsl:if test="position() != 1">, </xsl:if>
 360                 <xsl:apply-templates mode="person" />
 361             </xsl:for-each>
 362         </span>
 363     </xsl:if>
 364 </xsl:template>
 365
 366 <xsl:template match="text()" mode="person">
 367     <xsl:value-of select="wl:person_name(.)" />
 368 </xsl:template>
 369
 370
 371 <!-- ================ -->
 372 <!-- = IGNORED TAGS = -->
 373 <!-- ================ -->
 374 <xsl:template match="extra|uwaga" />
 375 <xsl:template match="extra|uwaga" mode="inline" />
 376
 377 <xsl:template match="nota_red" />
 378 <xsl:template match="abstrakt" />
 379
 380 <!-- ======== -->
 381 <!-- = TEXT = -->
 382 <!-- ======== -->
 383 <xsl:template match="text()" />
 384 <xsl:template match="text()" mode="inline">
 385     <xsl:value-of select="wl:substitute_entities(.)" />
 386 </xsl:template>
 387
 388 <!-- ========= -->
 389 <!-- = utils = -->
 390 <!-- ========= -->
 391 <xsl:template name="section-anchor">
 392   <!--
 393        this formula works as follows:
 394        - get all ancestors including self
 395        - choose the header (third one from root): utwor/book-type/header
 396        - get all preceding siblings
 397        - count them
 398        - create an <a name="sec123"/> tag.
 399   -->
 400         <a name="{concat('sec', count(ancestor-or-self::*[last()-2]/preceding-sibling::*) + 1)}" />
 401 </xsl:template>
 402
 403 </xsl:stylesheet>