librarian/xslt/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[a4paper, oneside, 11pt]{book}
  19         \usepackage{wl}
  20         </TeXML>
  21
  22         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  23         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  24
  25         <env name="document">
  26             <cmd name="maketitle" />
  27
  28             <xsl:choose>
  29                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  30                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  31                     <!-- title in master -->
  32                 </xsl:when>
  33                 <xsl:otherwise>
  34                     <!-- look for author title in dc -->
  35                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  36                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  37                 </xsl:otherwise>
  38             </xsl:choose>
  39             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  40             <xsl:apply-templates select="utwor" mode="part" />
  41         </env>
  42     </TeXML>
  43 </xsl:template>
  44
  45 <xsl:template match="utwor" mode="part">
  46     <!-- title for empty dc -->
  47     <xsl:choose>
  48         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  49             <!-- title in master -->
  50         </xsl:when>
  51         <xsl:otherwise>
  52             <!-- look for title in dc -->
  53             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
  54             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
  55         </xsl:otherwise>
  56     </xsl:choose>
  57
  58     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  59     <xsl:apply-templates select="utwor" mode="part" />
  60 </xsl:template>
  61
  62 <!-- =================== -->
  63 <!-- = MAIN TITLE PAGE = -->
  64 <!-- = (from DC)       = -->
  65 <!-- =================== -->
  66
  67 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
  68     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  69 </xsl:template>
  70
  71 <xsl:template match="rdf:RDF" mode="titlepage">
  72     <cmd name='title'><parm>
  73         <xsl:value-of select=".//dc:title/text()" />
  74     </parm></cmd>
  75     <cmd name='author'><parm>
  76         <xsl:value-of select="wl:person_name(.//dc:creator/text())" />
  77     </parm></cmd>
  78 </xsl:template>
  79
  80
  81 <!-- ============== -->
  82 <!-- = BOOK TITLE = -->
  83 <!-- = (from DC)  = -->
  84 <!-- ============== -->
  85
  86 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
  87     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
  88 </xsl:template>
  89
  90 <xsl:template match="rdf:RDF" mode="dctitle">
  91     <cmd name="section*"><parm>
  92         <xsl:value-of select=".//dc:title/text()" />
  93     </parm></cmd>
  94 </xsl:template>
  95
  96
  97 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
  98     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  99 </xsl:template>
 100
 101 <xsl:template match="rdf:RDF" mode="firstdctitle">
 102     <cmd name="subsection*"><parm>
 103         <xsl:value-of select="wl:person_name(.//dc:creator/text())" />
 104     </parm></cmd>
 105     <cmd name="section*"><parm>
 106         <xsl:value-of select=".//dc:title/text()" />
 107     </parm></cmd>
 108 </xsl:template>
 109
 110
 111 <!-- ============================================================================== -->
 112 <!-- = MASTER TAG                                                                 = -->
 113 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 114 <!-- ============================================================================== -->
 115
 116 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny">
 117     <xsl:apply-templates />
 118 </xsl:template>
 119
 120
 121
 122 <!-- ==================================================================================== -->
 123 <!-- = BLOCK TAGS                                                                       = -->
 124 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 125 <!-- ==================================================================================== -->
 126 <xsl:template match="nota">
 127     <cmd name="par">
 128         <parm><xsl:apply-templates /></parm>
 129     </cmd>
 130 </xsl:template>
 131
 132 <xsl:template match="lista_osob">
 133     <cmd name="par"><parm>
 134         <cmd name="textbf">
 135             <parm><xsl:value-of select="naglowek_listy" /></parm>
 136         </cmd>
 137         <env name="itemize">
 138             <xsl:apply-templates select="lista_osoba" />
 139         </env>
 140     </parm></cmd>
 141 </xsl:template>
 142
 143 <xsl:template match="dedykacja">
 144     <cmd name="hspace"><parm>0.4<cmd name='linewidth' /></parm></cmd>
 145     <env name="minipage"><parm>0.6<cmd name='linewidth' /></parm>
 146         <env name="em">
 147             <xsl:apply-templates />
 148         </env>
 149     </env>
 150 </xsl:template>
 151
 152 <xsl:template match="kwestia">
 153     <cmd name="par">
 154         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 155     </cmd>
 156 </xsl:template>
 157
 158 <xsl:template match="dlugi_cytat">
 159     <env name="quotation">
 160         <xsl:apply-templates />
 161     </env>
 162 </xsl:template>
 163
 164 <xsl:template match="poezja_cyt">
 165     <env name="verse">
 166         <xsl:apply-templates />
 167     </env>
 168 </xsl:template>
 169
 170 <xsl:template match="motto">
 171     <env name="em">
 172         <xsl:apply-templates mode="inline" />
 173     </env>
 174 </xsl:template>
 175
 176
 177 <!-- ========================================== -->
 178 <!-- = PARAGRAPH TAGS                         = -->
 179 <!-- = (can contain inline and special tags)  = -->
 180 <!-- ========================================== -->
 181
 182 <!-- only in root -->
 183 <xsl:template match="autor_utworu" mode="title">X
 184     <cmd name="subsection*"><parm>
 185         <xsl:apply-templates mode="inline" />
 186     </parm></cmd>
 187 </xsl:template>
 188
 189 <xsl:template match="nazwa_utworu">
 190     <cmd name="section*"><parm>
 191         <xsl:apply-templates mode="inline" />
 192     </parm></cmd>
 193 </xsl:template>
 194
 195 <!-- Section headers (included in index)-->
 196 <xsl:template match="naglowek_akt|naglowek_czesc|srodtytul">
 197     <cmd name="subsection*">
 198         <parm><xsl:apply-templates mode="inline" /></parm>
 199     </cmd>
 200 </xsl:template>
 201
 202 <xsl:template match="naglowek_scena|naglowek_rozdzial">
 203     <cmd name="subsubsection*">
 204         <parm><xsl:apply-templates mode="inline" /></parm>
 205     </cmd>
 206 </xsl:template>
 207
 208 <xsl:template match="naglowek_osoba|naglowek_podrozdzial">
 209     <cmd name="paragraph*">
 210         <parm><xsl:apply-templates mode="inline" /></parm>
 211     </cmd>
 212 </xsl:template>
 213
 214 <!-- Other paragraph tags -->
 215 <xsl:template match="miejsce_czas">
 216     <cmd name="par"><parm>
 217         <cmd name="emph">
 218             <parm><xsl:apply-templates mode="inline" /></parm>
 219         </cmd>
 220     </parm></cmd>
 221 </xsl:template>
 222
 223 <xsl:template match="didaskalia">
 224     <cmd name="par"><parm>
 225         <cmd name="emph">
 226             <parm><xsl:apply-templates mode="inline" /></parm>
 227         </cmd>
 228     </parm></cmd>
 229 </xsl:template>
 230
 231 <xsl:template match="lista_osoba">
 232     <cmd name="item"><parm>
 233         <xsl:apply-templates mode="inline" />
 234     </parm></cmd>
 235 </xsl:template>
 236
 237 <xsl:template match="akap|akap_dialog|akap_cd">
 238     <cmd name="par"><parm>
 239         <xsl:apply-templates mode="inline" />
 240     </parm></cmd>
 241 </xsl:template>
 242
 243 <xsl:template match="strofa">
 244 <cmd name="par"><parm><cmd name="noindent"><parm>
 245             <xsl:choose>
 246             <xsl:when test="count(br) > 0">
 247                 <xsl:call-template name="verse">
 248                     <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 249                     <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd'][1]" />
 250                 </xsl:call-template>
 251                 <xsl:for-each select="br">
 252                     <cmd name="newline" />
 253                     <!-- Each BR tag "consumes" text after it -->
 254                     <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 255                     <xsl:call-template name="verse">
 256                         <xsl:with-param name="verse-content"
 257                             select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 258                         <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd')][1]" />
 259                     </xsl:call-template>
 260                 </xsl:for-each>
 261             </xsl:when>
 262             <xsl:otherwise>
 263                 <xsl:call-template name="verse">
 264                     <xsl:with-param name="verse-content" select="text() | node()" />
 265                     <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd[1]" />
 266                  </xsl:call-template>
 267             </xsl:otherwise>
 268         </xsl:choose>
 269     <cmd name="vspace"><parm>1em</parm></cmd>
 270 </parm></cmd></parm></cmd>
 271 </xsl:template>
 272
 273
 274 <xsl:template name="verse">
 275     <xsl:param name="verse-content" />
 276     <xsl:param name="verse-type" />
 277         <xsl:choose><xsl:when test="name($verse-type) = 'wers_akap'"><cmd name="hspace" ><parm><xsl:value-of select="$firet" />pt</parm></cmd></xsl:when>
 278             <xsl:when test="name($verse-type) = 'wers_wciety'">
 279                 <xsl:choose>
 280                     <xsl:when test="$verse-content/@typ">
 281                         <cmd name="hspace" ><parm><xsl:value-of select="$verse-content/@typ" />em</parm></cmd>
 282                     </xsl:when>
 283                     <xsl:otherwise>
 284                         <cmd name="hspace" ><parm>1em</parm></cmd>
 285                     </xsl:otherwise>
 286                 </xsl:choose>
 287             </xsl:when>
 288             <xsl:when test="name($verse-type) = 'wers_cd'">
 289                 <cmd name="hspace" ><parm>12em</parm></cmd>
 290             </xsl:when>
 291         </xsl:choose>
 292         <xsl:apply-templates select="$verse-content" mode="inline" />
 293 </xsl:template>
 294
 295 <xsl:template match="motto_podpis">
 296     <cmd name="hspace"><parm>0.4<cmd name='linewidth' /></parm></cmd>
 297     <env name="minipage"><parm>0.6<cmd name='linewidth' /></parm>
 298         <env name="em">
 299             <xsl:apply-templates mode="inline" />
 300         </env>
 301     </env>
 302 </xsl:template>
 303
 304 <!-- ================================================ -->
 305 <!-- = INLINE TAGS                                  = -->
 306 <!-- = (contain other inline tags and special tags) = -->
 307 <!-- ================================================ -->
 308
 309 <!-- Annotations -->
 310 <xsl:template match="pa|pe|pr|pt" mode="inline">
 311     <cmd name="footnote"><parm><xsl:apply-templates mode="inline" /></parm></cmd>
 312 </xsl:template>
 313
 314 <!-- Other inline tags -->
 315 <xsl:template match="mat" mode="inline">
 316     <math><xsl:apply-templates mode="inline" /></math>
 317 </xsl:template>
 318
 319 <xsl:template match="didask_tekst" mode="inline">
 320     <cmd name="emph"><parm><xsl:apply-templates mode="inline" /></parm></cmd>
 321 </xsl:template>
 322
 323 <xsl:template match="slowo_obce" mode="inline">
 324     <cmd name="emph"><parm><xsl:apply-templates mode="inline" /></parm></cmd>
 325 </xsl:template>
 326
 327 <xsl:template match="tytul_dziela" mode="inline">
 328     <cmd name="emph"><parm>
 329         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 330     </parm></cmd>
 331 </xsl:template>
 332
 333 <xsl:template match="wyroznienie" mode="inline">
 334     <cmd name="emph"><parm><xsl:apply-templates mode="inline" /></parm></cmd>
 335 </xsl:template>
 336
 337 <xsl:template match="osoba" mode="inline">
 338     <cmd name="textsc"><parm><xsl:apply-templates mode="inline" /></parm></cmd>
 339 </xsl:template>
 340
 341
 342 <!-- ============================================== -->
 343 <!-- = STANDALONE TAGS                            = -->
 344 <!-- = (cannot contain any other tags)            = -->
 345 <!-- ============================================== -->
 346 <xsl:template match="sekcja_swiatlo">
 347     <cmd name="hspace"><parm>30pt</parm></cmd>
 348 </xsl:template>
 349
 350 <xsl:template match="sekcja_asterysk">
 351     <!-- TODO: padding? -->
 352     <cmd name="par"><parm>*</parm></cmd>
 353 </xsl:template>
 354
 355 <xsl:template match="separator_linia">
 356     <cmd name="hrule" />
 357 </xsl:template>
 358
 359
 360
 361 <!-- ================ -->
 362 <!-- = SPECIAL TAGS = -->
 363 <!-- ================ -->
 364 <!-- Themes -->
 365
 366
 367 <xsl:template match="begin|end|motyw">
 368     <xsl:apply-templates select='.' mode="inline" />
 369 </xsl:template>
 370
 371 <xsl:template match="begin" mode="inline" />
 372 <xsl:template match="end" mode="inline" />
 373
 374 <xsl:template match="motyw" mode="inline">
 375     <cmd name="mbox" />
 376     <cmd name="marginpar">
 377         <parm>
 378             <cmd name="vspace"><parm>-8pt</parm></cmd>
 379             <xsl:if test="@moved">
 380                 <cmd name="vspace"><parm>-<xsl:value-of select="@moved" /><cmd name="baselineskip" /></parm></cmd>
 381             </xsl:if>
 382             <cmd name="raggedright"><parm>
 383                 <cmd name="hspace"><parm>0pt</parm></cmd>
 384                 <cmd name="footnotesize"><parm>
 385                     <cmd name="color"><parm>theme</parm><parm>
 386                         <xsl:value-of select="." />
 387                     </parm></cmd>
 388                 </parm></cmd>
 389             </parm></cmd>
 390         </parm>
 391     </cmd>
 392 </xsl:template>
 393
 394
 395 <!-- ============== -->
 396 <!-- = ADDED TAGS = -->
 397 <!-- ============== -->
 398
 399
 400 <xsl:template match="dywiz" mode="inline">
 401     <cmd name="dywiz" />
 402 </xsl:template>
 403
 404 <xsl:template match="nbsp" mode="inline">
 405     <spec cat="tilde" />
 406 </xsl:template>
 407
 408 <!-- ================ -->
 409 <!-- = IGNORED TAGS = -->
 410 <!-- ================ -->
 411 <xsl:template match="extra|uwaga" />
 412 <xsl:template match="extra|uwaga" mode="inline" />
 413
 414
 415 <!-- ======== -->
 416 <!-- = TEXT = -->
 417 <!-- ======== -->
 418 <xsl:template match="text()" />
 419 <xsl:template match="text()" mode="inline">
 420     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 421       <xsl:text> </xsl:text>
 422     </xsl:if>
 423
 424     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 425
 426     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 427       <xsl:text> </xsl:text>
 428     </xsl:if>
 429 </xsl:template>
 430
 431
 432 </xsl:stylesheet>