bin/book2html.xslt

   1 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   2     xmlns:wl="http://wolnelektury.pl/functions" >
   3
   4 <xsl:output method="xml" encoding="utf-8" doctype-public="-//W3C//DTD XHTML 1.1//EN" doctype-system="http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd" indent="yes" />
   5
   6 <xsl:template match="text()" />
   7 <xsl:template match="text()" mode="inline">
   8     <xsl:value-of select="wl:substitute_entities(.)" />
   9 </xsl:template>
  10
  11 <xsl:template match="extra|uwaga" />
  12 <xsl:template match="extra|uwaga" mode="inline" />
  13
  14 <xsl:template match="utwor">
  15     <html>
  16         <head>
  17             <title>book2html output</title>
  18             <meta http-equiv="content-type" content="text/html;charset=utf-8"/>
  19             <link rel="stylesheet" href="master.css" type="text/css" media="all" charset="utf-8" />
  20         </head>
  21         <body>
  22             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  23             <xsl:if test="count(descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)])">
  24                 <div id="footnotes">
  25                     <h3>Przypisy</h3>
  26                     <xsl:for-each select="descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)]">
  27                         <div>
  28                             <a name="{concat('footnote-', generate-id(.))}" />
  29                             <a href="{concat('#anchor-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
  30                             <xsl:choose>
  31                                 <xsl:when test="count(akap|akap_cd|strofa) = 0">
  32                                     <p><xsl:apply-templates select="text()|*" mode="inline" /></p>
  33                                 </xsl:when>
  34                                 <xsl:otherwise>
  35                                     <xsl:apply-templates select="text()|*" mode="inline" />
  36                                 </xsl:otherwise>
  37                             </xsl:choose>
  38                         </div>
  39                     </xsl:for-each>
  40                 </div>
  41             </xsl:if>
  42         </body>
  43     </html>
  44 </xsl:template>
  45
  46
  47 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny">
  48     <xsl:if test="nazwa_utworu">
  49         <h1>
  50             <xsl:apply-templates select="autor_utworu|dzielo_nadrzedne|nazwa_utworu" mode="header" />
  51         </h1>
  52     </xsl:if>
  53     <xsl:apply-templates />
  54 </xsl:template>
  55
  56 <xsl:template match="autor_utworu" mode="header">
  57     <span class="author"><xsl:apply-templates mode="inline" /></span>
  58 </xsl:template>
  59
  60 <xsl:template match="nazwa_utworu" mode="header">
  61     <span class="title"><xsl:apply-templates mode="inline" /></span>
  62 </xsl:template>
  63
  64 <xsl:template match="dzielo_nadrzedne" mode="header">
  65     <span class="collection"><xsl:apply-templates mode="inline" /></span>
  66 </xsl:template>
  67
  68 <xsl:template match="naglowek_akt|naglowek_czesc|srodtytul">
  69     <h2><xsl:apply-templates mode="inline" /></h2>
  70 </xsl:template>
  71
  72 <xsl:template match="naglowek_scena|naglowek_rozdzial">
  73     <h3><xsl:apply-templates mode="inline" /></h3>
  74 </xsl:template>
  75
  76 <xsl:template match="naglowek_osoba">
  77     <h4><xsl:apply-templates mode="inline" /></h4>
  78 </xsl:template>
  79
  80 <xsl:template match="kwestia">
  81     <div class="kwestia">
  82         <xsl:apply-templates select="strofa|akap" />
  83     </div>
  84 </xsl:template>
  85
  86 <xsl:template match="didaskalia">
  87     <div class="didaskalia"><xsl:apply-templates mode="inline" /></div>
  88 </xsl:template>
  89
  90 <xsl:template match="lista_osob">
  91     <div class="person-list">
  92         <h3><xsl:value-of select="naglowek_listy" /></h3>
  93         <ol>
  94             <xsl:apply-templates select="lista_osoba" />
  95         </ol>
  96     </div>
  97 </xsl:template>
  98
  99 <xsl:template match="lista_osoba">
 100     <li><xsl:apply-templates mode="inline" /></li>
 101 </xsl:template>
 102
 103 <xsl:template match="begin" mode="inline">
 104     <xsl:variable name="mnum" select="concat('m', substring(@id, 2))" />
 105     <span class="theme-begin" fid="{substring(@id, 2)}">
 106         <xsl:value-of select="string(following::motyw[@id=$mnum]/text())" />
 107     </span>
 108 </xsl:template>
 109
 110 <xsl:template match="end" mode="inline">
 111     <span class="theme-end" fid="{substring(@id, 2)}"> </span>
 112 </xsl:template>
 113
 114 <xsl:template match="begin|end">
 115     <xsl:apply-templates select='.' mode="inline" />
 116 </xsl:template>
 117
 118 <xsl:template name="verse">
 119     <xsl:param name="line-content" />
 120     <xsl:param name="line-number" />
 121     <p>
 122         <xsl:choose>
 123             <xsl:when test="name($line-content) = 'wers_akap'">
 124                 <xsl:attribute name="style">indent: 1em</xsl:attribute>
 125             </xsl:when>
 126             <xsl:when test="name($line-content) = 'wers_wciety'">
 127                 <xsl:attribute name="style">indent: 2em</xsl:attribute>
 128             </xsl:when>
 129         </xsl:choose>
 130         <xsl:apply-templates select="$line-content" mode="inline" />
 131     </p>
 132 </xsl:template>
 133
 134 <xsl:template match="pa|pe|pr|pt" mode="inline">
 135     <a name="{concat('anchor-', generate-id(.))}" />
 136     <a href="{concat('#footnote-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
 137 </xsl:template>
 138
 139 <xsl:template match="strofa">
 140     <div class="stanza">
 141         <xsl:choose>
 142             <xsl:when test="count(br) > 0">
 143                 <xsl:call-template name="verse">
 144                     <xsl:with-param name="line-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 145                     <xsl:with-param name="line-number" select="1" />
 146                 </xsl:call-template>
 147                 <xsl:for-each select="br">
 148                                 <!-- Każdy BR "zjada" to co jest za nim -->
 149                     <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 150                     <xsl:call-template name="verse">
 151                         <xsl:with-param name="line-number" select="$lnum+2" />
 152                         <xsl:with-param name="line-content"
 153                             select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 154                     </xsl:call-template>
 155                 </xsl:for-each>
 156             </xsl:when>
 157             <xsl:otherwise>
 158                 <xsl:call-template name="verse">
 159                     <xsl:with-param name="line-content" select="text() | node()" />
 160                     <xsl:with-param name="line-number" select="1" />
 161                  </xsl:call-template>
 162             </xsl:otherwise>
 163         </xsl:choose>
 164     </div>
 165 </xsl:template>
 166
 167 <xsl:template match="akap|akap_dialog|akap_cd">
 168     <p class="paragraph"><xsl:apply-templates mode="inline" /></p>
 169 </xsl:template>
 170
 171 <xsl:template match="motyw" mode="inline" />
 172
 173 <xsl:template match="dlugi_cytat">
 174     <blockquote><xsl:apply-templates /></blockquote>
 175 </xsl:template>
 176
 177 <xsl:template match="motto">
 178     <p class="motto"><xsl:apply-templates mode="inline" /></p>
 179 </xsl:template>
 180
 181 <xsl:template match="sekcja_swiatlo">
 182     <hr class="spacer" />
 183 </xsl:template>
 184
 185 </xsl:stylesheet>