<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Font::TTF::Mort::Contextual;

=head1 NAME

Font::TTF::Mort::Contextual - Contextual Mort subtable for AAT

=head1 METHODS

=cut

use strict;
use vars qw(@ISA);
use Font::TTF::Utils;
use Font::TTF::AATutils;
use Font::TTF::Mort::Subtable;
use IO::File;

@ISA = qw(Font::TTF::AAT::Mort::Subtable);

sub new
{
    my ($class, $direction, $orientation, $subFeatureFlags) = @_;
    my ($self) = {
                    'direction'            =&gt; $direction,
                    'orientation'        =&gt; $orientation,
                    'subFeatureFlags'    =&gt; $subFeatureFlags
                };

    $class = ref($class) || $class;
    bless $self, $class;
}

=head2 $t-&gt;read

Reads the table into memory

=cut

sub read
{
    my ($self, $fh) = @_;
    my ($dat);
    
    my $stateTableStart = $fh-&gt;tell();
    my ($classes, $states, $entries) = AAT_read_state_table($fh, 2);

    $fh-&gt;seek($stateTableStart, IO::File::SEEK_SET);
    $fh-&gt;read($dat, 10);
    my ($stateSize, $classTable, $stateArray, $entryTable, $mappingTables) = unpack("nnnnn", $dat);
    my $limits = [$classTable, $stateArray, $entryTable, $mappingTables, $self-&gt;{'length'} - 8];

    foreach (@$entries) {
        my $actions = $_-&gt;{'actions'};
        foreach (@$actions) {
            $_ = $_ ? $_ - ($mappingTables / 2) : undef;
        }
    }
    
    $self-&gt;{'classes'} = $classes;
    $self-&gt;{'states'} = $states;
    $self-&gt;{'mappings'} = [unpack("n*", AAT_read_subtable($fh, $stateTableStart, $mappingTables, $limits))];
            
    $self;
}

=head2 $t-&gt;pack_sub()

=cut

sub pack_sub
{
    my ($self) = @_;
    
    my ($dat) = pack("nnnnn", (0) x 5);    # placeholders for stateSize, classTable, stateArray, entryTable, mappingTables
    
    my $classTable = length($dat);
    my $classes = $self-&gt;{'classes'};
    $dat .= AAT_pack_classes($classes);
    
    my $stateArray = length($dat);
    my $states = $self-&gt;{'states'};
    my ($dat1, $stateSize, $entries) = AAT_pack_states($classes, $stateArray, $states, 
            sub {
                my $actions = $_-&gt;{'actions'};
                ( $_-&gt;{'flags'}, @$actions )
            }
        );
    $dat .= $dat1;
    
    my $entryTable = length($dat);
    my $offset = ($entryTable + 8 * @$entries) / 2;
    foreach (@$entries) {
        my ($nextState, $flags, @parts) = split /,/;
        $dat .= pack("nnnn", $nextState, $flags, map { $_ eq "" ? 0 : $_ + $offset } @parts);
    }

    my $mappingTables = length($dat);
    my $mappings = $self-&gt;{'mappings'};
    $dat .= pack("n*", @$mappings);
    
    $dat1 = pack("nnnnn", $stateSize, $classTable, $stateArray, $entryTable, $mappingTables);
    substr($dat, 0, length($dat1)) = $dat1;
    
    return $dat;
}

=head2 $t-&gt;print($fh)

Prints a human-readable representation of the table

=cut

sub print
{
    my ($self, $fh) = @_;
    
    my $post = $self-&gt;post();
    
    $fh = 'STDOUT' unless defined $fh;

    $self-&gt;print_classes($fh);
    
    $fh-&gt;print("\n");
    my $states = $self-&gt;{'states'};
    foreach (0 .. $#$states) {
        $fh-&gt;printf("\t\tState %d:", $_);
        my $state = $states-&gt;[$_];
        foreach (@$state) {
            my $flags;
            $flags .= "!" if ($_-&gt;{'flags'} &amp; 0x4000);
            $flags .= "*" if ($_-&gt;{'flags'} &amp; 0x8000);
            my $actions = $_-&gt;{'actions'};
            $fh-&gt;printf("\t(%s%d,%s,%s)", $flags, $_-&gt;{'nextState'}, map { defined $_ ? $_ : "=" } @$actions);
        }
        $fh-&gt;print("\n");
    }

    $fh-&gt;print("\n");
    my $mappings = $self-&gt;{'mappings'};
    foreach (0 .. $#$mappings) {
        $fh-&gt;printf("\t\tMapping %d: %d [%s]\n", $_, $mappings-&gt;[$_], $post-&gt;{'VAL'}[$mappings-&gt;[$_]]);
    }
}

1;

=head1 BUGS

None known

=head1 AUTHOR

Jonathan Kew L&lt;Jonathan_Kew@sil.org&gt;. See L&lt;Font::TTF::Font&gt; for copyright and
licensing.

=cut

</pre></body></html>