<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Font::TTF::Hdmx;

=head1 NAME

Font::TTF::Hdmx - Horizontal device metrics

=head1 DESCRIPTION

The table consists of an hash of device metric tables indexed by the ppem for
that subtable. Each subtable consists of an array of advance widths in pixels
for each glyph at that ppem (horizontally).

=head1 INSTANCE VARIABLES

Individual metrics are accessed using the following referencing:

    $f-&gt;{'hdmx'}{$ppem}[$glyph_num]

In addition there is one instance variable:

=over 4

=item Num

Number of device tables.

=back

=head2 METHODS

=cut

use strict;
use vars qw(@ISA);

@ISA = qw(Font::TTF::Table);


=head2 $t-&gt;read

Reads the table into data structures

=cut

sub read
{
    my ($self) = @_;
    my ($fh) = $self-&gt;{' INFILE'};
    my ($numg, $ppem, $i, $numt, $dat, $len);

    $numg = $self-&gt;{' PARENT'}{'maxp'}{'numGlyphs'};
    $self-&gt;SUPER::read or return $self;

    $fh-&gt;read($dat, 8);
    ($self-&gt;{'Version'}, $numt, $len) = unpack("nnN", $dat);
    $self-&gt;{'Num'} = $numt;

    for ($i = 0; $i &lt; $numt; $i++)
    {
        $fh-&gt;read($dat, $len);
        $ppem = unpack("C", $dat);
        $self-&gt;{$ppem} = [unpack("C$numg", substr($dat, 2))];
    }
    $self;
}


=head2 $t-&gt;out($fh)

Outputs the device metrics for this font

=cut

sub out
{
    my ($self, $fh) = @_;
    my ($numg, $i, $pad, $len, $numt, @ppem, $max);

    return $self-&gt;SUPER::out($fh) unless ($self-&gt;{' read'});

    $numg = $self-&gt;{' PARENT'}{'maxp'}{'numGlyphs'};
    @ppem = grep(/^\d+$/, sort {$a &lt;=&gt; $b} keys %$self);
    $pad = "\000" x (3 - ($numg + 1) % 4);
    $len = $numg + 2 + length($pad);
    $fh-&gt;print(pack("nnN", 0, $#ppem + 1, $len));
    for $i (@ppem)
    {
        $max = 0;
        foreach (@{$self-&gt;{$i}}[0..($numg - 1)])
        { $max = $_ if $_ &gt; $max; }
        $fh-&gt;print(pack("C*", $i, $max, @{$self-&gt;{$i}}[0..($numg - 1)]) . $pad);
    }
    $self;
}


=head2 $t-&gt;tables_do(&amp;func)

For each subtable it calls &amp;sub($ref, $ppem)

=cut

sub tables_do
{
    my ($self, $func) = @_;
    my ($i);

    foreach $i (grep(/^\d+$/, %$self))
    { &amp;$func($self-&gt;{$i}, $i); }
    $self;
}


=head2 $t-&gt;XML_element($context, $depth, $key, $value)

Outputs device metrics a little more tidily

=cut

sub XML_element
{
    my ($self) = shift;
    my ($context, $depth, $key, $value) = @_;
    my ($fh) = $context-&gt;{'fh'};
    my ($i);

    return $self-&gt;SUPER::XML_element(@_) if (ref($value) ne 'ARRAY');
    $fh-&gt;print("$depth&lt;metrics ppem='$key'&gt;\n");
    for ($i = 0; $i &lt;= $#{$value}; $i += 25)
    {
        $fh-&gt;print("$depth$context-&gt;{'indent'}". join(' ', @{$value}[$i .. $i + 24]) . "\n");
    }
    $fh-&gt;print("$depth&lt;/metrics&gt;\n");
    $self;
}

1;

=head1 BUGS

None known

=head1 AUTHOR

Martin Hosken Martin_Hosken@sil.org. See L&lt;Font::TTF::Font&gt; for copyright and
licensing.

=cut

</pre></body></html>