<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Font::TTF::Fdsc;

=head1 NAME

Font::TTF::Fdsc - Font Descriptors table in a font

=head1 DESCRIPTION

=head1 INSTANCE VARIABLES

=item version

=item descriptors

Hash keyed by descriptor tags

=head1 METHODS

=cut

use strict;
use vars qw(@ISA %fields);
use Font::TTF::Utils;

@ISA = qw(Font::TTF::Table);

=head2 $t-&gt;read

Reads the table into memory

=cut

sub read
{
    my ($self) = @_;
    my ($dat, $fh, $numDescs, $tag, $descs);

    $self-&gt;SUPER::read or return $self;

    $fh = $self-&gt;{' INFILE'};
    $fh-&gt;read($dat, 4);
    $self-&gt;{'version'} = TTF_Unpack("v", $dat);

    $fh-&gt;read($dat, 4);

    foreach (1 .. unpack("N", $dat)) {
        $fh-&gt;read($tag, 4);
        $fh-&gt;read($dat, 4);
        $descs-&gt;{$tag} = ($tag eq 'nalf') ? unpack("N", $dat) : TTF_Unpack("f", $dat);
    }

    $self-&gt;{'descriptors'} = $descs;

    $self;
}


=head2 $t-&gt;out($fh)

Writes the table to a file either from memory or by copying

=cut

sub out
{
    my ($self, $fh) = @_;
    my ($descs);

    return $self-&gt;SUPER::out($fh) unless $self-&gt;{' read'};
    
    $fh-&gt;print(TTF_Pack("v", $self-&gt;{'version'}));
    
    $descs = $self-&gt;{'descriptors'} or {};
    
    $fh-&gt;print(pack("N", scalar keys %$descs));    
    foreach (sort keys %$descs) {
        $fh-&gt;print($_);
        $fh-&gt;print(($_ eq 'nalf') ? pack("N", $descs-&gt;{$_}) : TTF_Pack("f", $descs-&gt;{$_}));
    }

    $self;
}

=head2 $t-&gt;print($fh)

Prints a human-readable representation of the table

=cut

sub print
{
    my ($self, $fh) = @_;
    my ($descs, $k);

    $self-&gt;read;

    $fh = 'STDOUT' unless defined $fh;

    $descs = $self-&gt;{'descriptors'};
    foreach $k (sort keys %$descs) {
        if ($k eq 'nalf') {
            $fh-&gt;printf("Descriptor '%s' = %d\n", $k, $descs-&gt;{$k});
        }
        else {
            $fh-&gt;printf("Descriptor '%s' = %f\n", $k, $descs-&gt;{$k});
        }
    }
    
    $self;
}

1;


=head1 BUGS

None known

=head1 AUTHOR

Jonathan Kew L&lt;Jonathan_Kew@sil.org&gt;. See L&lt;Font::TTF::Font&gt; for copyright and
licensing.

=cut

</pre></body></html>