<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Font::TTF::Mort::Subtable;

=head1 NAME

Font::TTF::Mort::Subtable - Mort subtable superclass for AAT

=head1 METHODS

=cut

use strict;
use Font::TTF::Utils;
use Font::TTF::AATutils;
use IO::File;

require Font::TTF::Mort::Rearrangement;
require Font::TTF::Mort::Contextual;
require Font::TTF::Mort::Ligature;
require Font::TTF::Mort::Noncontextual;
require Font::TTF::Mort::Insertion;

sub new
{
    my ($class) = @_;
    my ($self) = {};

    $class = ref($class) || $class;

    bless $self, $class;
}

sub create
{
    my ($class, $type, $coverage, $subFeatureFlags, $length) = @_;

    $class = ref($class) || $class;

    my $subclass;
    if ($type == 0) {
        $subclass = 'Font::TTF::Mort::Rearrangement';
    }
    elsif ($type == 1) {
        $subclass = 'Font::TTF::Mort::Contextual';
    }
    elsif ($type == 2) {
        $subclass = 'Font::TTF::Mort::Ligature';
    }
    elsif ($type == 4) {
        $subclass = 'Font::TTF::Mort::Noncontextual';
    }
    elsif ($type == 5) {
        $subclass = 'Font::TTF::Mort::Insertion';
    }
    
    my ($self) = $subclass-&gt;new(
            (($coverage &amp; 0x4000) ? 'RL' : 'LR'),
            (($coverage &amp; 0x2000) ? 'VH' : ($coverage &amp; 0x8000) ? 'V' : 'H'),
            $subFeatureFlags
        );

    $self-&gt;{'type'} = $type;
    $self-&gt;{'length'} = $length;

    $self;
}

=head2 $t-&gt;out($fh)

Writes the table to a file

=cut

sub out
{
    my ($self, $fh) = @_;
    
    my ($subtableStart) = $fh-&gt;tell();
    my ($type) = $self-&gt;{'type'};
    my ($coverage) = $type;
    $coverage += 0x4000 if $self-&gt;{'direction'} eq 'RL';
    $coverage += 0x2000 if $self-&gt;{'orientation'} eq 'VH';
    $coverage += 0x8000 if $self-&gt;{'orientation'} eq 'V';
    
    $fh-&gt;print(TTF_Pack("SSL", 0, $coverage, $self-&gt;{'subFeatureFlags'}));    # placeholder for length
    
    my ($dat) = $self-&gt;pack_sub();
    $fh-&gt;print($dat);
    
    my ($length) = $fh-&gt;tell() - $subtableStart;
    my ($padBytes) = (4 - ($length &amp; 3)) &amp; 3;
    $fh-&gt;print(pack("C*", (0) x $padBytes));
    $length += $padBytes;
    $fh-&gt;seek($subtableStart, IO::File::SEEK_SET);
    $fh-&gt;print(pack("n", $length));
    $fh-&gt;seek($subtableStart + $length, IO::File::SEEK_SET);
}

=head2 $t-&gt;print($fh)

Prints a human-readable representation of the table

=cut

sub post
{
    my ($self) = @_;
    
    my ($post) = $self-&gt;{' PARENT'}{' PARENT'}{' PARENT'}{'post'};
    if (defined $post) {
        $post-&gt;read;
    }
    else {
        $post = {};
    }
    
    return $post;
}

sub feat
{
    my ($self) = @_;
    
    return $self-&gt;{' PARENT'}-&gt;feat();
}

sub print
{
    my ($self, $fh) = @_;
    
    my ($feat) = $self-&gt;feat();
    my ($post) = $self-&gt;post();
    
    $fh = 'STDOUT' unless defined $fh;

    my ($type) = $self-&gt;{'type'};
    my ($subFeatureFlags) = $self-&gt;{'subFeatureFlags'};
    my ($defaultFlags) = $self-&gt;{' PARENT'}{'defaultFlags'};
    my ($featureEntries) = $self-&gt;{' PARENT'}{'featureEntries'};
    $fh-&gt;printf("\n\t%s table, %s, %s, subFeatureFlags = %08x # %s (%s)\n",
                subtable_type_($type), $_-&gt;{'direction'}, $_-&gt;{'orientation'}, $subFeatureFlags,
                "Default " . ((($subFeatureFlags &amp; $defaultFlags) != 0) ? "On" : "Off"),
                join(", ",
                    map {
                        join(": ", $feat-&gt;settingName($_-&gt;{'type'}, $_-&gt;{'setting'}) )
                    } grep { ($_-&gt;{'enable'} &amp; $subFeatureFlags) != 0 } @$featureEntries
                ) );
}

sub subtable_type_
{
    my ($val) = @_;
    my ($res);
    
    my (@types) =    (
                        'Rearrangement',
                        'Contextual',
                        'Ligature',
                        undef,
                        'Non-contextual',
                        'Insertion',
                    );
    $res = $types[$val] or ('Undefined (' . $val . ')');
    
    $res;
}

=head2 $t-&gt;print_classes($fh)

Prints a human-readable representation of the table

=cut

sub print_classes
{
    my ($self, $fh) = @_;
    
    my ($post) = $self-&gt;post();
    
    my ($classes) = $self-&gt;{'classes'};
    foreach (0 .. $#$classes) {
        my $class = $classes-&gt;[$_];
        if (defined $class) {
            $fh-&gt;printf("\t\tClass %d:\t%s\n", $_, join(", ", map { $_ . " [" . $post-&gt;{'VAL'}[$_] . "]" } @$class));
        }
    }
}

1;

=head1 BUGS

None known

=head1 AUTHOR

Jonathan Kew L&lt;Jonathan_Kew@sil.org&gt;. See L&lt;Font::TTF::Font&gt; for copyright and
licensing.

=cut

</pre></body></html>