librarian/pdf/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[<xsl:value-of select="@customizations"/>]{wl}
  19
  20         <!-- flags and values set on root -->
  21
  22         \newif\ifflaglessadvertising
  23         <xsl:for-each select="@*[starts-with(name(), 'flag-')]">
  24             <cmd>
  25                 <xsl:attribute name="name"><xsl:value-of select="wl:texcommand(name())" />true</xsl:attribute>
  26             </cmd>
  27         </xsl:for-each>
  28
  29         <xsl:for-each select="@*[starts-with(name(), 'data-')]">
  30             <TeXML escape="0">
  31                 \def\<xsl:value-of select="wl:texcommand(name())" />{<TeXML escape="1"><xsl:value-of select="."/></TeXML>}
  32             </TeXML>
  33         </xsl:for-each>
  34         </TeXML>
  35
  36         <xsl:choose>
  37             <xsl:when test="@morefloats = 'new'">
  38                 <TeXML escape="0">
  39                     \usepackage[maxfloats=64]{morefloats}
  40                 </TeXML>
  41             </xsl:when>
  42             <xsl:when test="@morefloats = 'old'">
  43                 <TeXML escape="0">
  44                     \usepackage{morefloats}
  45                 </TeXML>
  46             </xsl:when>
  47             <xsl:when test="@morefloats = 'none'" />
  48             <xsl:otherwise>
  49                 <TeXML escape="0">
  50                     \IfFileExists{morefloats.sty}{
  51                         \usepackage{morefloats}
  52                     }{}
  53                 </TeXML>
  54             </xsl:otherwise>
  55         </xsl:choose>
  56
  57         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  58         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  59
  60         <env name="document">
  61             <xsl:if test="@data-cover-width">
  62                 <cmd name="makecover">
  63                     <parm><xsl:value-of select="210 * @data-cover-width div @data-cover-height" />mm</parm>
  64                     <parm>210mm</parm>
  65                 </cmd>
  66             </xsl:if>
  67             <cmd name="maketitle" />
  68
  69             <cmd name="tytul"><parm>
  70               <xsl:choose>
  71                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  72                     <!-- title in master -->
  73                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  74                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
  75                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
  76                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
  77                     <!-- dc in master or not -->
  78                     <cmd name="translatorsline" />
  79                 </xsl:when>
  80                 <xsl:otherwise>
  81                     <!-- look for author title in dc -->
  82                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  83                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  84                 </xsl:otherwise>
  85               </xsl:choose>
  86             </parm></cmd>
  87             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  88             <xsl:apply-templates select="utwor" mode="part" />
  89
  90             <TeXML escape="0">
  91                 <xsl:if test="@data-cover-by">
  92                 \def\coverby{Okładka na podstawie:
  93                     <xsl:choose>
  94                     <xsl:when test="@data-cover-source">
  95                         \href{\datacoversource}{\datacoverby}
  96                     </xsl:when>
  97                     <xsl:otherwise>
  98                         \datacoverby{}
  99                     </xsl:otherwise>
 100                     </xsl:choose>
 101                 }
 102                 </xsl:if>
 103                 \def\editors{<xsl:call-template name="editors" />}
 104             </TeXML>
 105
 106             <cmd name="editorialsection" />
 107
 108         </env>
 109     </TeXML>
 110 </xsl:template>
 111
 112 <xsl:template match="utwor" mode="part">
 113     <cmd name="tytul"><parm>
 114       <xsl:choose>
 115         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
 116             <!-- title in master -->
 117             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
 118             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
 119         </xsl:when>
 120         <xsl:otherwise>
 121             <!-- look for title in dc -->
 122             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 123             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
 124         </xsl:otherwise>
 125       </xsl:choose>
 126     </parm></cmd>
 127
 128     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 129     <xsl:apply-templates select="utwor" mode="part" />
 130 </xsl:template>
 131
 132 <!-- =================== -->
 133 <!-- = MAIN TITLE PAGE = -->
 134 <!-- = (from DC)       = -->
 135 <!-- =================== -->
 136
 137 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
 138     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
 139 </xsl:template>
 140
 141 <xsl:template match="rdf:RDF" mode="titlepage">
 142     <TeXML escape="0">
 143         \def\authors{<xsl:call-template name="authors" />}
 144         \author{\authors}
 145         \title{<xsl:apply-templates select=".//dc:title" mode="inline" />}
 146         \def\translatorsline{<xsl:call-template name="translators" />}
 147
 148         \def\bookurl{<xsl:value-of select=".//dc:identifier.url" />}
 149
 150         \def\rightsinfo{Ten utwór nie jest chroniony prawem autorskim i~znajduje się w~domenie
 151             publicznej, co oznacza że możesz go swobodnie wykorzystywać, publikować
 152             i~rozpowszechniać. Jeśli utwór opatrzony jest dodatkowymi materiałami
 153             (przypisy, motywy literackie etc.), które podlegają prawu autorskiemu, to
 154             te dodatkowe materiały udostępnione są na licencji
 155             \href{http://creativecommons.org/licenses/by-sa/3.0/}{Creative Commons
 156             Uznanie Autorstwa – Na Tych Samych Warunkach 3.0 PL}.}
 157         <xsl:if test=".//dc:rights.license">
 158             \def\rightsinfo{Ten utwór jest udostepniony na licencji
 159             \href{<xsl:value-of select=".//dc:rights.license" />}{<xsl:value-of select=".//dc:rights" />}.}
 160         </xsl:if>
 161
 162         \def\sourceinfo{
 163             <xsl:if test=".//dc:source">
 164                 Tekst opracowany na podstawie: <xsl:apply-templates select=".//dc:source" mode="inline" />
 165                 \vspace{.6em}
 166             </xsl:if>}
 167         \def\description{<xsl:apply-templates select=".//dc:description" mode="inline" />}
 168         \def\editors{<xsl:call-template name="editors" />}
 169     </TeXML>
 170 </xsl:template>
 171
 172
 173 <!-- ============== -->
 174 <!-- = BOOK TITLE = -->
 175 <!-- = (from DC)  = -->
 176 <!-- ============== -->
 177
 178 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
 179     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 180 </xsl:template>
 181
 182 <xsl:template match="rdf:RDF" mode="dctitle">
 183     <cmd name="nazwapodutworu"><parm>
 184         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 185     </parm></cmd>
 186 </xsl:template>
 187
 188 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
 189     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
 190 </xsl:template>
 191
 192 <xsl:template match="rdf:RDF" mode="firstdctitle">
 193     <cmd name="autorutworu"><parm><cmd name="authors"/></parm></cmd>
 194     <cmd name="nazwautworu"><parm>
 195         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 196     </parm></cmd>
 197     <cmd name="translatorsline" />
 198 </xsl:template>
 199
 200
 201 <!-- ============================================================================== -->
 202 <!-- = MASTER TAG                                                                 = -->
 203 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 204 <!-- ============================================================================== -->
 205 <!-- ==================================================================================== -->
 206 <!-- = BLOCK TAGS                                                                       = -->
 207 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 208 <!-- ==================================================================================== -->
 209
 210 <xsl:template
 211     match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny|nota|dedykacja|dlugi_cytat|poezja_cyt|motto">
 212     <cmd>
 213         <xsl:attribute name="name">
 214             <xsl:value-of select="wl:texcommand(name())" />
 215         </xsl:attribute>
 216         <parm><xsl:apply-templates/></parm>
 217     </cmd>
 218 </xsl:template>
 219
 220 <xsl:template match="lista_osob">
 221     <cmd name="listaosob">
 222         <parm><xsl:apply-templates select="naglowek_listy" /></parm>
 223         <parm><xsl:apply-templates select="lista_osoba" /></parm>
 224     </cmd>
 225 </xsl:template>
 226
 227 <xsl:template match="kwestia">
 228     <cmd name="kwestia">
 229         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 230     </cmd>
 231 </xsl:template>
 232
 233
 234 <!-- ========================================== -->
 235 <!-- = PARAGRAPH TAGS                         = -->
 236 <!-- = (can contain inline and special tags)  = -->
 237 <!-- ========================================== -->
 238
 239 <!-- only in root -->
 240 <xsl:template
 241     match="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul"
 242     mode="title">
 243     <cmd>
 244         <xsl:attribute name="name">
 245             <xsl:value-of select="wl:texcommand(name())" />
 246         </xsl:attribute>
 247         <parm><xsl:apply-templates mode="inline"/></parm>
 248     </cmd>
 249 </xsl:template>
 250
 251
 252 <xsl:template
 253     match="naglowek_akt|naglowek_czesc|srodtytul|naglowek_osoba|naglowek_podrozdzial|naglowek_scena|naglowek_rozdzial|miejsce_czas|didaskalia|lista_osoba|akap|akap_dialog|akap_cd|motto_podpis|naglowek_listy">
 254     <cmd>
 255         <xsl:attribute name="name">
 256             <xsl:value-of select="wl:texcommand(name())" />
 257         </xsl:attribute>
 258         <parm><xsl:apply-templates mode="inline"/></parm>
 259     </cmd>
 260 </xsl:template>
 261
 262 <xsl:template match="strofa">
 263   <cmd name="strofa"><parm>
 264     <xsl:choose>
 265         <xsl:when test="count(br) > 0">
 266             <xsl:call-template name="verse">
 267                 <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 268                 <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd'][1]" />
 269             </xsl:call-template>
 270             <xsl:for-each select="br">
 271                 <TeXML escape="0">\\{}</TeXML>
 272                 <!-- Each BR tag "consumes" text after it -->
 273                 <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 274                 <xsl:call-template name="verse">
 275                     <xsl:with-param name="verse-content"
 276                         select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 277                     <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd')][1]" />
 278                 </xsl:call-template>
 279             </xsl:for-each>
 280         </xsl:when>
 281         <xsl:otherwise>
 282             <xsl:call-template name="verse">
 283                 <xsl:with-param name="verse-content" select="text() | node()" />
 284                 <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd[1]" />
 285             </xsl:call-template>
 286         </xsl:otherwise>
 287     </xsl:choose>
 288   </parm></cmd>
 289 </xsl:template>
 290
 291
 292 <xsl:template name="verse">
 293     <xsl:param name="verse-content" />
 294     <xsl:param name="verse-type" />
 295
 296     <cmd>
 297         <xsl:attribute name="name">
 298             <xsl:choose>
 299                 <xsl:when test="$verse-type != ''">
 300                     <xsl:value-of select='wl:texcommand(name($verse-type))' />
 301                 </xsl:when>
 302                 <xsl:otherwise>wers</xsl:otherwise>
 303             </xsl:choose>
 304         </xsl:attribute>
 305         <xsl:if test="string($verse-content/@typ)">
 306             <opt><xsl:value-of select="$verse-content/@typ" />em</opt>
 307         </xsl:if>
 308         <parm><xsl:apply-templates select="$verse-content" mode="inline"/></parm>
 309     </cmd>
 310 </xsl:template>
 311
 312 <!-- ================================================ -->
 313 <!-- = INLINE TAGS                                  = -->
 314 <!-- = (contain other inline tags and special tags) = -->
 315 <!-- ================================================ -->
 316
 317 <xsl:template mode="inline"
 318     match="pa|pe|pr|pt|mat|didask_tekst|slowo_obce|wyroznienie|osoba">
 319     <cmd>
 320         <xsl:attribute name="name">
 321             <xsl:value-of select="wl:texcommand(name())" />
 322         </xsl:attribute>
 323         <parm><xsl:apply-templates mode="inline"/></parm>
 324     </cmd>
 325 </xsl:template>
 326
 327
 328
 329 <xsl:template match="tytul_dziela" mode="inline">
 330     <cmd name="tytuldziela"><parm>
 331         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 332     </parm></cmd>
 333 </xsl:template>
 334
 335
 336
 337 <!-- ============================================== -->
 338 <!-- = STANDALONE TAGS                            = -->
 339 <!-- = (cannot contain any other tags)            = -->
 340 <!-- ============================================== -->
 341 <xsl:template
 342     match="sekcja_swiatlo|sekcja_asterysk|separator_linia">
 343     <cmd>
 344         <xsl:attribute name="name">
 345             <xsl:value-of select="wl:texcommand(name())" />
 346         </xsl:attribute>
 347     </cmd>
 348 </xsl:template>
 349
 350
 351 <!-- ================ -->
 352 <!-- = SPECIAL TAGS = -->
 353 <!-- ================ -->
 354 <!-- Themes -->
 355
 356
 357 <xsl:template match="begin|end|motyw">
 358     <xsl:apply-templates select='.' mode="inline" />
 359 </xsl:template>
 360
 361 <xsl:template match="begin" mode="inline" />
 362 <xsl:template match="end" mode="inline" />
 363
 364 <xsl:template match="motyw" mode="inline">
 365     <cmd name="motyw">
 366         <xsl:if test="@moved">
 367             <opt name="moved"><xsl:value-of select="@moved" /></opt>
 368         </xsl:if>
 369         <parm><xsl:apply-templates mode="inline" /></parm>
 370     </cmd>
 371 </xsl:template>
 372
 373 <xsl:template name="authors">
 374     <xsl:for-each select=".//dc:creator_parsed">
 375         <xsl:if test="position() != 1">, </xsl:if>
 376         <xsl:apply-templates mode="inline" />
 377     </xsl:for-each>
 378 </xsl:template>
 379
 380 <xsl:template name="editors">
 381     <xsl:if test="@editors">
 382         <xsl:text>Opracowanie redakcyjne i przypisy: </xsl:text>
 383         <xsl:value-of select="@editors" />
 384         <xsl:text>.</xsl:text>
 385     </xsl:if>
 386 </xsl:template>
 387
 388 <xsl:template name="translators">
 389     <xsl:if test=".//dc:contributor.translator_parsed">
 390         <cmd name='translator'><parm>
 391             <xsl:for-each select=".//dc:contributor.translator_parsed">
 392                 <xsl:if test="position() != 1">, </xsl:if>
 393                 <xsl:apply-templates mode="inline" />
 394             </xsl:for-each>
 395         </parm></cmd>
 396     </xsl:if>
 397 </xsl:template>
 398
 399
 400 <!-- ============== -->
 401 <!-- = ADDED TAGS = -->
 402 <!-- ============== -->
 403
 404
 405 <xsl:template match="dywiz" mode="inline">
 406     <cmd name="dywiz" />
 407 </xsl:template>
 408
 409 <xsl:template match="nbsp" mode="inline">
 410     <spec cat="tilde" />
 411 </xsl:template>
 412
 413 <xsl:template match="alien" mode="inline">
 414     <group>
 415         <cmd name="alien" />
 416         <xsl:apply-templates mode="inline" />
 417     </group>
 418 </xsl:template>
 419
 420 <!-- ================ -->
 421 <!-- = IGNORED TAGS = -->
 422 <!-- ================ -->
 423 <xsl:template match="extra|uwaga" />
 424 <xsl:template match="extra|uwaga" mode="inline" />
 425
 426 <xsl:template match="nota_red" />
 427
 428 <!-- ======== -->
 429 <!-- = TEXT = -->
 430 <!-- ======== -->
 431 <xsl:template match="text()" />
 432 <xsl:template match="text()" mode="inline">
 433     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 434       <xsl:text> </xsl:text>
 435     </xsl:if>
 436
 437     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 438
 439     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 440       <xsl:text> </xsl:text>
 441     </xsl:if>
 442 </xsl:template>
 443
 444
 445 </xsl:stylesheet>