librarian/pdf/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[<xsl:value-of select="@customizations"/>]{wl}
  19
  20         <!-- flags and values set on root -->
  21
  22         \newif\ifflaglessadvertising
  23         <xsl:for-each select="@*[starts-with(name(), 'flag-')]">
  24             <cmd>
  25                 <xsl:attribute name="name"><xsl:value-of select="wl:texcommand(name())" />true</xsl:attribute>
  26             </cmd>
  27         </xsl:for-each>
  28
  29         <xsl:for-each select="@*[starts-with(name(), 'data-')]">
  30             <TeXML escape="0">
  31                 \def\<xsl:value-of select="wl:texcommand(name())" />{<TeXML escape="1"><xsl:value-of select="."/></TeXML>}
  32             </TeXML>
  33         </xsl:for-each>
  34         </TeXML>
  35
  36         <xsl:choose>
  37             <xsl:when test="@morefloats = 'new'">
  38                 <TeXML escape="0">
  39                     \usepackage[maxfloats=53]{morefloats}
  40                 </TeXML>
  41             </xsl:when>
  42             <xsl:when test="@morefloats = 'old'">
  43                 <TeXML escape="0">
  44                     \usepackage{morefloats}
  45                 </TeXML>
  46             </xsl:when>
  47             <xsl:when test="@morefloats = 'none'" />
  48             <xsl:otherwise>
  49                 <TeXML escape="0">
  50                     \IfFileExists{morefloats.sty}{
  51                         \usepackage{morefloats}
  52                     }{}
  53                 </TeXML>
  54             </xsl:otherwise>
  55         </xsl:choose>
  56
  57         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  58         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  59
  60         <env name="document">
  61             <xsl:if test="@data-cover-width">
  62                 <cmd name="makecover">
  63                     <parm>210mm</parm>
  64                     <parm><xsl:value-of select="210 * @data-cover-height div @data-cover-width" />mm</parm>
  65                 </cmd>
  66             </xsl:if>
  67                 <xsl:if test="@thanks">
  68                     <TeXML escape="0">
  69                         \def\thanknote{<TeXML escape="1"><xsl:value-of select="@thanks" /></TeXML>}
  70                     </TeXML>
  71                 </xsl:if>
  72             <cmd name="maketitle" />
  73
  74             <cmd name="tytul"><parm>
  75               <xsl:choose>
  76                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  77                     <!-- title in master -->
  78                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  79                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
  80                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
  81                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
  82                     <!-- dc in master or not -->
  83                     <cmd name="translatorsline" />
  84                 </xsl:when>
  85                 <xsl:otherwise>
  86                     <!-- look for author title in dc -->
  87                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  88                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  89                 </xsl:otherwise>
  90               </xsl:choose>
  91             </parm></cmd>
  92             <xsl:if test="//utwor//utwor or //naglowek_czesc or //naglowek_akt or //srodtytul or //naglowek_scena or //naglowek_rozdzial">
  93                 <cmd name="ifshowtoc" />
  94                 <cmd name="setcounter" >
  95                     <parm>tocdepth</parm>
  96                     <parm>3</parm>
  97                 </cmd>
  98                 <cmd name="tableofcontents" />
  99                 <cmd name="clearpage" />
 100                 <cmd name="fi" />
 101             </xsl:if>
 102             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 103             <xsl:apply-templates select="utwor" mode="part" />
 104
 105             <TeXML escape="0">
 106                 <xsl:if test="@data-cover-by">
 107                 \def\coverby{Okładka na podstawie:
 108                     <xsl:choose>
 109                     <xsl:when test="@data-cover-source">
 110                         \href{\datacoversource}{\datacoverby}
 111                     </xsl:when>
 112                     <xsl:otherwise>
 113                         \datacoverby{}
 114                     </xsl:otherwise>
 115                     </xsl:choose>
 116                 }
 117                 </xsl:if>
 118                 \def\editors{<TeXML escape="1"><xsl:call-template name="editors" /></TeXML>}
 119                 <xsl:if test="@funders">
 120                     \def\funders{Publikację wsparli i wsparły:
 121                         <TeXML escape="1"><xsl:value-of select="@funders" /></TeXML>.}
 122                 </xsl:if>
 123
 124                 <xsl:if test="@sponsor-note|data-sponsor">
 125                     \def\sponsors{
 126                         \scriptsize
 127                         <xsl:choose>
 128                             <xsl:when test="@sponsor-note">
 129                                 <TeXML escape="1"><xsl:value-of select="@sponsor-note" /></TeXML>
 130                             </xsl:when>
 131                             <xsl:otherwise>
 132                                 Sfinansowano ze~środków:
 133                             </xsl:otherwise>
 134                         </xsl:choose>
 135
 136                         \vspace{1em}
 137
 138                         <xsl:apply-templates select="data-sponsor" mode="sponsor" />
 139                     }
 140                 </xsl:if>
 141             </TeXML>
 142
 143             <cmd name="editorialsection" />
 144
 145         </env>
 146     </TeXML>
 147 </xsl:template>
 148
 149 <xsl:template match="utwor" mode="part">
 150     <cmd name="tytul"><parm>
 151       <xsl:choose>
 152         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
 153             <!-- title in master -->
 154             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="part_title" />
 155             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
 156         </xsl:when>
 157         <xsl:otherwise>
 158             <!-- look for title in dc -->
 159             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 160             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
 161         </xsl:otherwise>
 162       </xsl:choose>
 163     </parm></cmd>
 164
 165     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 166     <xsl:apply-templates select="utwor" mode="part" />
 167 </xsl:template>
 168
 169 <!-- =================== -->
 170 <!-- = MAIN TITLE PAGE = -->
 171 <!-- = (from DC)       = -->
 172 <!-- =================== -->
 173
 174 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
 175     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
 176 </xsl:template>
 177
 178 <xsl:template match="rdf:RDF" mode="titlepage">
 179     <TeXML escape="0">
 180         \def\authors{<TeXML escape="1"><xsl:call-template name="authors" /></TeXML>}
 181         \author{\authors}
 182         \title{<TeXML escape="1"><xsl:apply-templates select=".//dc:title" mode="inline" /></TeXML>}
 183         \def\translatorsline{<TeXML escape="1"><xsl:call-template name="translators" /></TeXML>}
 184
 185         \def\bookurl{<TeXML escape="1"><xsl:value-of select=".//dc:identifier.url" /></TeXML>}
 186
 187         \def\rightsinfo{Ten utwór nie jest objęty majątkowym prawem autorskim i~znajduje się w~domenie
 188             publicznej, co oznacza że możesz go swobodnie wykorzystywać, publikować
 189             i~rozpowszechniać. Jeśli utwór opatrzony jest dodatkowymi materiałami
 190             (przypisy, motywy literackie etc.), które podlegają prawu autorskiemu, to
 191             te dodatkowe materiały udostępnione są na licencji
 192             \href{http://creativecommons.org/licenses/by-sa/3.0/}{Creative Commons
 193             Uznanie Autorstwa – Na Tych Samych Warunkach 3.0 PL}.}
 194         <xsl:if test=".//dc:rights.license">
 195             \def\rightsinfo{Ten utwór jest udostępniony na licencji
 196             \href{<xsl:value-of select=".//dc:rights.license" />}{<TeXML escape="1"><xsl:apply-templates select=".//dc:rights" mode="inline" /></TeXML>}.}
 197         </xsl:if>
 198
 199         \def\sourceinfo{
 200             <xsl:if test=".//dc:source">
 201                 Tekst opracowany na podstawie: <TeXML escape="1"><xsl:apply-templates select=".//dc:source" mode="inline" /></TeXML>
 202                 \vspace{.6em}
 203             </xsl:if>}
 204         \def\publisherinfo{
 205             <xsl:if test=".//dc:publisher">
 206                 Wydawca:
 207                 <TeXML escape="1">
 208                     <xsl:for-each select=".//dc:publisher/text()">
 209                         <xsl:value-of select="."/>
 210                         <xsl:if test="not(position() = last())">, </xsl:if>
 211                     </xsl:for-each>
 212                 </TeXML>
 213                 \vspace{.6em}
 214             </xsl:if>}
 215         \def\description{<TeXML escape="1"><xsl:apply-templates select=".//dc:description" mode="inline" /></TeXML>}
 216         <xsl:if test=".//meta[@id='pdf-id']">
 217             <xsl:variable name="isbn" select=".//meta[@id='pdf-id']"/>
 218             \def\isbn{ISBN <xsl:value-of select="substring-after($isbn, 'ISBN-')"/>}
 219         </xsl:if>
 220     </TeXML>
 221 </xsl:template>
 222
 223
 224 <!-- ============== -->
 225 <!-- = BOOK TITLE = -->
 226 <!-- = (from DC)  = -->
 227 <!-- ============== -->
 228
 229 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
 230     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 231 </xsl:template>
 232
 233 <xsl:template match="rdf:RDF" mode="dctitle">
 234     <xsl:if test="../../rdf:RDF//use_subauthor">
 235         <cmd name="autorpodutworu">
 236             <parm><xsl:call-template name="authors" /></parm>
 237         </cmd>
 238     </xsl:if>
 239     <cmd name="nazwanadpodutworu"><parm>
 240         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 241     </parm>
 242     <parm>
 243         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 244     </parm></cmd>
 245 </xsl:template>
 246
 247 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
 248     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
 249 </xsl:template>
 250
 251 <xsl:template match="rdf:RDF" mode="firstdctitle">
 252     <cmd name="autorutworu"><parm><cmd name="authors"/></parm></cmd>
 253     <cmd name="nazwautworu"><parm>
 254         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 255     </parm></cmd>
 256     <cmd name="translatorsline" />
 257 </xsl:template>
 258
 259
 260 <!-- ============================================================================== -->
 261 <!-- = MASTER TAG                                                                 = -->
 262 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 263 <!-- ============================================================================== -->
 264 <!-- ==================================================================================== -->
 265 <!-- = BLOCK TAGS                                                                       = -->
 266 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 267 <!-- ==================================================================================== -->
 268
 269 <xsl:template
 270     match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny|nota|dedykacja|dlugi_cytat|poezja_cyt|motto|ramka">
 271     <cmd>
 272         <xsl:attribute name="name">
 273             <xsl:value-of select="wl:texcommand(name())" />
 274         </xsl:attribute>
 275         <parm><xsl:apply-templates/></parm>
 276     </cmd>
 277 </xsl:template>
 278
 279 <xsl:template match="lista_osob">
 280     <cmd name="listaosob">
 281         <parm><xsl:apply-templates select="naglowek_listy" /></parm>
 282         <parm><xsl:apply-templates select="lista_osoba" /></parm>
 283     </cmd>
 284 </xsl:template>
 285
 286 <xsl:template match="kwestia">
 287     <cmd name="kwestia">
 288         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 289     </cmd>
 290 </xsl:template>
 291
 292 <xsl:template match="ilustr">
 293     <cmd name="ilustr">
 294         <parm><xsl:value-of select="@src" /></parm>
 295         <parm><xsl:value-of select="@alt" /></parm>
 296     </cmd>
 297 </xsl:template>
 298
 299 <!-- ========================================== -->
 300 <!-- = PARAGRAPH TAGS                         = -->
 301 <!-- = (can contain inline and special tags)  = -->
 302 <!-- ========================================== -->
 303
 304 <!-- only in root -->
 305 <xsl:template
 306     match="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul"
 307     mode="title">
 308     <cmd>
 309         <xsl:attribute name="name">
 310             <xsl:value-of select="wl:texcommand(name())" />
 311         </xsl:attribute>
 312         <parm><xsl:apply-templates mode="inline"/></parm>
 313     </cmd>
 314 </xsl:template>
 315
 316 <xsl:template match="nazwa_utworu" mode="part_title">
 317     <xsl:if test="../../rdf:RDF//use_subauthor">
 318         <cmd name="autorpodutworu"><parm><xsl:call-template name="authors2"/></parm></cmd>
 319     </xsl:if>
 320     <cmd name="nazwapodutworu">
 321         <parm><xsl:apply-templates mode="inline"/></parm>
 322         <parm>
 323             <xsl:for-each select="./text() | nbsp | dywiz | alien | slowo_obce">
 324                 <xsl:choose>
 325                     <xsl:when test="name() = 'nbsp'">
 326                         <xsl:text> </xsl:text>
 327                     </xsl:when>
 328                     <xsl:when test="name() = 'dywiz'">
 329                         <xsl:text>-</xsl:text>
 330                     </xsl:when>
 331                     <xsl:when test="name() = 'alien' or name() = 'slowo_obce'">
 332                         <xsl:apply-templates mode="inline" />
 333                     </xsl:when>
 334                     <xsl:otherwise>
 335                         <xsl:value-of select="."/>
 336                     </xsl:otherwise>
 337                 </xsl:choose>
 338             </xsl:for-each>
 339         </parm>
 340     </cmd>
 341 </xsl:template>
 342
 343
 344 <xsl:template
 345     match="naglowek_osoba|naglowek_podrozdzial|miejsce_czas|didaskalia|lista_osoba|akap|akap_diafrlog|akap_cd|motto_podpis|naglowek_listy|srodtytul">
 346     <cmd>
 347         <xsl:attribute name="name">
 348             <xsl:value-of select="wl:texcommand(name())" />
 349         </xsl:attribute>
 350         <parm><xsl:apply-templates mode="inline"/></parm>
 351     </cmd>
 352 </xsl:template>
 353
 354 <xsl:template match="naglowek_czesc|naglowek_rozdzial|naglowek_akt|naglowek_scena">
 355     <cmd>
 356         <xsl:attribute name="name">
 357             <xsl:value-of select="wl:texcommand(name())" />
 358         </xsl:attribute>
 359         <parm><xsl:apply-templates mode="inline"/></parm>
 360         <parm>
 361             <!-- osobny szablon? -->
 362             <xsl:for-each select="./text() | nbsp | dywiz | alien | slowo_obce">
 363                 <xsl:choose>
 364                     <xsl:when test="name() = 'nbsp'">
 365                         <xsl:text> </xsl:text>
 366                     </xsl:when>
 367                     <xsl:when test="name() = 'dywiz'">
 368                         <xsl:text>-</xsl:text>
 369                     </xsl:when>
 370                     <xsl:when test="name() = 'alien'">
 371                         <xsl:apply-templates mode="inline" />
 372                     </xsl:when>
 373                     <xsl:when test="name() = 'slowo_obce'">
 374                         <cmd name="slowoobce">
 375                             <parm><xsl:value-of select="text()"/></parm>
 376                         </cmd>
 377                     </xsl:when>
 378                     <xsl:otherwise>
 379                         <xsl:value-of select="."/>
 380                     </xsl:otherwise>
 381                 </xsl:choose>
 382             </xsl:for-each>
 383         </parm>
 384     </cmd>
 385 </xsl:template>
 386
 387 <xsl:template match="strofa" mode="inline">
 388     <env name="minipage">
 389         <opt>t</opt>
 390         <parm><cmd name="linewidth" /></parm>
 391         <parm><xsl:apply-templates select="." /></parm>
 392     </env>
 393 </xsl:template>
 394
 395 <xsl:template match="strofa">
 396   <cmd name="strofa"><parm>
 397     <xsl:choose>
 398         <xsl:when test="count(br) > 0">
 399             <xsl:call-template name="verse">
 400                 <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 401                 <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd' or name() = 'wers_do_prawej'][1]" />
 402             </xsl:call-template>
 403             <xsl:for-each select="br">
 404                 <TeXML escape="0">\\{}</TeXML>
 405                 <!-- Each BR tag "consumes" text after it -->
 406                 <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 407                 <xsl:call-template name="verse">
 408                     <xsl:with-param name="verse-content"
 409                         select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 410                     <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd' or name() = 'wers_do_prawej')][1]" />
 411                 </xsl:call-template>
 412             </xsl:for-each>
 413         </xsl:when>
 414         <xsl:otherwise>
 415             <xsl:call-template name="verse">
 416                 <xsl:with-param name="verse-content" select="text() | node()" />
 417                 <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd|wers_do_prawej[1]" />
 418             </xsl:call-template>
 419         </xsl:otherwise>
 420     </xsl:choose>
 421   </parm></cmd>
 422 </xsl:template>
 423
 424
 425 <xsl:template name="verse">
 426     <xsl:param name="verse-content" />
 427     <xsl:param name="verse-type" />
 428
 429     <cmd>
 430         <xsl:attribute name="name">
 431             <xsl:choose>
 432                 <xsl:when test="$verse-type != ''">
 433                     <xsl:value-of select='wl:texcommand(name($verse-type))' />
 434                 </xsl:when>
 435                 <xsl:otherwise>wers</xsl:otherwise>
 436             </xsl:choose>
 437         </xsl:attribute>
 438         <xsl:if test="string($verse-content/@typ)">
 439             <opt><xsl:value-of select="$verse-content/@typ" />em</opt>
 440         </xsl:if>
 441         <parm><xsl:apply-templates select="$verse-content" mode="inline"/></parm>
 442     </cmd>
 443 </xsl:template>
 444
 445 <!-- ================================================ -->
 446 <!-- = INLINE TAGS                                  = -->
 447 <!-- = (contain other inline tags and special tags) = -->
 448 <!-- ================================================ -->
 449
 450 <xsl:template mode="inline"
 451     match="pa|pe|pr|pt|mat|didask_tekst|slowo_obce|wyroznienie|osoba|indeks_dolny|wieksze_odstepy">
 452     <cmd>
 453         <xsl:attribute name="name">
 454             <xsl:value-of select="wl:texcommand(name())" />
 455         </xsl:attribute>
 456         <parm><xsl:apply-templates mode="inline"/></parm>
 457     </cmd>
 458 </xsl:template>
 459
 460
 461
 462 <xsl:template match="tytul_dziela" mode="inline">
 463     <cmd name="tytuldziela"><parm>
 464         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 465     </parm></cmd>
 466 </xsl:template>
 467
 468
 469
 470 <!-- ============================================== -->
 471 <!-- = STANDALONE TAGS                            = -->
 472 <!-- = (cannot contain any other tags)            = -->
 473 <!-- ============================================== -->
 474 <xsl:template
 475     match="sekcja_swiatlo|sekcja_asterysk|separator_linia">
 476     <cmd>
 477         <xsl:attribute name="name">
 478             <xsl:value-of select="wl:texcommand(name())" />
 479         </xsl:attribute>
 480     </cmd>
 481 </xsl:template>
 482
 483
 484 <!-- ================ -->
 485 <!-- = SPECIAL TAGS = -->
 486 <!-- ================ -->
 487 <!-- Themes -->
 488
 489
 490 <xsl:template match="begin|end|motyw">
 491     <xsl:apply-templates select='.' mode="inline" />
 492 </xsl:template>
 493
 494 <xsl:template match="begin" mode="inline" />
 495 <xsl:template match="end" mode="inline" />
 496
 497 <xsl:template match="motyw" mode="inline">
 498     <cmd name="motyw">
 499         <xsl:if test="@moved">
 500             <opt name="moved"><xsl:value-of select="@moved" /></opt>
 501         </xsl:if>
 502         <parm><xsl:apply-templates mode="inline" /></parm>
 503     </cmd>
 504 </xsl:template>
 505
 506 <xsl:template name="authors">
 507     <xsl:for-each select=".//dc:creator_parsed">
 508         <xsl:if test="position() != 1">, </xsl:if>
 509         <xsl:apply-templates mode="inline" />
 510     </xsl:for-each>
 511 </xsl:template>
 512
 513 <xsl:template name="authors2">
 514     <xsl:for-each select="../..//dc:creator_parsed">
 515         <xsl:if test="position() != 1">, </xsl:if>
 516         <xsl:apply-templates mode="inline" />
 517     </xsl:for-each>
 518 </xsl:template>
 519
 520 <xsl:template name="editors">
 521     <xsl:if test="@editors">
 522         <xsl:text>Opracowanie redakcyjne i przypisy: </xsl:text>
 523         <xsl:value-of select="@editors" />
 524         <xsl:text>.</xsl:text>
 525     </xsl:if>
 526 </xsl:template>
 527
 528 <xsl:template name="translators">
 529     <xsl:if test=".//dc:contributor.translator_parsed">
 530         <cmd name='translator'><parm>
 531             <xsl:for-each select=".//dc:contributor.translator_parsed">
 532                 <xsl:if test="position() != 1">, </xsl:if>
 533                 <xsl:apply-templates mode="inline" />
 534             </xsl:for-each>
 535         </parm></cmd>
 536     </xsl:if>
 537 </xsl:template>
 538
 539 <xsl:template match="data-sponsor" mode="sponsor">
 540     <cmd name="par"><parm>
 541     <xsl:choose>
 542         <xsl:when test="@src">
 543             \includegraphics[height=0.25\textwidth,width=0.25\textwidth,keepaspectratio]{<xsl:value-of select="@src" />}
 544         </xsl:when>
 545         <xsl:otherwise>
 546             <xsl:value-of select="@name" />
 547         </xsl:otherwise>
 548     </xsl:choose>
 549     </parm></cmd>
 550 </xsl:template>
 551
 552 <xsl:template match="mat" mode="inline">
 553     <TeXML escape="0">
 554         <xsl:text>$</xsl:text>
 555         <xsl:value-of select="wl:mathml_latex(.)" />
 556         <xsl:text>$</xsl:text>
 557     </TeXML>
 558 </xsl:template>
 559
 560 <xsl:template match="mat">
 561     <TeXML escape="0">
 562         <xsl:text>$$</xsl:text>
 563         <xsl:value-of select="wl:mathml_latex(.)" />
 564         <xsl:text>$$</xsl:text>
 565     </TeXML>
 566 </xsl:template>
 567
 568 <xsl:template match="tabela|tabelka">
 569     <cmd name="par" />
 570     <cmd name="vspace"><parm>1em</parm></cmd>
 571     <group><cmd name="raggedright" />
 572     <xsl:element name="env">
 573         <xsl:attribute name="name">
 574             <xsl:choose>
 575                 <xsl:when test="name(.)='tabela'">longtabu</xsl:when>
 576                 <xsl:otherwise>tabu</xsl:otherwise>
 577             </xsl:choose>
 578         </xsl:attribute> to <TeXML escape="0">\textwidth </TeXML>
 579       <!--parm><cmd name="textwidth"/></parm-->
 580       <parm><TeXML escape="0"><xsl:value-of select="@_format" /></TeXML></parm>
 581         <xsl:choose>
 582         <xsl:when test="@ramka='1' or @ramki='1'">
 583           <cmd name="hline" />
 584           <xsl:apply-templates mode="wiersze-ramki"/>
 585         </xsl:when>
 586         <xsl:otherwise>
 587           <xsl:apply-templates/>
 588         </xsl:otherwise>
 589         </xsl:choose>
 590     </xsl:element>
 591     </group>
 592     <cmd name="vspace"><parm>1em</parm></cmd>
 593 </xsl:template>
 594 <xsl:template match="wiersz" mode="wiersze-ramki">
 595     <xsl:apply-templates />
 596     <spec cat="esc"/><spec cat="esc"/>
 597     <cmd name="hline" gr="0" />
 598 </xsl:template>
 599 <xsl:template match="wiersz">
 600     <xsl:apply-templates />
 601     <spec cat="esc"/><spec cat="esc"/>
 602 </xsl:template>
 603 <xsl:template match="kol">
 604     <xsl:apply-templates mode="inline"/>
 605     <xsl:if test="position() &lt; last()">
 606     <spec cat="align"/>
 607     </xsl:if>
 608 </xsl:template>
 609
 610
 611 <!-- ============== -->
 612 <!-- = ADDED TAGS = -->
 613 <!-- ============== -->
 614
 615
 616 <xsl:template match="dywiz" mode="inline">
 617     <cmd name="dywiz" />
 618 </xsl:template>
 619
 620 <xsl:template match="nbsp" mode="inline">
 621     <spec cat="tilde" />
 622 </xsl:template>
 623
 624 <xsl:template match="alien" mode="inline">
 625     <group>
 626         <cmd name="alien" />
 627         <xsl:apply-templates mode="inline" />
 628     </group>
 629 </xsl:template>
 630
 631 <!-- ================ -->
 632 <!-- = IGNORED TAGS = -->
 633 <!-- ================ -->
 634 <xsl:template match="extra|uwaga" />
 635 <xsl:template match="extra|uwaga" mode="inline" />
 636
 637 <xsl:template match="nota_red" />
 638 <xsl:template match="abstrakt" />
 639
 640 <!-- ======== -->
 641 <!-- = TEXT = -->
 642 <!-- ======== -->
 643 <xsl:template match="text()" />
 644 <xsl:template match="text()" mode="inline">
 645     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 646       <xsl:text> </xsl:text>
 647     </xsl:if>
 648
 649     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 650
 651     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 652       <xsl:text> </xsl:text>
 653     </xsl:if>
 654 </xsl:template>
 655
 656
 657 </xsl:stylesheet>