librarian/pdf/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[<xsl:value-of select="@customizations"/>]{wl}
  19
  20         <!-- flags and values set on root -->
  21
  22         \newif\ifflaglessadvertising
  23         <xsl:for-each select="@*[starts-with(name(), 'flag-')]">
  24             <cmd>
  25                 <xsl:attribute name="name"><xsl:value-of select="wl:texcommand(name())" />true</xsl:attribute>
  26             </cmd>
  27         </xsl:for-each>
  28
  29         <xsl:for-each select="@*[starts-with(name(), 'data-')]">
  30             <TeXML escape="0">
  31                 \def\<xsl:value-of select="wl:texcommand(name())" />{<TeXML escape="1"><xsl:value-of select="."/></TeXML>}
  32             </TeXML>
  33         </xsl:for-each>
  34         </TeXML>
  35
  36         <xsl:choose>
  37             <xsl:when test="@morefloats = 'new'">
  38                 <TeXML escape="0">
  39                     \usepackage[maxfloats=53]{morefloats}
  40                 </TeXML>
  41             </xsl:when>
  42             <xsl:when test="@morefloats = 'old'">
  43                 <TeXML escape="0">
  44                     \usepackage{morefloats}
  45                 </TeXML>
  46             </xsl:when>
  47             <xsl:when test="@morefloats = 'none'" />
  48             <xsl:otherwise>
  49                 <TeXML escape="0">
  50                     \IfFileExists{morefloats.sty}{
  51                         \usepackage{morefloats}
  52                     }{}
  53                 </TeXML>
  54             </xsl:otherwise>
  55         </xsl:choose>
  56
  57         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  58         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  59
  60         <env name="document">
  61             <xsl:if test="@data-cover-width">
  62                 <cmd name="makecover">
  63                     <parm>210mm</parm>
  64                     <parm><xsl:value-of select="210 * @data-cover-height div @data-cover-width" />mm</parm>
  65                 </cmd>
  66             </xsl:if>
  67                 <xsl:if test="@thanks">
  68                     <TeXML escape="0">
  69                         \def\thanknote{<TeXML escape="1"><xsl:value-of select="@thanks" /></TeXML>}
  70                     </TeXML>
  71                 </xsl:if>
  72             <cmd name="maketitle" />
  73
  74             <cmd name="tytul"><parm>
  75               <xsl:choose>
  76                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  77                     <!-- title in master -->
  78                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  79                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
  80                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
  81                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
  82                     <!-- dc in master or not -->
  83                     <cmd name="translatorsline" />
  84                 </xsl:when>
  85                 <xsl:otherwise>
  86                     <!-- look for author title in dc -->
  87                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  88                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  89                 </xsl:otherwise>
  90               </xsl:choose>
  91             </parm></cmd>
  92             <xsl:if test="//utwor//utwor or //naglowek_czesc or //naglowek_akt or //srodtytul or //naglowek_scena or //naglowek_rozdzial">
  93                 <cmd name="ifshowtoc" />
  94                 <cmd name="setcounter" >
  95                     <parm>tocdepth</parm>
  96                     <parm>3</parm>
  97                 </cmd>
  98                 <cmd name="tableofcontents" />
  99                 <cmd name="clearpage" />
 100                 <cmd name="fi" />
 101             </xsl:if>
 102             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 103             <xsl:apply-templates select="utwor" mode="part" />
 104
 105             <TeXML escape="0">
 106                 <xsl:if test="@data-cover-by">
 107                 \def\coverby{Okładka na podstawie:
 108                     <xsl:choose>
 109                     <xsl:when test="@data-cover-source">
 110                         \href{\datacoversource}{\datacoverby}
 111                     </xsl:when>
 112                     <xsl:otherwise>
 113                         \datacoverby{}
 114                     </xsl:otherwise>
 115                     </xsl:choose>
 116                 }
 117                 </xsl:if>
 118                 \def\editors{<TeXML escape="1"><xsl:call-template name="editors" /></TeXML>}
 119                 <xsl:if test="@funders">
 120                     \def\funders{Publikację wsparli i wsparły:
 121                         <TeXML escape="1"><xsl:value-of select="@funders" /></TeXML>.}
 122                 </xsl:if>
 123
 124                 <xsl:if test="@sponsor-note|data-sponsor">
 125                     \def\sponsors{
 126                         \scriptsize
 127                         <xsl:choose>
 128                             <xsl:when test="@sponsor-note">
 129                                 <TeXML escape="1"><xsl:value-of select="@sponsor-note" /></TeXML>
 130                             </xsl:when>
 131                             <xsl:otherwise>
 132                                 Sfinansowano ze~środków:
 133                             </xsl:otherwise>
 134                         </xsl:choose>
 135
 136                         \vspace{1em}
 137
 138                         <xsl:apply-templates select="data-sponsor" mode="sponsor" />
 139                     }
 140                 </xsl:if>
 141             </TeXML>
 142
 143             <cmd name="editorialsection" />
 144
 145         </env>
 146     </TeXML>
 147 </xsl:template>
 148
 149 <xsl:template match="utwor" mode="part">
 150     <cmd name="tytul"><parm>
 151       <xsl:choose>
 152         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
 153             <!-- title in master -->
 154             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="part_title" />
 155             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
 156         </xsl:when>
 157         <xsl:otherwise>
 158             <!-- look for title in dc -->
 159             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 160             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
 161         </xsl:otherwise>
 162       </xsl:choose>
 163     </parm></cmd>
 164
 165     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 166     <xsl:apply-templates select="utwor" mode="part" />
 167 </xsl:template>
 168
 169 <!-- =================== -->
 170 <!-- = MAIN TITLE PAGE = -->
 171 <!-- = (from DC)       = -->
 172 <!-- =================== -->
 173
 174 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
 175     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
 176 </xsl:template>
 177
 178 <xsl:template match="rdf:RDF" mode="titlepage">
 179     <TeXML escape="0">
 180         \def\authors{<TeXML escape="1"><xsl:call-template name="authors" /></TeXML>}
 181         \author{\authors}
 182         \title{<TeXML escape="1"><xsl:apply-templates select=".//dc:title" mode="inline" /></TeXML>}
 183         \def\translatorsline{<TeXML escape="1"><xsl:call-template name="translators" /></TeXML>}
 184
 185         \def\bookurl{<TeXML escape="1"><xsl:value-of select=".//dc:identifier.url" /></TeXML>}
 186
 187         \def\rightsinfo{Ten utwór nie jest objęty majątkowym prawem autorskim i~znajduje się w~domenie
 188             publicznej, co oznacza że możesz go swobodnie wykorzystywać, publikować
 189             i~rozpowszechniać. Jeśli utwór opatrzony jest dodatkowymi materiałami
 190             (przypisy, motywy literackie etc.), które podlegają prawu autorskiemu, to
 191             te dodatkowe materiały udostępnione są na licencji
 192             \href{http://creativecommons.org/licenses/by-sa/3.0/}{Creative Commons
 193             Uznanie Autorstwa – Na Tych Samych Warunkach 3.0 PL}.}
 194         <xsl:if test=".//dc:rights.license">
 195             \def\rightsinfo{Ten utwór jest udostępniony na licencji
 196             \href{<xsl:value-of select=".//dc:rights.license" />}{<TeXML escape="1"><xsl:apply-templates select=".//dc:rights" mode="inline" /></TeXML>}.}
 197         </xsl:if>
 198
 199         \def\sourceinfo{
 200             <xsl:if test=".//dc:source">
 201                 Tekst opracowany na podstawie: <TeXML escape="1"><xsl:apply-templates select=".//dc:source" mode="inline" /></TeXML>
 202                 \vspace{.6em}
 203             </xsl:if>}
 204         \def\publisherinfo{
 205             <xsl:if test=".//dc:publisher">
 206                 Wydawca:
 207                 <TeXML escape="1">
 208                     <xsl:for-each select=".//dc:publisher/text()">
 209                         <xsl:value-of select="."/>
 210                         <xsl:if test="not(position() = last())">, </xsl:if>
 211                     </xsl:for-each>
 212                 </TeXML>
 213                 \vspace{.6em}
 214             </xsl:if>}
 215         \def\description{<TeXML escape="1"><xsl:apply-templates select=".//dc:description" mode="inline" /></TeXML>}
 216         <xsl:if test=".//meta[@id='pdf-id']">
 217             <xsl:variable name="isbn" select=".//meta[@id='pdf-id']"/>
 218             \def\isbn{ISBN <xsl:value-of select="substring-after($isbn, 'ISBN-')"/>}
 219         </xsl:if>
 220     </TeXML>
 221 </xsl:template>
 222
 223
 224 <!-- ============== -->
 225 <!-- = BOOK TITLE = -->
 226 <!-- = (from DC)  = -->
 227 <!-- ============== -->
 228
 229 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
 230     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 231 </xsl:template>
 232
 233 <xsl:template match="rdf:RDF" mode="dctitle">
 234     <cmd name="autorpodutworu">
 235         <parm><xsl:call-template name="authors" /></parm>
 236     </cmd>
 237     <cmd name="nazwapodutworu"><parm>
 238         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 239     </parm></cmd>
 240 </xsl:template>
 241
 242 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
 243     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
 244 </xsl:template>
 245
 246 <xsl:template match="rdf:RDF" mode="firstdctitle">
 247     <cmd name="autorutworu"><parm><cmd name="authors"/></parm></cmd>
 248     <cmd name="nazwautworu"><parm>
 249         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 250     </parm></cmd>
 251     <cmd name="translatorsline" />
 252 </xsl:template>
 253
 254
 255 <!-- ============================================================================== -->
 256 <!-- = MASTER TAG                                                                 = -->
 257 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 258 <!-- ============================================================================== -->
 259 <!-- ==================================================================================== -->
 260 <!-- = BLOCK TAGS                                                                       = -->
 261 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 262 <!-- ==================================================================================== -->
 263
 264 <xsl:template
 265     match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny|nota|dedykacja|dlugi_cytat|poezja_cyt|motto|ramka">
 266     <cmd>
 267         <xsl:attribute name="name">
 268             <xsl:value-of select="wl:texcommand(name())" />
 269         </xsl:attribute>
 270         <parm><xsl:apply-templates/></parm>
 271     </cmd>
 272 </xsl:template>
 273
 274 <xsl:template match="lista_osob">
 275     <cmd name="listaosob">
 276         <parm><xsl:apply-templates select="naglowek_listy" /></parm>
 277         <parm><xsl:apply-templates select="lista_osoba" /></parm>
 278     </cmd>
 279 </xsl:template>
 280
 281 <xsl:template match="kwestia">
 282     <cmd name="kwestia">
 283         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 284     </cmd>
 285 </xsl:template>
 286
 287 <xsl:template match="ilustr">
 288     <cmd name="ilustr">
 289         <parm><xsl:value-of select="@src" /></parm>
 290         <parm><xsl:value-of select="@alt" /></parm>
 291     </cmd>
 292 </xsl:template>
 293
 294 <!-- ========================================== -->
 295 <!-- = PARAGRAPH TAGS                         = -->
 296 <!-- = (can contain inline and special tags)  = -->
 297 <!-- ========================================== -->
 298
 299 <!-- only in root -->
 300 <xsl:template
 301     match="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul"
 302     mode="title">
 303     <cmd>
 304         <xsl:attribute name="name">
 305             <xsl:value-of select="wl:texcommand(name())" />
 306         </xsl:attribute>
 307         <parm><xsl:apply-templates mode="inline"/></parm>
 308     </cmd>
 309 </xsl:template>
 310
 311 <xsl:template match="nazwa_utworu" mode="part_title">
 312     <xsl:if test="../../rdf:RDF//use_subauthor">
 313         <cmd name="autorpodutworu"><parm><xsl:call-template name="authors2"/></parm></cmd>
 314     </xsl:if>
 315     <cmd name="nazwapodutworu">
 316         <parm><xsl:apply-templates mode="inline"/></parm>
 317         <parm>
 318             <xsl:for-each select="./text() | nbsp | dywiz | alien">
 319                 <xsl:choose>
 320                     <xsl:when test="name() = 'nbsp'">
 321                         <xsl:text> </xsl:text>
 322                     </xsl:when>
 323                     <xsl:when test="name() = 'dywiz'">
 324                         <xsl:text>-</xsl:text>
 325                     </xsl:when>
 326                     <xsl:when test="name() = 'alien'">
 327                         <xsl:apply-templates mode="inline" />
 328                     </xsl:when>
 329                     <xsl:otherwise>
 330                         <xsl:value-of select="."/>
 331                     </xsl:otherwise>
 332                 </xsl:choose>
 333             </xsl:for-each>
 334         </parm>
 335     </cmd>
 336 </xsl:template>
 337
 338
 339 <xsl:template
 340     match="naglowek_osoba|naglowek_podrozdzial|miejsce_czas|didaskalia|lista_osoba|akap|akap_diafrlog|akap_cd|motto_podpis|naglowek_listy|srodtytul">
 341     <cmd>
 342         <xsl:attribute name="name">
 343             <xsl:value-of select="wl:texcommand(name())" />
 344         </xsl:attribute>
 345         <parm><xsl:apply-templates mode="inline"/></parm>
 346     </cmd>
 347 </xsl:template>
 348
 349 <xsl:template match="naglowek_czesc|naglowek_rozdzial|naglowek_akt|naglowek_scena">
 350     <cmd>
 351         <xsl:attribute name="name">
 352             <xsl:value-of select="wl:texcommand(name())" />
 353         </xsl:attribute>
 354         <parm><xsl:apply-templates mode="inline"/></parm>
 355         <parm>
 356             <xsl:for-each select="./text()">
 357                 <xsl:value-of select="."/>
 358             </xsl:for-each>
 359         </parm>
 360     </cmd>
 361 </xsl:template>
 362
 363 <xsl:template match="strofa" mode="inline">
 364     <env name="minipage">
 365         <opt>t</opt>
 366         <parm><cmd name="linewidth" /></parm>
 367         <parm><xsl:apply-templates select="." /></parm>
 368     </env>
 369 </xsl:template>
 370
 371 <xsl:template match="strofa">
 372   <cmd name="strofa"><parm>
 373     <xsl:choose>
 374         <xsl:when test="count(br) > 0">
 375             <xsl:call-template name="verse">
 376                 <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 377                 <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd' or name() = 'wers_do_prawej'][1]" />
 378             </xsl:call-template>
 379             <xsl:for-each select="br">
 380                 <TeXML escape="0">\\{}</TeXML>
 381                 <!-- Each BR tag "consumes" text after it -->
 382                 <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 383                 <xsl:call-template name="verse">
 384                     <xsl:with-param name="verse-content"
 385                         select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 386                     <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd' or name() = 'wers_do_prawej')][1]" />
 387                 </xsl:call-template>
 388             </xsl:for-each>
 389         </xsl:when>
 390         <xsl:otherwise>
 391             <xsl:call-template name="verse">
 392                 <xsl:with-param name="verse-content" select="text() | node()" />
 393                 <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd|wers_do_prawej[1]" />
 394             </xsl:call-template>
 395         </xsl:otherwise>
 396     </xsl:choose>
 397   </parm></cmd>
 398 </xsl:template>
 399
 400
 401 <xsl:template name="verse">
 402     <xsl:param name="verse-content" />
 403     <xsl:param name="verse-type" />
 404
 405     <cmd>
 406         <xsl:attribute name="name">
 407             <xsl:choose>
 408                 <xsl:when test="$verse-type != ''">
 409                     <xsl:value-of select='wl:texcommand(name($verse-type))' />
 410                 </xsl:when>
 411                 <xsl:otherwise>wers</xsl:otherwise>
 412             </xsl:choose>
 413         </xsl:attribute>
 414         <xsl:if test="string($verse-content/@typ)">
 415             <opt><xsl:value-of select="$verse-content/@typ" />em</opt>
 416         </xsl:if>
 417         <parm><xsl:apply-templates select="$verse-content" mode="inline"/></parm>
 418     </cmd>
 419 </xsl:template>
 420
 421 <!-- ================================================ -->
 422 <!-- = INLINE TAGS                                  = -->
 423 <!-- = (contain other inline tags and special tags) = -->
 424 <!-- ================================================ -->
 425
 426 <xsl:template mode="inline"
 427     match="pa|pe|pr|pt|mat|didask_tekst|slowo_obce|wyroznienie|osoba|indeks_dolny|wieksze_odstepy">
 428     <cmd>
 429         <xsl:attribute name="name">
 430             <xsl:value-of select="wl:texcommand(name())" />
 431         </xsl:attribute>
 432         <parm><xsl:apply-templates mode="inline"/></parm>
 433     </cmd>
 434 </xsl:template>
 435
 436
 437
 438 <xsl:template match="tytul_dziela" mode="inline">
 439     <cmd name="tytuldziela"><parm>
 440         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 441     </parm></cmd>
 442 </xsl:template>
 443
 444
 445
 446 <!-- ============================================== -->
 447 <!-- = STANDALONE TAGS                            = -->
 448 <!-- = (cannot contain any other tags)            = -->
 449 <!-- ============================================== -->
 450 <xsl:template
 451     match="sekcja_swiatlo|sekcja_asterysk|separator_linia">
 452     <cmd>
 453         <xsl:attribute name="name">
 454             <xsl:value-of select="wl:texcommand(name())" />
 455         </xsl:attribute>
 456     </cmd>
 457 </xsl:template>
 458
 459
 460 <!-- ================ -->
 461 <!-- = SPECIAL TAGS = -->
 462 <!-- ================ -->
 463 <!-- Themes -->
 464
 465
 466 <xsl:template match="begin|end|motyw">
 467     <xsl:apply-templates select='.' mode="inline" />
 468 </xsl:template>
 469
 470 <xsl:template match="begin" mode="inline" />
 471 <xsl:template match="end" mode="inline" />
 472
 473 <xsl:template match="motyw" mode="inline">
 474     <cmd name="motyw">
 475         <xsl:if test="@moved">
 476             <opt name="moved"><xsl:value-of select="@moved" /></opt>
 477         </xsl:if>
 478         <parm><xsl:apply-templates mode="inline" /></parm>
 479     </cmd>
 480 </xsl:template>
 481
 482 <xsl:template name="authors">
 483     <xsl:for-each select=".//dc:creator_parsed">
 484         <xsl:if test="position() != 1">, </xsl:if>
 485         <xsl:apply-templates mode="inline" />
 486     </xsl:for-each>
 487 </xsl:template>
 488
 489 <xsl:template name="authors2">
 490     <xsl:for-each select="../..//dc:creator_parsed">
 491         <xsl:if test="position() != 1">, </xsl:if>
 492         <xsl:apply-templates mode="inline" />
 493     </xsl:for-each>
 494 </xsl:template>
 495
 496 <xsl:template name="editors">
 497     <xsl:if test="@editors">
 498         <xsl:text>Opracowanie redakcyjne i przypisy: </xsl:text>
 499         <xsl:value-of select="@editors" />
 500         <xsl:text>.</xsl:text>
 501     </xsl:if>
 502 </xsl:template>
 503
 504 <xsl:template name="translators">
 505     <xsl:if test=".//dc:contributor.translator_parsed">
 506         <cmd name='translator'><parm>
 507             <xsl:for-each select=".//dc:contributor.translator_parsed">
 508                 <xsl:if test="position() != 1">, </xsl:if>
 509                 <xsl:apply-templates mode="inline" />
 510             </xsl:for-each>
 511         </parm></cmd>
 512     </xsl:if>
 513 </xsl:template>
 514
 515 <xsl:template match="data-sponsor" mode="sponsor">
 516     <cmd name="par"><parm>
 517     <xsl:choose>
 518         <xsl:when test="@src">
 519             \includegraphics[height=0.25\textwidth,width=0.25\textwidth,keepaspectratio]{<xsl:value-of select="@src" />}
 520         </xsl:when>
 521         <xsl:otherwise>
 522             <xsl:value-of select="@name" />
 523         </xsl:otherwise>
 524     </xsl:choose>
 525     </parm></cmd>
 526 </xsl:template>
 527
 528 <xsl:template match="mat" mode="inline">
 529     <TeXML escape="0">
 530         <xsl:text>$</xsl:text>
 531         <xsl:value-of select="wl:mathml_latex(.)" />
 532         <xsl:text>$</xsl:text>
 533     </TeXML>
 534 </xsl:template>
 535
 536 <xsl:template match="mat">
 537     <TeXML escape="0">
 538         <xsl:text>$$</xsl:text>
 539         <xsl:value-of select="wl:mathml_latex(.)" />
 540         <xsl:text>$$</xsl:text>
 541     </TeXML>
 542 </xsl:template>
 543
 544 <xsl:template match="tabela|tabelka">
 545     <cmd name="par" />
 546     <cmd name="vspace"><parm>1em</parm></cmd>
 547     <group><cmd name="raggedright" />
 548     <xsl:element name="env">
 549         <xsl:attribute name="name">
 550             <xsl:choose>
 551                 <xsl:when test="name(.)='tabela'">longtabu</xsl:when>
 552                 <xsl:otherwise>tabu</xsl:otherwise>
 553             </xsl:choose>
 554         </xsl:attribute> to <TeXML escape="0">\textwidth </TeXML>
 555       <!--parm><cmd name="textwidth"/></parm-->
 556       <parm><TeXML escape="0"><xsl:value-of select="@_format" /></TeXML></parm>
 557         <xsl:choose>
 558         <xsl:when test="@ramka='1' or @ramki='1'">
 559           <cmd name="hline" />
 560           <xsl:apply-templates mode="wiersze-ramki"/>
 561         </xsl:when>
 562         <xsl:otherwise>
 563           <xsl:apply-templates/>
 564         </xsl:otherwise>
 565         </xsl:choose>
 566     </xsl:element>
 567     </group>
 568     <cmd name="vspace"><parm>1em</parm></cmd>
 569 </xsl:template>
 570 <xsl:template match="wiersz" mode="wiersze-ramki">
 571     <xsl:apply-templates />
 572     <spec cat="esc"/><spec cat="esc"/>
 573     <cmd name="hline" gr="0" />
 574 </xsl:template>
 575 <xsl:template match="wiersz">
 576     <xsl:apply-templates />
 577     <spec cat="esc"/><spec cat="esc"/>
 578 </xsl:template>
 579 <xsl:template match="kol">
 580     <xsl:apply-templates mode="inline"/>
 581     <xsl:if test="position() &lt; last()">
 582     <spec cat="align"/>
 583     </xsl:if>
 584 </xsl:template>
 585
 586
 587 <!-- ============== -->
 588 <!-- = ADDED TAGS = -->
 589 <!-- ============== -->
 590
 591
 592 <xsl:template match="dywiz" mode="inline">
 593     <cmd name="dywiz" />
 594 </xsl:template>
 595
 596 <xsl:template match="nbsp" mode="inline">
 597     <spec cat="tilde" />
 598 </xsl:template>
 599
 600 <xsl:template match="alien" mode="inline">
 601     <group>
 602         <cmd name="alien" />
 603         <xsl:apply-templates mode="inline" />
 604     </group>
 605 </xsl:template>
 606
 607 <!-- ================ -->
 608 <!-- = IGNORED TAGS = -->
 609 <!-- ================ -->
 610 <xsl:template match="extra|uwaga" />
 611 <xsl:template match="extra|uwaga" mode="inline" />
 612
 613 <xsl:template match="nota_red" />
 614 <xsl:template match="abstrakt" />
 615
 616 <!-- ======== -->
 617 <!-- = TEXT = -->
 618 <!-- ======== -->
 619 <xsl:template match="text()" />
 620 <xsl:template match="text()" mode="inline">
 621     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 622       <xsl:text> </xsl:text>
 623     </xsl:if>
 624
 625     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 626
 627     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 628       <xsl:text> </xsl:text>
 629     </xsl:if>
 630 </xsl:template>
 631
 632
 633 </xsl:stylesheet>