librarian/pdf/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[<xsl:value-of select="@customizations"/>]{wl}
  19
  20         <!-- flags and values set on root -->
  21
  22         \newif\ifflaglessadvertising
  23         <xsl:for-each select="@*[starts-with(name(), 'flag-')]">
  24             <cmd>
  25                 <xsl:attribute name="name"><xsl:value-of select="wl:texcommand(name())" />true</xsl:attribute>
  26             </cmd>
  27         </xsl:for-each>
  28
  29         <xsl:for-each select="@*[starts-with(name(), 'data-')]">
  30             <TeXML escape="0">
  31                 \def\<xsl:value-of select="wl:texcommand(name())" />{<TeXML escape="1"><xsl:value-of select="."/></TeXML>}
  32             </TeXML>
  33         </xsl:for-each>
  34         </TeXML>
  35
  36         <xsl:choose>
  37             <xsl:when test="@morefloats = 'new'">
  38                 <TeXML escape="0">
  39                     \usepackage[maxfloats=53]{morefloats}
  40                 </TeXML>
  41             </xsl:when>
  42             <xsl:when test="@morefloats = 'old'">
  43                 <TeXML escape="0">
  44                     \usepackage{morefloats}
  45                 </TeXML>
  46             </xsl:when>
  47             <xsl:when test="@morefloats = 'none'" />
  48             <xsl:otherwise>
  49                 <TeXML escape="0">
  50                     \IfFileExists{morefloats.sty}{
  51                         \usepackage{morefloats}
  52                     }{}
  53                 </TeXML>
  54             </xsl:otherwise>
  55         </xsl:choose>
  56
  57         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  58         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  59
  60         <env name="document">
  61             <xsl:if test="@data-cover-width">
  62                 <cmd name="makecover">
  63                     <parm>210mm</parm>
  64                     <parm><xsl:value-of select="210 * @data-cover-height div @data-cover-width" />mm</parm>
  65                 </cmd>
  66             </xsl:if>
  67                 <xsl:if test="@thanks">
  68                     <TeXML escape="0">
  69                         \def\thanknote{<TeXML escape="1"><xsl:value-of select="@thanks" /></TeXML>}
  70                     </TeXML>
  71                 </xsl:if>
  72             <cmd name="maketitle" />
  73
  74             <cmd name="tytul"><parm>
  75               <xsl:choose>
  76                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  77                     <!-- title in master -->
  78                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  79                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
  80                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
  81                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
  82                     <!-- dc in master or not -->
  83                     <cmd name="translatorsline" />
  84                 </xsl:when>
  85                 <xsl:otherwise>
  86                     <!-- look for author title in dc -->
  87                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  88                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  89                 </xsl:otherwise>
  90               </xsl:choose>
  91             </parm></cmd>
  92             <xsl:if test="//utwor//utwor or //naglowek_czesc or //naglowek_akt or //srodtytul or //naglowek_scena or //naglowek_rozdzial">
  93                 <cmd name="ifshowtoc" />
  94                 <cmd name="setcounter" >
  95                     <parm>tocdepth</parm>
  96                     <parm>3</parm>
  97                 </cmd>
  98                 <cmd name="tableofcontents" />
  99                 <cmd name="clearpage" />
 100                 <cmd name="fi" />
 101             </xsl:if>
 102             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 103             <xsl:apply-templates select="utwor" mode="part" />
 104
 105             <TeXML escape="0">
 106                 <xsl:if test="@data-cover-by">
 107                 \def\coverby{Okładka na podstawie:
 108                     <xsl:choose>
 109                     <xsl:when test="@data-cover-source">
 110                         \href{\datacoversource}{\datacoverby}
 111                     </xsl:when>
 112                     <xsl:otherwise>
 113                         \datacoverby{}
 114                     </xsl:otherwise>
 115                     </xsl:choose>
 116                 }
 117                 </xsl:if>
 118                 \def\editors{<TeXML escape="1"><xsl:call-template name="editors" /></TeXML>}
 119                 <xsl:if test="@funders">
 120                     \def\funders{Publikację wsparli i wsparły:
 121                         <TeXML escape="1"><xsl:value-of select="@funders" /></TeXML>.}
 122                 </xsl:if>
 123
 124                 <xsl:if test="@sponsor-note|data-sponsor">
 125                     \def\sponsors{
 126                         \scriptsize
 127                         <xsl:choose>
 128                             <xsl:when test="@sponsor-note">
 129                                 <TeXML escape="1"><xsl:value-of select="@sponsor-note" /></TeXML>
 130                             </xsl:when>
 131                             <xsl:otherwise>
 132                                 Sfinansowano ze~środków:
 133                             </xsl:otherwise>
 134                         </xsl:choose>
 135
 136                         \vspace{1em}
 137
 138                         <xsl:apply-templates select="data-sponsor" mode="sponsor" />
 139                     }
 140                 </xsl:if>
 141             </TeXML>
 142
 143             <cmd name="editorialsection" />
 144
 145         </env>
 146     </TeXML>
 147 </xsl:template>
 148
 149 <xsl:template match="utwor" mode="part">
 150     <cmd name="tytul"><parm>
 151       <xsl:choose>
 152         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
 153             <!-- title in master -->
 154             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="part_title" />
 155             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
 156         </xsl:when>
 157         <xsl:otherwise>
 158             <!-- look for title in dc -->
 159             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 160             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
 161         </xsl:otherwise>
 162       </xsl:choose>
 163     </parm></cmd>
 164
 165     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 166     <xsl:apply-templates select="utwor" mode="part" />
 167 </xsl:template>
 168
 169 <!-- =================== -->
 170 <!-- = MAIN TITLE PAGE = -->
 171 <!-- = (from DC)       = -->
 172 <!-- =================== -->
 173
 174 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
 175     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
 176 </xsl:template>
 177
 178 <xsl:template match="rdf:RDF" mode="titlepage">
 179     <TeXML escape="0">
 180         \def\authors{<TeXML escape="1"><xsl:call-template name="authors" /></TeXML>}
 181         \author{\authors}
 182         \title{<TeXML escape="1"><xsl:apply-templates select=".//dc:title" mode="inline" /></TeXML>}
 183         \def\translatorsline{<TeXML escape="1"><xsl:call-template name="translators" /></TeXML>}
 184
 185         \def\bookurl{<TeXML escape="1"><xsl:value-of select=".//dc:identifier.url" /></TeXML>}
 186
 187         \def\rightsinfo{Ten utwór nie jest objęty majątkowym prawem autorskim i~znajduje się w~domenie
 188             publicznej, co oznacza że możesz go swobodnie wykorzystywać, publikować
 189             i~rozpowszechniać. Jeśli utwór opatrzony jest dodatkowymi materiałami
 190             (przypisy, motywy literackie etc.), które podlegają prawu autorskiemu, to
 191             te dodatkowe materiały udostępnione są na licencji
 192             \href{http://creativecommons.org/licenses/by-sa/3.0/}{Creative Commons
 193             Uznanie Autorstwa – Na Tych Samych Warunkach 3.0 PL}.}
 194         <xsl:if test=".//dc:rights.license">
 195             \def\rightsinfo{Ten utwór jest udostępniony na licencji
 196             \href{<xsl:value-of select=".//dc:rights.license" />}{<TeXML escape="1"><xsl:apply-templates select=".//dc:rights" mode="inline" /></TeXML>}.}
 197         </xsl:if>
 198
 199         \def\sourceinfo{
 200             <xsl:if test=".//dc:source">
 201                 Tekst opracowany na podstawie: <TeXML escape="1"><xsl:apply-templates select=".//dc:source" mode="inline" /></TeXML>
 202                 \vspace{.6em}
 203             </xsl:if>}
 204         \def\publisherinfo{
 205             <xsl:if test=".//dc:publisher">
 206                 Wydawca:
 207                 <TeXML escape="1">
 208                     <xsl:for-each select=".//dc:publisher/text()">
 209                         <xsl:value-of select="."/>
 210                         <xsl:if test="not(position() = last())">, </xsl:if>
 211                     </xsl:for-each>
 212                 </TeXML>
 213                 \vspace{.6em}
 214             </xsl:if>}
 215         \def\description{<TeXML escape="1"><xsl:apply-templates select=".//dc:description" mode="inline" /></TeXML>}
 216         <xsl:if test=".//meta[@id='pdf-id']">
 217             <xsl:variable name="isbn" select=".//meta[@id='pdf-id']"/>
 218             \def\isbn{ISBN <xsl:value-of select="substring-after($isbn, 'ISBN-')"/>}
 219         </xsl:if>
 220     </TeXML>
 221 </xsl:template>
 222
 223
 224 <!-- ============== -->
 225 <!-- = BOOK TITLE = -->
 226 <!-- = (from DC)  = -->
 227 <!-- ============== -->
 228
 229 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
 230     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 231 </xsl:template>
 232
 233 <xsl:template match="rdf:RDF" mode="dctitle">
 234     <xsl:if test="../../rdf:RDF//use_subauthor">
 235         <cmd name="autorpodutworu">
 236             <parm><xsl:call-template name="authors" /></parm>
 237         </cmd>
 238     </xsl:if>
 239     <cmd name="nazwanadpodutworu"><parm>
 240         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 241     </parm>
 242     <parm>
 243         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 244     </parm></cmd>
 245 </xsl:template>
 246
 247 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
 248     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
 249 </xsl:template>
 250
 251 <xsl:template match="rdf:RDF" mode="firstdctitle">
 252     <cmd name="autorutworu"><parm><cmd name="authors"/></parm></cmd>
 253     <cmd name="nazwautworu"><parm>
 254         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 255     </parm></cmd>
 256     <cmd name="translatorsline" />
 257 </xsl:template>
 258
 259
 260 <!-- ============================================================================== -->
 261 <!-- = MASTER TAG                                                                 = -->
 262 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 263 <!-- ============================================================================== -->
 264 <!-- ==================================================================================== -->
 265 <!-- = BLOCK TAGS                                                                       = -->
 266 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 267 <!-- ==================================================================================== -->
 268
 269 <xsl:template
 270     match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny|nota|dedykacja|dlugi_cytat|poezja_cyt|motto|ramka">
 271     <cmd>
 272         <xsl:attribute name="name">
 273             <xsl:value-of select="wl:texcommand(name())" />
 274         </xsl:attribute>
 275         <parm><xsl:apply-templates/></parm>
 276     </cmd>
 277 </xsl:template>
 278
 279 <xsl:template match="lista_osob">
 280     <cmd name="listaosob">
 281         <parm><xsl:apply-templates select="naglowek_listy" /></parm>
 282         <parm><xsl:apply-templates select="lista_osoba" /></parm>
 283     </cmd>
 284 </xsl:template>
 285
 286 <xsl:template match="kwestia">
 287     <cmd name="kwestia">
 288         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 289     </cmd>
 290 </xsl:template>
 291
 292 <xsl:template match="ilustr">
 293     <cmd name="ilustr">
 294         <parm><xsl:value-of select="@src" /></parm>
 295         <parm><xsl:value-of select="@alt" /></parm>
 296     </cmd>
 297 </xsl:template>
 298
 299 <!-- ========================================== -->
 300 <!-- = PARAGRAPH TAGS                         = -->
 301 <!-- = (can contain inline and special tags)  = -->
 302 <!-- ========================================== -->
 303
 304 <!-- only in root -->
 305 <xsl:template
 306     match="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul"
 307     mode="title">
 308     <cmd>
 309         <xsl:attribute name="name">
 310             <xsl:value-of select="wl:texcommand(name())" />
 311         </xsl:attribute>
 312         <parm><xsl:apply-templates mode="inline"/></parm>
 313     </cmd>
 314 </xsl:template>
 315
 316 <xsl:template match="nazwa_utworu" mode="part_title">
 317     <xsl:if test="../../rdf:RDF//use_subauthor">
 318         <cmd name="autorpodutworu"><parm><xsl:call-template name="authors2"/></parm></cmd>
 319     </xsl:if>
 320     <cmd name="nazwapodutworu">
 321         <parm><xsl:apply-templates mode="inline"/></parm>
 322         <parm>
 323             <xsl:call-template name="strip-for-toc" />
 324         </parm>
 325     </cmd>
 326 </xsl:template>
 327
 328
 329 <xsl:template
 330     match="naglowek_osoba|naglowek_podrozdzial|miejsce_czas|didaskalia|lista_osoba|akap|akap_diafrlog|akap_cd|motto_podpis|naglowek_listy|srodtytul">
 331     <cmd>
 332         <xsl:attribute name="name">
 333             <xsl:value-of select="wl:texcommand(name())" />
 334         </xsl:attribute>
 335         <parm><xsl:apply-templates mode="inline"/></parm>
 336     </cmd>
 337 </xsl:template>
 338
 339 <xsl:template match="naglowek_czesc|naglowek_rozdzial|naglowek_akt|naglowek_scena">
 340     <cmd>
 341         <xsl:attribute name="name">
 342             <xsl:value-of select="wl:texcommand(name())" />
 343         </xsl:attribute>
 344         <parm><xsl:apply-templates mode="inline"/></parm>
 345         <parm>
 346             <xsl:call-template name="strip-for-toc" />
 347         </parm>
 348     </cmd>
 349 </xsl:template>
 350
 351 <xsl:template match="strofa" mode="inline">
 352     <env name="minipage">
 353         <opt>t</opt>
 354         <parm><cmd name="linewidth" /></parm>
 355         <parm><xsl:apply-templates select="." /></parm>
 356     </env>
 357 </xsl:template>
 358
 359 <xsl:template match="strofa">
 360   <cmd name="strofa"><parm>
 361     <xsl:choose>
 362         <xsl:when test="count(br) > 0">
 363             <xsl:call-template name="verse">
 364                 <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 365                 <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd' or name() = 'wers_do_prawej'][1]" />
 366             </xsl:call-template>
 367             <xsl:for-each select="br">
 368                 <TeXML escape="0">\\{}</TeXML>
 369                 <!-- Each BR tag "consumes" text after it -->
 370                 <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 371                 <xsl:call-template name="verse">
 372                     <xsl:with-param name="verse-content"
 373                         select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 374                     <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd' or name() = 'wers_do_prawej')][1]" />
 375                 </xsl:call-template>
 376             </xsl:for-each>
 377         </xsl:when>
 378         <xsl:otherwise>
 379             <xsl:call-template name="verse">
 380                 <xsl:with-param name="verse-content" select="text() | node()" />
 381                 <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd|wers_do_prawej[1]" />
 382             </xsl:call-template>
 383         </xsl:otherwise>
 384     </xsl:choose>
 385   </parm></cmd>
 386 </xsl:template>
 387
 388
 389 <xsl:template name="verse">
 390     <xsl:param name="verse-content" />
 391     <xsl:param name="verse-type" />
 392
 393     <cmd>
 394         <xsl:attribute name="name">
 395             <xsl:choose>
 396                 <xsl:when test="$verse-type != ''">
 397                     <xsl:value-of select='wl:texcommand(name($verse-type))' />
 398                 </xsl:when>
 399                 <xsl:otherwise>wers</xsl:otherwise>
 400             </xsl:choose>
 401         </xsl:attribute>
 402         <xsl:if test="string($verse-content/@typ)">
 403             <opt><xsl:value-of select="$verse-content/@typ" />em</opt>
 404         </xsl:if>
 405         <parm><xsl:apply-templates select="$verse-content" mode="inline"/></parm>
 406     </cmd>
 407 </xsl:template>
 408
 409 <!-- ================================================ -->
 410 <!-- = INLINE TAGS                                  = -->
 411 <!-- = (contain other inline tags and special tags) = -->
 412 <!-- ================================================ -->
 413
 414 <xsl:template mode="inline"
 415     match="pa|pe|pr|pt|mat|didask_tekst|slowo_obce|wyroznienie|osoba|indeks_dolny|wieksze_odstepy">
 416     <cmd>
 417         <xsl:attribute name="name">
 418             <xsl:value-of select="wl:texcommand(name())" />
 419         </xsl:attribute>
 420         <parm><xsl:apply-templates mode="inline"/></parm>
 421     </cmd>
 422 </xsl:template>
 423
 424
 425
 426 <xsl:template match="tytul_dziela" mode="inline">
 427     <cmd name="tytuldziela"><parm>
 428         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 429     </parm></cmd>
 430 </xsl:template>
 431
 432
 433
 434 <!-- ============================================== -->
 435 <!-- = STANDALONE TAGS                            = -->
 436 <!-- = (cannot contain any other tags)            = -->
 437 <!-- ============================================== -->
 438 <xsl:template
 439     match="sekcja_swiatlo|sekcja_asterysk|separator_linia">
 440     <cmd>
 441         <xsl:attribute name="name">
 442             <xsl:value-of select="wl:texcommand(name())" />
 443         </xsl:attribute>
 444     </cmd>
 445 </xsl:template>
 446
 447
 448 <!-- ================ -->
 449 <!-- = SPECIAL TAGS = -->
 450 <!-- ================ -->
 451 <!-- Themes -->
 452
 453
 454 <xsl:template match="begin|end|motyw">
 455     <xsl:apply-templates select='.' mode="inline" />
 456 </xsl:template>
 457
 458 <xsl:template match="begin" mode="inline" />
 459 <xsl:template match="end" mode="inline" />
 460
 461 <xsl:template match="motyw" mode="inline">
 462     <cmd name="motyw">
 463         <xsl:if test="@moved">
 464             <opt name="moved"><xsl:value-of select="@moved" /></opt>
 465         </xsl:if>
 466         <parm><xsl:apply-templates mode="inline" /></parm>
 467     </cmd>
 468 </xsl:template>
 469
 470 <xsl:template name="authors">
 471     <xsl:for-each select=".//dc:creator_parsed">
 472         <xsl:if test="position() != 1">, </xsl:if>
 473         <xsl:apply-templates mode="inline" />
 474     </xsl:for-each>
 475 </xsl:template>
 476
 477 <xsl:template name="authors2">
 478     <xsl:for-each select="../..//dc:creator_parsed">
 479         <xsl:if test="position() != 1">, </xsl:if>
 480         <xsl:apply-templates mode="inline" />
 481     </xsl:for-each>
 482 </xsl:template>
 483
 484 <xsl:template name="editors">
 485     <xsl:if test="@editors">
 486         <xsl:text>Opracowanie redakcyjne i przypisy: </xsl:text>
 487         <xsl:value-of select="@editors" />
 488         <xsl:text>.</xsl:text>
 489     </xsl:if>
 490 </xsl:template>
 491
 492 <xsl:template name="translators">
 493     <xsl:if test=".//dc:contributor.translator_parsed">
 494         <cmd name='translator'><parm>
 495             <xsl:for-each select=".//dc:contributor.translator_parsed">
 496                 <xsl:if test="position() != 1">, </xsl:if>
 497                 <xsl:apply-templates mode="inline" />
 498             </xsl:for-each>
 499         </parm></cmd>
 500     </xsl:if>
 501 </xsl:template>
 502
 503 <xsl:template name="strip-for-toc">
 504     <xsl:for-each select="./text() | nbsp | dywiz | alien | slowo_obce">
 505         <xsl:choose>
 506             <xsl:when test="name() = 'nbsp'">
 507                 <xsl:text> </xsl:text>
 508             </xsl:when>
 509             <xsl:when test="name() = 'dywiz'">
 510                 <xsl:text>-</xsl:text>
 511             </xsl:when>
 512             <xsl:when test="name() = 'alien'">
 513                 <xsl:apply-templates mode="inline" />
 514             </xsl:when>
 515             <xsl:when test="name() = 'slowo_obce'">
 516                 <xsl:call-template name="strip-for-toc" />
 517             </xsl:when>
 518             <xsl:otherwise>
 519                 <xsl:value-of select="."/>
 520             </xsl:otherwise>
 521         </xsl:choose>
 522     </xsl:for-each>
 523 </xsl:template>
 524
 525 <xsl:template match="data-sponsor" mode="sponsor">
 526     <cmd name="par"><parm>
 527     <xsl:choose>
 528         <xsl:when test="@src">
 529             \includegraphics[height=0.25\textwidth,width=0.25\textwidth,keepaspectratio]{<xsl:value-of select="@src" />}
 530         </xsl:when>
 531         <xsl:otherwise>
 532             <xsl:value-of select="@name" />
 533         </xsl:otherwise>
 534     </xsl:choose>
 535     </parm></cmd>
 536 </xsl:template>
 537
 538 <xsl:template match="mat" mode="inline">
 539     <TeXML escape="0">
 540         <xsl:text>$</xsl:text>
 541         <xsl:value-of select="wl:mathml_latex(.)" />
 542         <xsl:text>$</xsl:text>
 543     </TeXML>
 544 </xsl:template>
 545
 546 <xsl:template match="mat">
 547     <TeXML escape="0">
 548         <xsl:text>$$</xsl:text>
 549         <xsl:value-of select="wl:mathml_latex(.)" />
 550         <xsl:text>$$</xsl:text>
 551     </TeXML>
 552 </xsl:template>
 553
 554 <xsl:template match="tabela|tabelka">
 555     <cmd name="par" />
 556     <cmd name="vspace"><parm>1em</parm></cmd>
 557     <group><cmd name="raggedright" />
 558     <xsl:element name="env">
 559         <xsl:attribute name="name">
 560             <xsl:choose>
 561                 <xsl:when test="name(.)='tabela'">longtabu</xsl:when>
 562                 <xsl:otherwise>tabu</xsl:otherwise>
 563             </xsl:choose>
 564         </xsl:attribute> to <TeXML escape="0">\textwidth </TeXML>
 565       <!--parm><cmd name="textwidth"/></parm-->
 566       <parm><TeXML escape="0"><xsl:value-of select="@_format" /></TeXML></parm>
 567         <xsl:choose>
 568         <xsl:when test="@ramka='1' or @ramki='1'">
 569           <cmd name="hline" />
 570           <xsl:apply-templates mode="wiersze-ramki"/>
 571         </xsl:when>
 572         <xsl:otherwise>
 573           <xsl:apply-templates/>
 574         </xsl:otherwise>
 575         </xsl:choose>
 576     </xsl:element>
 577     </group>
 578     <cmd name="vspace"><parm>1em</parm></cmd>
 579 </xsl:template>
 580 <xsl:template match="wiersz" mode="wiersze-ramki">
 581     <xsl:apply-templates />
 582     <spec cat="esc"/><spec cat="esc"/>
 583     <cmd name="hline" gr="0" />
 584 </xsl:template>
 585 <xsl:template match="wiersz">
 586     <xsl:apply-templates />
 587     <spec cat="esc"/><spec cat="esc"/>
 588 </xsl:template>
 589 <xsl:template match="kol">
 590     <xsl:apply-templates mode="inline"/>
 591     <xsl:if test="position() &lt; last()">
 592     <spec cat="align"/>
 593     </xsl:if>
 594 </xsl:template>
 595
 596
 597 <!-- ============== -->
 598 <!-- = ADDED TAGS = -->
 599 <!-- ============== -->
 600
 601
 602 <xsl:template match="dywiz" mode="inline">
 603     <cmd name="dywiz" />
 604 </xsl:template>
 605
 606 <xsl:template match="nbsp" mode="inline">
 607     <spec cat="tilde" />
 608 </xsl:template>
 609
 610 <xsl:template match="alien" mode="inline">
 611     <group>
 612         <cmd name="alien" />
 613         <xsl:apply-templates mode="inline" />
 614     </group>
 615 </xsl:template>
 616
 617 <!-- ================ -->
 618 <!-- = IGNORED TAGS = -->
 619 <!-- ================ -->
 620 <xsl:template match="extra|uwaga" />
 621 <xsl:template match="extra|uwaga" mode="inline" />
 622
 623 <xsl:template match="nota_red" />
 624 <xsl:template match="abstrakt" />
 625
 626 <!-- ======== -->
 627 <!-- = TEXT = -->
 628 <!-- ======== -->
 629 <xsl:template match="text()" />
 630 <xsl:template match="text()" mode="inline">
 631     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 632       <xsl:text> </xsl:text>
 633     </xsl:if>
 634
 635     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 636
 637     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 638       <xsl:text> </xsl:text>
 639     </xsl:if>
 640 </xsl:template>
 641
 642
 643 </xsl:stylesheet>