librarian/xslt/book2html.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/" >
  11
  12 <xsl:output encoding="utf-8" indent="yes" omit-xml-declaration = "yes" version="2.0" />
  13 <xsl:strip-space  elements="opowiadanie powiesc dramat_wierszowany_l dramat_wierszowany_lp dramat_wspolczesny liryka_l liryka_lp wywiad"/>
  14 <xsl:template match="utwor">
  15     <xsl:choose>
  16         <xsl:when test="@full-page">
  17             <html>
  18             <head>
  19                 <title>Książka z serwisu WolneLektury.pl</title>
  20                 <meta charset="utf-8" />
  21                 <meta name="viewport" content="width=device-width, initial-scale=1, maximum-scale=1" />
  22                 <link href="https://static.wolnelektury.pl/css/compressed/book_text.css" rel="stylesheet" type="text/css" />
  23                 <style>
  24                   .animacja {cursor: pointer;}
  25                 </style>
  26             </head>
  27             <body>
  28               <xsl:call-template name="book-text" />
  29
  30               <script src="http://ajax.googleapis.com/ajax/libs/jquery/1/jquery.min.js"></script>
  31               <script src="http://malsup.github.io/min/jquery.cycle2.min.js"></script>
  32             </body>
  33             </html>
  34         </xsl:when>
  35         <xsl:otherwise>
  36             <xsl:call-template name="book-text" />
  37         </xsl:otherwise>
  38     </xsl:choose>
  39 </xsl:template>
  40
  41 <xsl:template name="book-text">
  42     <div id="book-text">
  43         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  44         <xsl:if test="count(descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)])">
  45             <div id="footnotes">
  46                 <h3>Przypisy</h3>
  47                 <xsl:for-each select="descendant::*[self::pe or self::pa or self::pr or self::pt][not(parent::extra)]">
  48                     <div>
  49                         <xsl:attribute name="class">fn-<xsl:value-of select="name()" /></xsl:attribute>
  50                         <a name="{concat('footnote-', generate-id(.))}" />
  51                         <a href="{concat('#anchor-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
  52                         <xsl:choose>
  53                             <xsl:when test="count(akap|akap_cd|strofa) = 0">
  54                                 <p><xsl:apply-templates select="text()|*" mode="inline" />
  55                                 <xsl:if test="name()='pa'"> [przypis autorski]</xsl:if>
  56                                 <xsl:if test="name()='pt'"> [przypis tłumacza]</xsl:if>
  57                                 <xsl:if test="name()='pr'"> [przypis redakcyjny]</xsl:if>
  58                                 <xsl:if test="name()='pe'"> [przypis edytorski]</xsl:if>
  59                                 </p>
  60                             </xsl:when>
  61                             <xsl:otherwise>
  62                                 <xsl:apply-templates select="text()|*" mode="inline" />
  63                             </xsl:otherwise>
  64                         </xsl:choose>
  65                     </div>
  66                 </xsl:for-each>
  67             </div>
  68         </xsl:if>
  69     </div>
  70 </xsl:template>
  71
  72
  73 <!-- ============================================================================== -->
  74 <!-- = MASTER TAG                                                                 = -->
  75 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
  76 <!-- ============================================================================== -->
  77 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny">
  78     <xsl:apply-templates select="nota_red" mode="special" />
  79     <xsl:if test="nazwa_utworu">
  80         <h1>
  81             <xsl:apply-templates select="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul" mode="header" />
  82             <xsl:call-template name="translators" />
  83         </h1>
  84     </xsl:if>
  85     <xsl:apply-templates />
  86 </xsl:template>
  87
  88
  89 <!-- ==================================================================================== -->
  90 <!-- = BLOCK TAGS                                                                       = -->
  91 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
  92 <!-- ==================================================================================== -->
  93 <xsl:template match="nota">
  94     <div class="note"><xsl:apply-templates /></div>
  95 </xsl:template>
  96
  97 <xsl:template match="lista_osob">
  98     <xsl:call-template name="section-anchor"/>
  99     <div class="person-list">
 100         <h3><xsl:value-of select="naglowek_listy" /></h3>
 101         <ol>
 102             <xsl:apply-templates select="lista_osoba" />
 103         </ol>
 104     </div>
 105 </xsl:template>
 106
 107 <xsl:template match="dedykacja">
 108     <div class="dedication"><xsl:apply-templates /></div>
 109 </xsl:template>
 110
 111 <xsl:template match="ramka">
 112     <div class="frame"><xsl:apply-templates /></div>
 113 </xsl:template>
 114
 115 <xsl:template match="kwestia">
 116     <div class="kwestia">
 117         <xsl:apply-templates select="strofa|akap|didaskalia" />
 118     </div>
 119 </xsl:template>
 120
 121 <xsl:template match="dlugi_cytat|poezja_cyt">
 122     <blockquote><xsl:apply-templates /></blockquote>
 123 </xsl:template>
 124
 125 <xsl:template match="motto">
 126     <xsl:call-template name="section-anchor"/>
 127     <div class="motto"><xsl:apply-templates /></div>
 128 </xsl:template>
 129
 130 <xsl:template match="ilustr" mode="inline">
 131     <xsl:apply-templates select="."/>
 132 </xsl:template>
 133
 134 <xsl:template match="ilustr">
 135     <img>
 136         <xsl:attribute name="src">
 137             <xsl:value-of select="$gallery" /><xsl:value-of select="@src" />
 138         </xsl:attribute>
 139         <xsl:attribute name="alt">
 140             <xsl:value-of select="@alt" />
 141         </xsl:attribute>
 142         <xsl:attribute name="title">
 143             <xsl:value-of select="@alt" />
 144         </xsl:attribute>
 145     </img>
 146 </xsl:template>
 147
 148 <xsl:template match="animacja">
 149   <div class="animacja cycle-slideshow" data-cycle-pause-on-hover="true" data-cycle-next="> img" data-cycle-fx="fadeout" data-cycle-paused="true">
 150     <xsl:apply-templates/>
 151   </div>
 152 </xsl:template>
 153
 154
 155 <!-- ========================================== -->
 156 <!-- = PARAGRAPH TAGS                         = -->
 157 <!-- = (can contain inline and special tags)  = -->
 158 <!-- ========================================== -->
 159 <!-- Title page -->
 160 <xsl:template match="autor_utworu" mode="header">
 161     <span class="author"><xsl:apply-templates mode="inline" /></span>
 162 </xsl:template>
 163
 164 <xsl:template match="nazwa_utworu" mode="header">
 165     <span class="title"><xsl:apply-templates mode="inline" /></span>
 166 </xsl:template>
 167
 168 <xsl:template match="dzielo_nadrzedne" mode="header">
 169     <span class="collection"><xsl:apply-templates mode="inline" /></span>
 170 </xsl:template>
 171
 172 <xsl:template match="podtytul" mode="header">
 173     <span class="subtitle"><xsl:apply-templates mode="inline" /></span>
 174 </xsl:template>
 175
 176 <!-- Section headers (included in index)-->
 177 <xsl:template match="naglowek_akt|naglowek_czesc|srodtytul">
 178   <xsl:call-template name="section-anchor"/>
 179     <h2><xsl:apply-templates mode="inline" /></h2>
 180 </xsl:template>
 181
 182 <xsl:template match="naglowek_scena|naglowek_rozdzial">
 183     <xsl:call-template name="section-anchor"/>
 184     <h3><xsl:apply-templates mode="inline" /></h3>
 185 </xsl:template>
 186
 187 <xsl:template match="naglowek_osoba|naglowek_podrozdzial">
 188       <xsl:call-template name="section-anchor"/>
 189     <h4><xsl:apply-templates mode="inline" /></h4>
 190 </xsl:template>
 191
 192 <!-- Other paragraph tags -->
 193 <xsl:template match="miejsce_czas">
 194       <xsl:call-template name="section-anchor"/>
 195     <p class="place-and-time"><xsl:apply-templates mode="inline" /></p>
 196 </xsl:template>
 197
 198 <xsl:template match="didaskalia">
 199       <xsl:call-template name="section-anchor"/>
 200     <div class="didaskalia"><xsl:apply-templates mode="inline" /></div>
 201 </xsl:template>
 202
 203 <xsl:template match="lista_osoba">
 204     <li><xsl:apply-templates mode="inline" /></li>
 205 </xsl:template>
 206
 207 <xsl:template match="akap|akap_dialog|akap_cd">
 208     <p class="paragraph">
 209       <xsl:call-template name="section-anchor"/>
 210         <xsl:apply-templates mode="inline" />
 211     </p>
 212 </xsl:template>
 213
 214 <xsl:template match="strofa" mode="inline">
 215     <xsl:apply-templates select="." />
 216 </xsl:template>
 217
 218 <xsl:template match="strofa">
 219     <div class="stanza">
 220       <xsl:call-template name="section-anchor"/>
 221         <xsl:choose>
 222             <xsl:when test="count(br) > 0">
 223                 <xsl:call-template name="verse">
 224                     <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 225                     <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd' or name() = 'wers_do_prawej'][1]" />
 226                 </xsl:call-template>
 227                 <xsl:for-each select="br">
 228                                 <!-- Each BR tag "consumes" text after it -->
 229                     <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 230                     <xsl:call-template name="verse">
 231                         <xsl:with-param name="verse-content"
 232                             select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 233                         <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd' or name() = 'wers_do_prawej')][1]" />
 234                     </xsl:call-template>
 235                 </xsl:for-each>
 236             </xsl:when>
 237             <xsl:otherwise>
 238                 <xsl:call-template name="verse">
 239                     <xsl:with-param name="verse-content" select="text() | node()" />
 240                     <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd|wers_do_prawej[1]" />
 241                  </xsl:call-template>
 242             </xsl:otherwise>
 243         </xsl:choose>
 244     </div>
 245 </xsl:template>
 246
 247 <xsl:template name="verse">
 248     <xsl:param name="verse-content" />
 249     <xsl:param name="verse-type" />
 250     <p class="verse">
 251         <xsl:choose>
 252             <xsl:when test="name($verse-type) = 'wers_akap'">
 253                 <xsl:attribute name="style">padding-left: 1em</xsl:attribute>
 254             </xsl:when>
 255             <xsl:when test="name($verse-type) = 'wers_wciety'">
 256                 <xsl:choose>
 257                     <xsl:when test="$verse-content/@typ">
 258                         <xsl:attribute name="style">padding-left: <xsl:value-of select="$verse-content/@typ" />em</xsl:attribute>
 259                     </xsl:when>
 260                     <xsl:otherwise>
 261                         <xsl:attribute name="style">padding-left: 1em</xsl:attribute>
 262                     </xsl:otherwise>
 263                 </xsl:choose>
 264             </xsl:when>
 265             <xsl:when test="name($verse-type) = 'wers_cd'">
 266                 <xsl:attribute name="style">padding-left: 12em</xsl:attribute>
 267             </xsl:when>
 268             <xsl:when test="name($verse-type) = 'wers_do_prawej'">
 269                 <xsl:attribute name="style">text-align: right</xsl:attribute>
 270             </xsl:when>
 271         </xsl:choose>
 272         <xsl:apply-templates select="$verse-content" mode="inline" />
 273     </p>
 274 </xsl:template>
 275
 276 <xsl:template match="motto_podpis">
 277     <xsl:call-template name="section-anchor"/>
 278     <p class="motto_podpis"><xsl:apply-templates mode="inline" /></p>
 279 </xsl:template>
 280
 281 <xsl:template match="tabela|tabelka">
 282     <xsl:call-template name="section-anchor"/>
 283     <xsl:choose>
 284         <xsl:when test="@ramka = '1'">
 285             <table class="border"><xsl:apply-templates /></table>
 286         </xsl:when>
 287         <xsl:otherwise>
 288             <table><xsl:apply-templates /></table>
 289         </xsl:otherwise>
 290     </xsl:choose>
 291 </xsl:template>
 292 <xsl:template match="wiersz">
 293     <tr><xsl:apply-templates /></tr>
 294 </xsl:template>
 295 <xsl:template match="kol">
 296     <td><xsl:apply-templates mode="inline" /></td>
 297 </xsl:template>
 298
 299 <xsl:template match="mat">
 300     <math xmlns="http://www.w3.org/1998/Math/MathML"><xsl:copy-of select="*" /></math>
 301 </xsl:template>
 302
 303
 304 <!-- ================================================ -->
 305 <!-- = INLINE TAGS                                  = -->
 306 <!-- = (contain other inline tags and special tags) = -->
 307 <!-- ================================================ -->
 308 <!-- Annotations -->
 309 <xsl:template match="pa|pe|pr|pt" mode="inline">
 310     <a name="{concat('anchor-', generate-id(.))}" />
 311     <a href="{concat('#footnote-', generate-id(.))}" class="annotation">[<xsl:number value="count(preceding::*[self::pa or self::pe or self::pr or self::pt]) + 1" />]</a>
 312 </xsl:template>
 313
 314 <!-- Other inline tags -->
 315 <xsl:template match="mat" mode="inline">
 316     <math xmlns="http://www.w3.org/1998/Math/MathML"><xsl:copy-of select="*" /></math>
 317 </xsl:template>
 318
 319 <xsl:template match="didask_tekst" mode="inline">
 320     <em class="didaskalia"><xsl:apply-templates mode="inline" /></em>
 321 </xsl:template>
 322
 323 <xsl:template match="slowo_obce" mode="inline">
 324     <em class="foreign-word"><xsl:apply-templates mode="inline" /></em>
 325 </xsl:template>
 326
 327 <xsl:template match="tytul_dziela" mode="inline">
 328     <em class="book-title">
 329         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 330     </em>
 331 </xsl:template>
 332
 333 <xsl:template match="wyroznienie" mode="inline">
 334     <em class="author-emphasis"><xsl:apply-templates mode="inline" /></em>
 335 </xsl:template>
 336
 337 <xsl:template match="wieksze_odstepy" mode="inline">
 338     <em class="wieksze-odstepy"><xsl:apply-templates mode="inline" /></em>
 339 </xsl:template>
 340
 341 <xsl:template match="indeks_dolny" mode="inline">
 342     <sub><xsl:apply-templates mode="inline" /></sub>
 343 </xsl:template>
 344
 345 <xsl:template match="osoba" mode="inline">
 346     <em class="person"><xsl:apply-templates mode="inline" /></em>
 347 </xsl:template>
 348
 349
 350 <!-- ============================================== -->
 351 <!-- = STANDALONE TAGS                            = -->
 352 <!-- = (cannot contain any other tags)            = -->
 353 <!-- ============================================== -->
 354 <xsl:template match="sekcja_swiatlo">
 355     <hr class="spacer" />
 356 </xsl:template>
 357
 358 <xsl:template match="sekcja_asterysk">
 359     <p class="spacer-asterisk">*</p>
 360 </xsl:template>
 361
 362 <xsl:template match="separator_linia">
 363     <hr class="spacer-line" />
 364 </xsl:template>
 365
 366
 367 <!-- ================ -->
 368 <!-- = SPECIAL TAGS = -->
 369 <!-- ================ -->
 370 <!-- Themes -->
 371 <xsl:template match="begin" mode="inline">
 372     <xsl:variable name="mnum" select="concat('m', substring(@id, 2))" />
 373     <a name="m{substring(@id, 2)}" class="theme-begin" fid="{substring(@id, 2)}">
 374         <xsl:value-of select="string(following::motyw[@id=$mnum]/text())" />
 375     </a>
 376 </xsl:template>
 377
 378 <xsl:template match="end" mode="inline">
 379     <span class="theme-end" fid="{substring(@id, 2)}"> </span>
 380 </xsl:template>
 381
 382 <xsl:template match="begin|end">
 383     <xsl:apply-templates select='.' mode="inline" />
 384 </xsl:template>
 385
 386 <xsl:template match="motyw" mode="inline" />
 387
 388
 389 <xsl:template match="nota_red" mode="special">
 390     <div id="nota_red">
 391         <xsl:apply-templates />
 392     </div>
 393 </xsl:template>
 394
 395
 396 <xsl:template name="translators">
 397     <xsl:if test="//dc:contributor.translator">
 398         <span class="translator">
 399             <xsl:text>tłum. </xsl:text>
 400             <xsl:for-each select="//dc:contributor.translator">
 401                 <xsl:if test="position() != 1">, </xsl:if>
 402                 <xsl:apply-templates mode="person" />
 403             </xsl:for-each>
 404         </span>
 405     </xsl:if>
 406 </xsl:template>
 407
 408 <xsl:template match="text()" mode="person">
 409     <xsl:value-of select="wl:person_name(.)" />
 410 </xsl:template>
 411
 412
 413 <!-- ================ -->
 414 <!-- = IGNORED TAGS = -->
 415 <!-- ================ -->
 416 <xsl:template match="extra|uwaga" />
 417 <xsl:template match="extra|uwaga" mode="inline" />
 418
 419 <xsl:template match="nota_red" />
 420 <xsl:template match="abstrakt" />
 421
 422 <!-- ======== -->
 423 <!-- = TEXT = -->
 424 <!-- ======== -->
 425 <xsl:template match="text()" />
 426 <xsl:template match="text()" mode="inline">
 427     <xsl:value-of select="wl:substitute_entities(.)" />
 428 </xsl:template>
 429
 430 <!-- ========= -->
 431 <!-- = utils = -->
 432 <!-- ========= -->
 433 <xsl:template name="section-anchor">
 434   <!--
 435        this formula works as follows:
 436        - get all ancestors including self
 437        - choose the header (third one from root): utwor/book-type/header
 438        - get all preceding siblings
 439        - count them
 440        - create an <a name="sec123"/> tag.
 441   -->
 442         <a name="{concat('sec', count(ancestor-or-self::*[last()-2]/preceding-sibling::*) + 1)}" />
 443 </xsl:template>
 444
 445 </xsl:stylesheet>