librarian/pdf/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[<xsl:value-of select="@customizations"/>]{wl}
  19
  20         <!-- flags and values set on root -->
  21
  22         \newif\ifflaglessadvertising
  23         \newif\ifflagnotwl
  24         <xsl:for-each select="@*[starts-with(name(), 'flag-')]">
  25             <cmd>
  26                 <xsl:attribute name="name"><xsl:value-of select="wl:texcommand(name())" />true</xsl:attribute>
  27             </cmd>
  28         </xsl:for-each>
  29
  30         <xsl:for-each select="@*[starts-with(name(), 'data-')]">
  31             <TeXML escape="0">
  32                 \def\<xsl:value-of select="wl:texcommand(name())" />{<TeXML escape="1"><xsl:value-of select="."/></TeXML>}
  33             </TeXML>
  34         </xsl:for-each>
  35         </TeXML>
  36
  37         <xsl:choose>
  38             <xsl:when test="@morefloats = 'new'">
  39                 <TeXML escape="0">
  40                     \usepackage[maxfloats=64]{morefloats}
  41                 </TeXML>
  42             </xsl:when>
  43             <xsl:when test="@morefloats = 'old'">
  44                 <TeXML escape="0">
  45                     \usepackage{morefloats}
  46                 </TeXML>
  47             </xsl:when>
  48             <xsl:when test="@morefloats = 'none'" />
  49             <xsl:otherwise>
  50                 <TeXML escape="0">
  51                     \IfFileExists{morefloats.sty}{
  52                         \usepackage{morefloats}
  53                     }{}
  54                 </TeXML>
  55             </xsl:otherwise>
  56         </xsl:choose>
  57
  58         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  59         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  60
  61         <env name="document">
  62             <xsl:if test="@data-cover-width">
  63                 <cmd name="makecover">
  64                     <parm><xsl:value-of select="210 * @data-cover-width div @data-cover-height" />mm</parm>
  65                     <parm>210mm</parm>
  66                 </cmd>
  67             </xsl:if>
  68             <cmd name="maketitle" />
  69
  70             <cmd name="tytul"><parm>
  71               <xsl:choose>
  72                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  73                     <!-- title in master -->
  74                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  75                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
  76                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
  77                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
  78                     <!-- dc in master or not -->
  79                     <cmd name="translatorsline" />
  80                 </xsl:when>
  81                 <xsl:otherwise>
  82                     <!-- look for author title in dc -->
  83                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  84                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  85                 </xsl:otherwise>
  86               </xsl:choose>
  87             </parm></cmd>
  88             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  89             <xsl:apply-templates select="utwor" mode="part" />
  90
  91             <TeXML escape="0">
  92                 \def\coverby{
  93                 <xsl:if test="@data-cover-by">Okładka na podstawie:
  94                     <xsl:choose>
  95                     <xsl:when test="@data-cover-source">
  96                         \href{\datacoversource}{\datacoverby}
  97                     </xsl:when>
  98                     <xsl:otherwise>
  99                         \datacoverby{}
 100                     </xsl:otherwise>
 101                     </xsl:choose>
 102                 </xsl:if>
 103                 }
 104             </TeXML>
 105
 106             <cmd name="editorialsection" />
 107         </env>
 108     </TeXML>
 109 </xsl:template>
 110
 111 <xsl:template match="utwor" mode="part">
 112     <cmd name="tytul"><parm>
 113       <xsl:choose>
 114         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
 115             <!-- title in master -->
 116             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
 117             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
 118         </xsl:when>
 119         <xsl:otherwise>
 120             <!-- look for title in dc -->
 121             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 122             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
 123         </xsl:otherwise>
 124       </xsl:choose>
 125     </parm></cmd>
 126
 127     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 128     <xsl:apply-templates select="utwor" mode="part" />
 129 </xsl:template>
 130
 131 <!-- =================== -->
 132 <!-- = MAIN TITLE PAGE = -->
 133 <!-- = (from DC)       = -->
 134 <!-- =================== -->
 135
 136 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
 137     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
 138 </xsl:template>
 139
 140 <xsl:template match="rdf:RDF" mode="titlepage">
 141     <TeXML escape="0">
 142         \def\authors{<xsl:call-template name="authors" />}
 143         \author{\authors}
 144         \title{<xsl:apply-templates select=".//dc:title" mode="inline" />}
 145         \def\translatorsline{<xsl:call-template name="translators" />}
 146
 147         \def\bookurl{<xsl:value-of select=".//dc:identifier.url" />}
 148
 149         \def\rightsinfo{Ten utwór nie jest chroniony prawem autorskim i~znajduje się w~domenie
 150             publicznej, co oznacza że możesz go swobodnie wykorzystywać, publikować
 151             i~rozpowszechniać. Jeśli utwór opatrzony jest dodatkowymi materiałami
 152             (przypisy, motywy literackie etc.), które podlegają prawu autorskiemu, to
 153             te dodatkowe materiały udostępnione są na licencji
 154             \href{http://creativecommons.org/licenses/by-sa/3.0/}{Creative Commons
 155             Uznanie Autorstwa – Na Tych Samych Warunkach 3.0 PL}.}
 156         <xsl:if test=".//dc:rights.license">
 157             \def\rightsinfo{Ten utwór jest udostepniony na licencji
 158             \href{<xsl:value-of select=".//dc:rights.license" />}{<xsl:value-of select=".//dc:rights" />}.}
 159         </xsl:if>
 160
 161         \def\sourceinfo{
 162             <xsl:if test=".//dc:source">
 163                 Tekst opracowany na podstawie: <xsl:apply-templates select=".//dc:source" mode="inline" />
 164                 \vspace{.6em}
 165             </xsl:if>}
 166         \def\description{<xsl:apply-templates select=".//dc:description" mode="inline" />}
 167         \def\editors{<xsl:call-template name="editors" />}
 168     </TeXML>
 169 </xsl:template>
 170
 171
 172 <!-- ============== -->
 173 <!-- = BOOK TITLE = -->
 174 <!-- = (from DC)  = -->
 175 <!-- ============== -->
 176
 177 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
 178     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 179 </xsl:template>
 180
 181 <xsl:template match="rdf:RDF" mode="dctitle">
 182     <cmd name="nazwapodutworu"><parm>
 183         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 184     </parm></cmd>
 185 </xsl:template>
 186
 187 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
 188     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
 189 </xsl:template>
 190
 191 <xsl:template match="rdf:RDF" mode="firstdctitle">
 192     <cmd name="autorutworu"><parm><cmd name="authors"/></parm></cmd>
 193     <cmd name="nazwautworu"><parm>
 194         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 195     </parm></cmd>
 196     <cmd name="translatorsline" />
 197 </xsl:template>
 198
 199
 200 <!-- ============================================================================== -->
 201 <!-- = MASTER TAG                                                                 = -->
 202 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 203 <!-- ============================================================================== -->
 204 <!-- ==================================================================================== -->
 205 <!-- = BLOCK TAGS                                                                       = -->
 206 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 207 <!-- ==================================================================================== -->
 208
 209 <xsl:template
 210     match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny|nota|dedykacja|dlugi_cytat|poezja_cyt|motto">
 211     <cmd>
 212         <xsl:attribute name="name">
 213             <xsl:value-of select="wl:texcommand(name())" />
 214         </xsl:attribute>
 215         <parm><xsl:apply-templates/></parm>
 216     </cmd>
 217 </xsl:template>
 218
 219 <xsl:template match="lista_osob">
 220     <cmd name="listaosob">
 221         <parm><xsl:apply-templates select="naglowek_listy" /></parm>
 222         <parm><xsl:apply-templates select="lista_osoba" /></parm>
 223     </cmd>
 224 </xsl:template>
 225
 226 <xsl:template match="kwestia">
 227     <cmd name="kwestia">
 228         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 229     </cmd>
 230 </xsl:template>
 231
 232
 233 <!-- ========================================== -->
 234 <!-- = PARAGRAPH TAGS                         = -->
 235 <!-- = (can contain inline and special tags)  = -->
 236 <!-- ========================================== -->
 237
 238 <!-- only in root -->
 239 <xsl:template
 240     match="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul"
 241     mode="title">
 242     <cmd>
 243         <xsl:attribute name="name">
 244             <xsl:value-of select="wl:texcommand(name())" />
 245         </xsl:attribute>
 246         <parm><xsl:apply-templates mode="inline"/></parm>
 247     </cmd>
 248 </xsl:template>
 249
 250
 251 <xsl:template
 252     match="naglowek_akt|naglowek_czesc|srodtytul|naglowek_osoba|naglowek_podrozdzial|naglowek_scena|naglowek_rozdzial|miejsce_czas|didaskalia|lista_osoba|akap|akap_dialog|akap_cd|motto_podpis|naglowek_listy">
 253     <cmd>
 254         <xsl:attribute name="name">
 255             <xsl:value-of select="wl:texcommand(name())" />
 256         </xsl:attribute>
 257         <parm><xsl:apply-templates mode="inline"/></parm>
 258     </cmd>
 259 </xsl:template>
 260
 261 <xsl:template match="strofa">
 262   <cmd name="strofa"><parm>
 263     <xsl:choose>
 264         <xsl:when test="count(br) > 0">
 265             <xsl:call-template name="verse">
 266                 <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 267                 <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd'][1]" />
 268             </xsl:call-template>
 269             <xsl:for-each select="br">
 270                 <TeXML escape="0">\\{}</TeXML>
 271                 <!-- Each BR tag "consumes" text after it -->
 272                 <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 273                 <xsl:call-template name="verse">
 274                     <xsl:with-param name="verse-content"
 275                         select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 276                     <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd')][1]" />
 277                 </xsl:call-template>
 278             </xsl:for-each>
 279         </xsl:when>
 280         <xsl:otherwise>
 281             <xsl:call-template name="verse">
 282                 <xsl:with-param name="verse-content" select="text() | node()" />
 283                 <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd[1]" />
 284             </xsl:call-template>
 285         </xsl:otherwise>
 286     </xsl:choose>
 287   </parm></cmd>
 288 </xsl:template>
 289
 290
 291 <xsl:template name="verse">
 292     <xsl:param name="verse-content" />
 293     <xsl:param name="verse-type" />
 294
 295     <cmd>
 296         <xsl:attribute name="name">
 297             <xsl:choose>
 298                 <xsl:when test="$verse-type != ''">
 299                     <xsl:value-of select='wl:texcommand(name($verse-type))' />
 300                 </xsl:when>
 301                 <xsl:otherwise>wers</xsl:otherwise>
 302             </xsl:choose>
 303         </xsl:attribute>
 304         <xsl:if test="string($verse-content/@typ)">
 305             <opt><xsl:value-of select="$verse-content/@typ" />em</opt>
 306         </xsl:if>
 307         <parm><xsl:apply-templates select="$verse-content" mode="inline"/></parm>
 308     </cmd>
 309 </xsl:template>
 310
 311 <!-- ================================================ -->
 312 <!-- = INLINE TAGS                                  = -->
 313 <!-- = (contain other inline tags and special tags) = -->
 314 <!-- ================================================ -->
 315
 316 <xsl:template mode="inline"
 317     match="pa|pe|pr|pt|mat|didask_tekst|slowo_obce|wyroznienie|osoba">
 318     <cmd>
 319         <xsl:attribute name="name">
 320             <xsl:value-of select="wl:texcommand(name())" />
 321         </xsl:attribute>
 322         <parm><xsl:apply-templates mode="inline"/></parm>
 323     </cmd>
 324 </xsl:template>
 325
 326
 327
 328 <xsl:template match="tytul_dziela" mode="inline">
 329     <cmd name="tytuldziela"><parm>
 330         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 331     </parm></cmd>
 332 </xsl:template>
 333
 334
 335
 336 <!-- ============================================== -->
 337 <!-- = STANDALONE TAGS                            = -->
 338 <!-- = (cannot contain any other tags)            = -->
 339 <!-- ============================================== -->
 340 <xsl:template
 341     match="sekcja_swiatlo|sekcja_asterysk|separator_linia">
 342     <cmd>
 343         <xsl:attribute name="name">
 344             <xsl:value-of select="wl:texcommand(name())" />
 345         </xsl:attribute>
 346     </cmd>
 347 </xsl:template>
 348
 349
 350 <!-- ================ -->
 351 <!-- = SPECIAL TAGS = -->
 352 <!-- ================ -->
 353 <!-- Themes -->
 354
 355
 356 <xsl:template match="begin|end|motyw">
 357     <xsl:apply-templates select='.' mode="inline" />
 358 </xsl:template>
 359
 360 <xsl:template match="begin" mode="inline" />
 361 <xsl:template match="end" mode="inline" />
 362
 363 <xsl:template match="motyw" mode="inline">
 364     <cmd name="motyw">
 365         <xsl:if test="@moved">
 366             <opt name="moved"><xsl:value-of select="@moved" /></opt>
 367         </xsl:if>
 368         <parm><xsl:apply-templates mode="inline" /></parm>
 369     </cmd>
 370 </xsl:template>
 371
 372 <xsl:template name="authors">
 373     <xsl:for-each select=".//dc:creator_parsed">
 374         <xsl:if test="position() != 1">, </xsl:if>
 375         <xsl:apply-templates mode="inline" />
 376     </xsl:for-each>
 377 </xsl:template>
 378
 379 <xsl:template name="editors">
 380     <xsl:if test="//dc:contributor.editor_parsed|//dc:contributor.technical_editor_parsed">
 381         <xsl:text>Opracowanie redakcyjne: </xsl:text>
 382         <xsl:for-each select="//dc:contributor.editor_parsed|//dc:contributor.technical_editor_parsed[not(//dc:contributor.editor_parsed/text()=text())]">
 383             <xsl:sort select="@sortkey" />
 384             <xsl:if test="position() != 1">, </xsl:if>
 385             <xsl:apply-templates mode="inline" />
 386         </xsl:for-each>.
 387     </xsl:if>
 388 </xsl:template>
 389
 390 <xsl:template name="translators">
 391     <xsl:if test=".//dc:contributor.translator_parsed">
 392         <cmd name='translator'><parm>
 393             <xsl:for-each select=".//dc:contributor.translator_parsed">
 394                 <xsl:if test="position() != 1">, </xsl:if>
 395                 <xsl:apply-templates mode="inline" />
 396             </xsl:for-each>
 397         </parm></cmd>
 398     </xsl:if>
 399 </xsl:template>
 400
 401
 402 <!-- ============== -->
 403 <!-- = ADDED TAGS = -->
 404 <!-- ============== -->
 405
 406
 407 <xsl:template match="dywiz" mode="inline">
 408     <cmd name="dywiz" />
 409 </xsl:template>
 410
 411 <xsl:template match="nbsp" mode="inline">
 412     <spec cat="tilde" />
 413 </xsl:template>
 414
 415 <xsl:template match="alien" mode="inline">
 416     <group>
 417         <cmd name="alien" />
 418         <xsl:apply-templates mode="inline" />
 419     </group>
 420 </xsl:template>
 421
 422 <!-- ================ -->
 423 <!-- = IGNORED TAGS = -->
 424 <!-- ================ -->
 425 <xsl:template match="extra|uwaga" />
 426 <xsl:template match="extra|uwaga" mode="inline" />
 427
 428 <xsl:template match="nota_red" />
 429
 430 <!-- ======== -->
 431 <!-- = TEXT = -->
 432 <!-- ======== -->
 433 <xsl:template match="text()" />
 434 <xsl:template match="text()" mode="inline">
 435     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 436       <xsl:text> </xsl:text>
 437     </xsl:if>
 438
 439     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 440
 441     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 442       <xsl:text> </xsl:text>
 443     </xsl:if>
 444 </xsl:template>
 445
 446
 447 </xsl:stylesheet>