librarian/pdf/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[<xsl:value-of select="@customizations"/>]{wl}
  19
  20         <!-- flags and values set on root -->
  21
  22         \newif\ifflaglessadvertising
  23         <xsl:for-each select="@*[starts-with(name(), 'flag-')]">
  24             <cmd>
  25                 <xsl:attribute name="name"><xsl:value-of select="wl:texcommand(name())" />true</xsl:attribute>
  26             </cmd>
  27         </xsl:for-each>
  28
  29         <xsl:for-each select="@*[starts-with(name(), 'data-')]">
  30             <TeXML escape="0">
  31                 \def\<xsl:value-of select="wl:texcommand(name())" />{<TeXML escape="1"><xsl:value-of select="."/></TeXML>}
  32             </TeXML>
  33         </xsl:for-each>
  34         </TeXML>
  35
  36         <xsl:choose>
  37             <xsl:when test="@morefloats = 'new'">
  38                 <TeXML escape="0">
  39                     \usepackage[maxfloats=64]{morefloats}
  40                 </TeXML>
  41             </xsl:when>
  42             <xsl:when test="@morefloats = 'old'">
  43                 <TeXML escape="0">
  44                     \usepackage{morefloats}
  45                 </TeXML>
  46             </xsl:when>
  47             <xsl:when test="@morefloats = 'none'" />
  48             <xsl:otherwise>
  49                 <TeXML escape="0">
  50                     \IfFileExists{morefloats.sty}{
  51                         \usepackage{morefloats}
  52                     }{}
  53                 </TeXML>
  54             </xsl:otherwise>
  55         </xsl:choose>
  56
  57         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  58         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  59
  60         <env name="document">
  61             <xsl:if test="@data-cover-width">
  62                 <cmd name="makecover">
  63                     <parm><xsl:value-of select="210 * @data-cover-width div @data-cover-height" />mm</parm>
  64                     <parm>210mm</parm>
  65                 </cmd>
  66             </xsl:if>
  67             <cmd name="maketitle" />
  68
  69             <cmd name="tytul"><parm>
  70               <xsl:choose>
  71                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  72                     <!-- title in master -->
  73                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  74                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
  75                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
  76                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
  77                     <!-- dc in master or not -->
  78                     <cmd name="translatorsline" />
  79                 </xsl:when>
  80                 <xsl:otherwise>
  81                     <!-- look for author title in dc -->
  82                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  83                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  84                 </xsl:otherwise>
  85               </xsl:choose>
  86             </parm></cmd>
  87             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  88             <xsl:apply-templates select="utwor" mode="part" />
  89
  90             <TeXML escape="0">
  91                 \def\coverby{
  92                 <xsl:if test="@data-cover-by">Okładka na podstawie:
  93                     <xsl:choose>
  94                     <xsl:when test="@data-cover-source">
  95                         \href{\datacoversource}{\datacoverby}
  96                     </xsl:when>
  97                     <xsl:otherwise>
  98                         \datacoverby{}
  99                     </xsl:otherwise>
 100                     </xsl:choose>
 101                 </xsl:if>
 102                 }
 103                 \def\editors{<xsl:call-template name="editors" />}
 104             </TeXML>
 105
 106             <cmd name="editorialsection" />
 107
 108         </env>
 109     </TeXML>
 110 </xsl:template>
 111
 112 <xsl:template match="utwor" mode="part">
 113     <cmd name="tytul"><parm>
 114       <xsl:choose>
 115         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
 116             <!-- title in master -->
 117             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
 118             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
 119         </xsl:when>
 120         <xsl:otherwise>
 121             <!-- look for title in dc -->
 122             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 123             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
 124         </xsl:otherwise>
 125       </xsl:choose>
 126     </parm></cmd>
 127
 128     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 129     <xsl:apply-templates select="utwor" mode="part" />
 130 </xsl:template>
 131
 132 <!-- =================== -->
 133 <!-- = MAIN TITLE PAGE = -->
 134 <!-- = (from DC)       = -->
 135 <!-- =================== -->
 136
 137 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
 138     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
 139 </xsl:template>
 140
 141 <xsl:template match="rdf:RDF" mode="titlepage">
 142     <TeXML escape="0">
 143         \def\authors{<xsl:call-template name="authors" />}
 144         \author{\authors}
 145         \title{<xsl:apply-templates select=".//dc:title" mode="inline" />}
 146         \def\translatorsline{<xsl:call-template name="translators" />}
 147
 148         \def\bookurl{<xsl:value-of select=".//dc:identifier.url" />}
 149
 150         \def\rightsinfo{Ten utwór nie jest chroniony prawem autorskim i~znajduje się w~domenie
 151             publicznej, co oznacza że możesz go swobodnie wykorzystywać, publikować
 152             i~rozpowszechniać. Jeśli utwór opatrzony jest dodatkowymi materiałami
 153             (przypisy, motywy literackie etc.), które podlegają prawu autorskiemu, to
 154             te dodatkowe materiały udostępnione są na licencji
 155             \href{http://creativecommons.org/licenses/by-sa/3.0/}{Creative Commons
 156             Uznanie Autorstwa – Na Tych Samych Warunkach 3.0 PL}.}
 157         <xsl:if test=".//dc:rights.license">
 158             \def\rightsinfo{Ten utwór jest udostępniony na licencji\\
 159             \href{<xsl:value-of select=".//dc:rights.license" />}{<TeXML escape="1"><xsl:apply-templates select=".//dc:rights" mode="inline" /></TeXML>}.}
 160         </xsl:if>
 161
 162         \def\sourceinfo{
 163             <xsl:if test=".//dc:source">
 164                 Tekst opracowany na podstawie: <TeXML escape="1"><xsl:apply-templates select=".//dc:source" mode="inline" /></TeXML>
 165                 \vspace{.6em}
 166             </xsl:if>}
 167         \def\description{\raggedright <TeXML escape="1"><xsl:apply-templates select=".//dc:description" mode="inline" /></TeXML>}
 168     </TeXML>
 169 </xsl:template>
 170
 171
 172 <!-- ============== -->
 173 <!-- = BOOK TITLE = -->
 174 <!-- = (from DC)  = -->
 175 <!-- ============== -->
 176
 177 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
 178     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 179 </xsl:template>
 180
 181 <xsl:template match="rdf:RDF" mode="dctitle">
 182     <cmd name="nazwapodutworu"><parm>
 183         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 184     </parm></cmd>
 185 </xsl:template>
 186
 187 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
 188     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
 189 </xsl:template>
 190
 191 <xsl:template match="rdf:RDF" mode="firstdctitle">
 192     <cmd name="autorutworu"><parm><cmd name="authors"/></parm></cmd>
 193     <cmd name="nazwautworu"><parm>
 194         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 195     </parm></cmd>
 196     <cmd name="translatorsline" />
 197 </xsl:template>
 198
 199
 200 <!-- ============================================================================== -->
 201 <!-- = MASTER TAG                                                                 = -->
 202 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 203 <!-- ============================================================================== -->
 204 <!-- ==================================================================================== -->
 205 <!-- = BLOCK TAGS                                                                       = -->
 206 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 207 <!-- ==================================================================================== -->
 208
 209 <xsl:template
 210     match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny|nota|dedykacja|dlugi_cytat|poezja_cyt|motto">
 211     <cmd>
 212         <xsl:attribute name="name">
 213             <xsl:value-of select="wl:texcommand(name())" />
 214         </xsl:attribute>
 215         <parm><xsl:apply-templates/></parm>
 216     </cmd>
 217 </xsl:template>
 218
 219 <xsl:template match="lista_osob">
 220     <cmd name="listaosob">
 221         <parm><xsl:apply-templates select="naglowek_listy" /></parm>
 222         <parm><xsl:apply-templates select="lista_osoba" /></parm>
 223     </cmd>
 224 </xsl:template>
 225
 226 <xsl:template match="kwestia">
 227     <cmd name="kwestia">
 228         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 229     </cmd>
 230 </xsl:template>
 231
 232
 233 <xsl:template match="tabela|tabelka">
 234     <cmd name="par" />
 235     <cmd name="vspace"><parm>1em</parm></cmd>
 236     <group><cmd name="raggedright" />
 237     <env name="tabularx">
 238       <parm><cmd name="textwidth"/></parm>
 239         <xsl:choose>
 240         <xsl:when test="@ramka='1' or @ramki='1'">
 241         <parm><spec cat="vert"/>X<spec cat="vert"/>X<spec cat="vert"/>X<spec cat="vert"/>X<spec cat="vert"/>X<spec cat="vert"/></parm>
 242         <cmd name="hline" />
 243         <xsl:apply-templates mode="wiersze-ramki"/>
 244         </xsl:when>
 245         <xsl:otherwise>
 246         <parm>XXXXX</parm>
 247         <xsl:apply-templates/>
 248         </xsl:otherwise>
 249         </xsl:choose>
 250     </env>
 251     </group>
 252     <cmd name="vspace"><parm>1em</parm></cmd>
 253 </xsl:template>
 254 <xsl:template match="wiersz" mode="wiersze-ramki">
 255     <xsl:apply-templates />
 256     <spec cat="esc"/><spec cat="esc"/>
 257     <cmd name="hline" gr="0" />
 258 </xsl:template>
 259 <xsl:template match="wiersz">
 260     <xsl:apply-templates />
 261     <spec cat="esc"/><spec cat="esc"/>
 262 </xsl:template>
 263
 264 <xsl:template match="kol">
 265     <xsl:apply-templates mode="inline"/>
 266     <xsl:if test="position() &lt; last()">
 267     <spec cat="align"/>
 268     </xsl:if>
 269 </xsl:template>
 270
 271 <xsl:template match="punkt">
 272     <cmd name="punkt"><parm>
 273         <xsl:choose>
 274         <xsl:when test=".//akap">
 275             <xsl:apply-templates />
 276         </xsl:when>
 277         <xsl:otherwise>
 278             <xsl:apply-templates mode="inline"/>
 279         </xsl:otherwise>
 280         </xsl:choose>
 281     </parm></cmd>
 282 </xsl:template>
 283 <xsl:template match="lista">
 284     <xsl:if test="@typ='num'">
 285         <cmd name="listanum">
 286             <parm><xsl:apply-templates /></parm>
 287         </cmd>
 288     </xsl:if>
 289     <xsl:if test="@typ='punkt'">
 290         <cmd name="listapunkt">
 291             <parm><xsl:apply-templates /></parm>
 292         </cmd>
 293     </xsl:if>
 294 </xsl:template>
 295
 296 <xsl:template match="ilustr">
 297     <cmd name="ilustr">
 298         <parm><xsl:value-of select="@src" /></parm>
 299         <parm><xsl:value-of select="@alt" /></parm>
 300     </cmd>
 301 </xsl:template>
 302
 303 <!-- ========================================== -->
 304 <!-- = PARAGRAPH TAGS                         = -->
 305 <!-- = (can contain inline and special tags)  = -->
 306 <!-- ========================================== -->
 307
 308 <!-- only in root -->
 309 <xsl:template
 310     match="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul"
 311     mode="title">
 312     <cmd>
 313         <xsl:attribute name="name">
 314             <xsl:value-of select="wl:texcommand(name())" />
 315         </xsl:attribute>
 316         <parm><xsl:apply-templates mode="inline"/></parm>
 317     </cmd>
 318 </xsl:template>
 319
 320
 321 <xsl:template
 322     match="naglowek_akt|naglowek_czesc|srodtytul|naglowek_osoba|naglowek_podrozdzial|naglowek_scena|naglowek_rozdzial|miejsce_czas|didaskalia|lista_osoba|akap|akap_dialog|akap_cd|motto_podpis|naglowek_listy">
 323     <cmd>
 324         <xsl:attribute name="name">
 325             <xsl:value-of select="wl:texcommand(name())" />
 326         </xsl:attribute>
 327         <parm><xsl:apply-templates mode="inline"/></parm>
 328     </cmd>
 329 </xsl:template>
 330
 331 <xsl:template match="strofa">
 332   <cmd name="strofa"><parm>
 333     <xsl:choose>
 334         <xsl:when test="count(br) > 0">
 335             <xsl:call-template name="verse">
 336                 <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 337                 <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd'][1]" />
 338             </xsl:call-template>
 339             <xsl:for-each select="br">
 340                 <TeXML escape="0">\\{}</TeXML>
 341                 <!-- Each BR tag "consumes" text after it -->
 342                 <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 343                 <xsl:call-template name="verse">
 344                     <xsl:with-param name="verse-content"
 345                         select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 346                     <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd')][1]" />
 347                 </xsl:call-template>
 348             </xsl:for-each>
 349         </xsl:when>
 350         <xsl:otherwise>
 351             <xsl:call-template name="verse">
 352                 <xsl:with-param name="verse-content" select="text() | node()" />
 353                 <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd[1]" />
 354             </xsl:call-template>
 355         </xsl:otherwise>
 356     </xsl:choose>
 357   </parm></cmd>
 358 </xsl:template>
 359
 360
 361 <xsl:template name="verse">
 362     <xsl:param name="verse-content" />
 363     <xsl:param name="verse-type" />
 364
 365     <cmd>
 366         <xsl:attribute name="name">
 367             <xsl:choose>
 368                 <xsl:when test="$verse-type != ''">
 369                     <xsl:value-of select='wl:texcommand(name($verse-type))' />
 370                 </xsl:when>
 371                 <xsl:otherwise>wers</xsl:otherwise>
 372             </xsl:choose>
 373         </xsl:attribute>
 374         <xsl:if test="string($verse-content/@typ)">
 375             <opt><xsl:value-of select="$verse-content/@typ" />em</opt>
 376         </xsl:if>
 377         <parm><xsl:apply-templates select="$verse-content" mode="inline"/></parm>
 378     </cmd>
 379 </xsl:template>
 380
 381 <!-- ================================================ -->
 382 <!-- = INLINE TAGS                                  = -->
 383 <!-- = (contain other inline tags and special tags) = -->
 384 <!-- ================================================ -->
 385
 386 <xsl:template mode="inline"
 387     match="pa|pe|pr|pt|mat|didask_tekst|slowo_obce|wyroznienie|osoba">
 388     <cmd>
 389         <xsl:attribute name="name">
 390             <xsl:value-of select="wl:texcommand(name())" />
 391         </xsl:attribute>
 392         <parm><xsl:apply-templates mode="inline"/></parm>
 393     </cmd>
 394 </xsl:template>
 395
 396 <xsl:template match="www" mode="inline">
 397     <cmd name="href">
 398         <parm><xsl:value-of select="wl:urlquote(text())" /></parm>
 399         <parm><cmd name="url"><parm><xsl:value-of select="text()" /></parm></cmd></parm>
 400     </cmd>
 401 </xsl:template>
 402
 403
 404
 405 <xsl:template match="tytul_dziela" mode="inline">
 406     <cmd name="tytuldziela"><parm>
 407         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 408     </parm></cmd>
 409 </xsl:template>
 410
 411
 412
 413 <!-- ============================================== -->
 414 <!-- = STANDALONE TAGS                            = -->
 415 <!-- = (cannot contain any other tags)            = -->
 416 <!-- ============================================== -->
 417 <xsl:template
 418     match="sekcja_swiatlo|sekcja_asterysk|separator_linia">
 419     <cmd>
 420         <xsl:attribute name="name">
 421             <xsl:value-of select="wl:texcommand(name())" />
 422         </xsl:attribute>
 423     </cmd>
 424 </xsl:template>
 425
 426
 427 <!-- ================ -->
 428 <!-- = SPECIAL TAGS = -->
 429 <!-- ================ -->
 430 <!-- Themes -->
 431
 432
 433 <xsl:template match="begin|end|motyw">
 434     <xsl:apply-templates select='.' mode="inline" />
 435 </xsl:template>
 436
 437 <xsl:template match="begin" mode="inline" />
 438 <xsl:template match="end" mode="inline" />
 439
 440 <xsl:template match="motyw" mode="inline">
 441     <cmd name="motyw">
 442         <xsl:if test="@moved">
 443             <opt name="moved"><xsl:value-of select="@moved" /></opt>
 444         </xsl:if>
 445         <parm><xsl:apply-templates mode="inline" /></parm>
 446     </cmd>
 447 </xsl:template>
 448
 449 <xsl:template name="authors">
 450     <xsl:for-each select=".//dc:creator_parsed">
 451         <xsl:if test="position() != 1">, </xsl:if>
 452         <xsl:apply-templates mode="inline" />
 453     </xsl:for-each>
 454 </xsl:template>
 455
 456 <xsl:template name="editors">
 457     <!--xsl:if test="@editors">
 458         <xsl:text>Opracowanie redakcyjne i przypisy: </xsl:text>
 459         <xsl:value-of select="@editors" />
 460         <xsl:text>.</xsl:text>
 461     </xsl:if-->
 462     <xsl:if test=".//dc:contributor.editor_parsed">
 463     <cmd name="par"><parm>Redakcja literacka:
 464     <xsl:for-each select=".//dc:contributor.editor_parsed">
 465         <xsl:if test="position() != 1">, </xsl:if>
 466         <xsl:apply-templates mode="inline" />
 467     </xsl:for-each>
 468     </parm></cmd>
 469     </xsl:if>
 470     <xsl:if test=".//dc:contributor.technical_editor_parsed">
 471     <cmd name="par"><parm>Redakcja techniczna:
 472     <xsl:for-each select=".//dc:contributor.technical_editor_parsed">
 473         <xsl:if test="position() != 1">, </xsl:if>
 474         <xsl:apply-templates mode="inline" />
 475     </xsl:for-each>
 476     </parm></cmd>
 477     </xsl:if>
 478
 479
 480 </xsl:template>
 481
 482 <xsl:template name="translators">
 483     <xsl:if test=".//dc:contributor.translator_parsed">
 484         <cmd name='translator'><parm>
 485             <xsl:for-each select=".//dc:contributor.translator_parsed">
 486                 <xsl:if test="position() != 1">, </xsl:if>
 487                 <xsl:apply-templates mode="inline" />
 488             </xsl:for-each>
 489         </parm></cmd>
 490     </xsl:if>
 491 </xsl:template>
 492
 493
 494 <!-- ============== -->
 495 <!-- = ADDED TAGS = -->
 496 <!-- ============== -->
 497
 498
 499 <xsl:template match="dywiz" mode="inline">
 500     <cmd name="dywiz" />
 501 </xsl:template>
 502
 503 <xsl:template match="nbsp" mode="inline">
 504     <spec cat="tilde" />
 505 </xsl:template>
 506
 507 <xsl:template match="alien" mode="inline">
 508     <group>
 509         <cmd name="alien" />
 510         <xsl:apply-templates mode="inline" />
 511     </group>
 512 </xsl:template>
 513
 514
 515
 516 <!-- ================ -->
 517 <!-- = IGNORED TAGS = -->
 518 <!-- ================ -->
 519 <xsl:template match="extra|uwaga" />
 520 <xsl:template match="extra|uwaga" mode="inline" />
 521
 522 <xsl:template match="nota_red" />
 523
 524 <!-- ======== -->
 525 <!-- = TEXT = -->
 526 <!-- ======== -->
 527 <xsl:template match="text()" />
 528 <xsl:template match="text()" mode="inline">
 529     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 530       <xsl:text> </xsl:text>
 531     </xsl:if>
 532
 533     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 534
 535     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 536       <xsl:text> </xsl:text>
 537     </xsl:if>
 538 </xsl:template>
 539
 540
 541 </xsl:stylesheet>