librarian/pdf/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[<xsl:value-of select="@customizations"/>]{<xsl:value-of select="@documentclass"/>}
  19
  20         <!-- flags and values set on root -->
  21
  22         \newif\ifflaglessadvertising
  23         <xsl:for-each select="@*[starts-with(name(), 'flag-')]">
  24             <cmd>
  25                 <xsl:attribute name="name"><xsl:value-of select="wl:texcommand(name())" />true</xsl:attribute>
  26             </cmd>
  27         </xsl:for-each>
  28
  29         <xsl:for-each select="@*[starts-with(name(), 'data-')]">
  30             <TeXML escape="0">
  31                 \def\<xsl:value-of select="wl:texcommand(name())" />{<TeXML escape="1"><xsl:value-of select="."/></TeXML>}
  32             </TeXML>
  33         </xsl:for-each>
  34         </TeXML>
  35
  36         <xsl:choose>
  37             <xsl:when test="@morefloats = 'new'">
  38                 <TeXML escape="0">
  39                     \usepackage[maxfloats=64]{morefloats}
  40                 </TeXML>
  41             </xsl:when>
  42             <xsl:when test="@morefloats = 'old'">
  43                 <TeXML escape="0">
  44                     \usepackage{morefloats}
  45                 </TeXML>
  46             </xsl:when>
  47             <xsl:when test="@morefloats = 'none'" />
  48             <xsl:otherwise>
  49                 <TeXML escape="0">
  50                     \IfFileExists{morefloats.sty}{
  51                         \usepackage{morefloats}
  52                     }{}
  53                 </TeXML>
  54             </xsl:otherwise>
  55         </xsl:choose>
  56
  57         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  58         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  59
  60         <env name="document">
  61             <TeXML escape="0">
  62                 \def\thankyou{%
  63                 <xsl:choose>
  64                 <xsl:when test="//dc:contributor">Thank you for your contribution, <xsl:value-of select="//dc:contributor"/>!</xsl:when>
  65                 <xsl:otherwise>Thank you for all your contributions!</xsl:otherwise>
  66                 </xsl:choose>
  67                 }
  68             </TeXML>
  69
  70             <xsl:if test="@data-cover-width">
  71                 <cmd name="makecover">
  72                     <parm>210mm</parm>
  73                     <parm><xsl:value-of select="210 * @data-cover-height div @data-cover-width" />mm</parm>
  74                 </cmd>
  75             </xsl:if>
  76             <!--cmd name="maketitle" /-->
  77
  78             <!--cmd name="tytul"><parm>
  79               <xsl:choose>
  80                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  81                     <!- title in master ->
  82                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  83                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
  84                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
  85                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
  86                     <!- dc in master or not ->
  87                     <cmd name="translatorsline" />
  88                 </xsl:when>
  89                 <xsl:otherwise>
  90                     <!- look for author title in dc ->
  91                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  92                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  93                 </xsl:otherwise>
  94               </xsl:choose>
  95             </parm></cmd-->
  96
  97             <TeXML escape="0">
  98                 \def\coverby{
  99                 <xsl:if test="@data-cover-by">Obraz na okładce:
 100                     <xsl:choose>
 101                     <xsl:when test="@data-cover-source">
 102                         \href{\datacoversource}{\datacoverby}.
 103                     </xsl:when>
 104                     <xsl:otherwise>
 105                         \datacoverby{}.
 106                     </xsl:otherwise>
 107                     </xsl:choose>
 108                 </xsl:if>
 109                 }
 110             </TeXML>
 111
 112             <cmd name="editorialsection" />
 113
 114             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 115             <xsl:apply-templates select="utwor" mode="part" />
 116         </env>
 117     </TeXML>
 118 </xsl:template>
 119
 120 <xsl:template match="utwor" mode="part">
 121     <cmd name="newpage" />
 122     <cmd name="tytul"><parm>
 123
 124     <!-- Dirty! -->
 125     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/motyw" mode="inline"/>
 126
 127       <xsl:choose>
 128         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
 129             <!-- title in master -->
 130             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
 131             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
 132             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
 133             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
 134         </xsl:when>
 135         <xsl:otherwise>
 136             <!-- look for title in dc -->
 137             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 138             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
 139         </xsl:otherwise>
 140       </xsl:choose>
 141     </parm></cmd>
 142
 143     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 144     <xsl:apply-templates select="utwor" mode="part" />
 145 </xsl:template>
 146
 147 <!-- =================== -->
 148 <!-- = MAIN TITLE PAGE = -->
 149 <!-- = (from DC)       = -->
 150 <!-- =================== -->
 151
 152 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
 153     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
 154 </xsl:template>
 155
 156 <xsl:template match="rdf:RDF" mode="titlepage">
 157     <TeXML escape="0">
 158         \def\authors{<xsl:call-template name="authors" />}
 159         \author{\authors}
 160         \title{<xsl:apply-templates select=".//dc:title" mode="inline" />}
 161         \makeatletter
 162         \let\theauthor\@author
 163         \let\thetitle\@title
 164         \makeatother
 165
 166         \def\translatorsline{<xsl:call-template name="translators" />}
 167
 168         \def\bookurl{<xsl:value-of select=".//dc:identifier.url" />}
 169
 170         \def\rightsinfo{Ten utwór nie jest chroniony prawem autorskim i~znajduje się w~domenie
 171             publicznej, co oznacza że możesz go swobodnie wykorzystywać, publikować
 172             i~rozpowszechniać. Jeśli utwór opatrzony jest dodatkowymi materiałami
 173             (przypisy, motywy literackie etc.), które podlegają prawu autorskiemu, to
 174             te dodatkowe materiały udostępnione są na licencji
 175             \href{http://creativecommons.org/licenses/by-sa/3.0/}{Creative Commons
 176             Uznanie Autorstwa – Na Tych Samych Warunkach 3.0 PL}.}
 177         <xsl:if test=".//dc:rights.license">
 178             \def\rightsinfo{Ta książka jest udostpęniona na licencji
 179             \href{<xsl:value-of select=".//dc:rights.license" />}{<xsl:value-of select=".//dc:rights" />}.}
 180         </xsl:if>
 181
 182         \def\sourceinfo{
 183             <xsl:if test=".//dc:source">
 184                 Tekst opracowany na podstawie: <xsl:apply-templates select=".//dc:source" mode="inline" />
 185                 \vspace{.6em}
 186             </xsl:if>}
 187         \def\description{<xsl:apply-templates select=".//dc:description" mode="inline" />}
 188         \def\editors{<xsl:call-template name="editors" />}
 189     </TeXML>
 190 </xsl:template>
 191
 192
 193 <!-- ============== -->
 194 <!-- = BOOK TITLE = -->
 195 <!-- = (from DC)  = -->
 196 <!-- ============== -->
 197
 198 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
 199     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 200 </xsl:template>
 201
 202 <xsl:template match="rdf:RDF" mode="dctitle">
 203     <cmd name="nazwapodutworu"><parm>
 204         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 205     </parm></cmd>
 206 </xsl:template>
 207
 208 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
 209     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
 210 </xsl:template>
 211
 212 <xsl:template match="rdf:RDF" mode="firstdctitle">
 213     <cmd name="autorutworu"><parm><cmd name="authors"/></parm></cmd>
 214     <cmd name="nazwautworu"><parm>
 215         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 216     </parm></cmd>
 217     <cmd name="translatorsline" />
 218 </xsl:template>
 219
 220
 221 <!-- ============================================================================== -->
 222 <!-- = MASTER TAG                                                                 = -->
 223 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 224 <!-- ============================================================================== -->
 225 <!-- ==================================================================================== -->
 226 <!-- = BLOCK TAGS                                                                       = -->
 227 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 228 <!-- ==================================================================================== -->
 229
 230 <xsl:template
 231     match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny|nota|dedykacja|dlugi_cytat|poezja_cyt|motto">
 232     <cmd>
 233         <xsl:attribute name="name">
 234             <xsl:value-of select="wl:texcommand(name())" />
 235         </xsl:attribute>
 236         <parm><xsl:apply-templates/></parm>
 237     </cmd>
 238 </xsl:template>
 239
 240 <xsl:template match="lista_osob">
 241     <cmd name="listaosob">
 242         <parm><xsl:apply-templates select="naglowek_listy" /></parm>
 243         <parm><xsl:apply-templates select="lista_osoba" /></parm>
 244     </cmd>
 245 </xsl:template>
 246
 247 <xsl:template match="kwestia">
 248     <cmd name="kwestia">
 249         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 250     </cmd>
 251 </xsl:template>
 252
 253
 254 <!-- ========================================== -->
 255 <!-- = PARAGRAPH TAGS                         = -->
 256 <!-- = (can contain inline and special tags)  = -->
 257 <!-- ========================================== -->
 258
 259 <!-- only in root -->
 260 <xsl:template
 261     match="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul"
 262     mode="title">
 263     <cmd>
 264         <xsl:attribute name="name">
 265             <xsl:value-of select="wl:texcommand(name())" />
 266         </xsl:attribute>
 267         <parm><xsl:apply-templates mode="inline"/></parm>
 268     </cmd>
 269 </xsl:template>
 270
 271
 272 <xsl:template
 273     match="naglowek_akt|naglowek_czesc|srodtytul|naglowek_osoba|naglowek_podrozdzial|naglowek_scena|autor_rozdzialu|naglowek_rozdzial|miejsce_czas|didaskalia|lista_osoba|akap|akap_dialog|akap_cd|motto_podpis|naglowek_listy|lista">
 274     <cmd>
 275         <xsl:attribute name="name">
 276             <xsl:value-of select="wl:texcommand(name())" />
 277         </xsl:attribute>
 278         <parm><xsl:apply-templates mode="inline"/></parm>
 279     </cmd>
 280 </xsl:template>
 281
 282 <xsl:template match="strofa">
 283   <cmd name="strofa"><parm>
 284     <xsl:choose>
 285         <xsl:when test="count(br) > 0">
 286             <xsl:call-template name="verse">
 287                 <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 288                 <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd'][1]" />
 289             </xsl:call-template>
 290             <xsl:for-each select="br">
 291                 <TeXML escape="0">\\{}</TeXML>
 292                 <!-- Each BR tag "consumes" text after it -->
 293                 <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 294                 <xsl:call-template name="verse">
 295                     <xsl:with-param name="verse-content"
 296                         select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 297                     <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd')][1]" />
 298                 </xsl:call-template>
 299             </xsl:for-each>
 300         </xsl:when>
 301         <xsl:otherwise>
 302             <xsl:call-template name="verse">
 303                 <xsl:with-param name="verse-content" select="text() | node()" />
 304                 <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd[1]" />
 305             </xsl:call-template>
 306         </xsl:otherwise>
 307     </xsl:choose>
 308   </parm></cmd>
 309 </xsl:template>
 310
 311
 312 <xsl:template match="link">
 313   <cmd name="link">
 314     <parm><xsl:value-of select="@url"/></parm>
 315     <parm><xsl:apply-templates mode="inline"/></parm>
 316   </cmd>
 317 </xsl:template>
 318
 319
 320 <xsl:template name="verse">
 321     <xsl:param name="verse-content" />
 322     <xsl:param name="verse-type" />
 323
 324     <cmd>
 325         <xsl:attribute name="name">
 326             <xsl:choose>
 327                 <xsl:when test="$verse-type != ''">
 328                     <xsl:value-of select='wl:texcommand(name($verse-type))' />
 329                 </xsl:when>
 330                 <xsl:otherwise>wers</xsl:otherwise>
 331             </xsl:choose>
 332         </xsl:attribute>
 333         <xsl:if test="string($verse-content/@typ)">
 334             <opt><xsl:value-of select="$verse-content/@typ" />em</opt>
 335         </xsl:if>
 336         <parm><xsl:apply-templates select="$verse-content" mode="inline"/></parm>
 337     </cmd>
 338 </xsl:template>
 339
 340 <!-- ================================================ -->
 341 <!-- = INLINE TAGS                                  = -->
 342 <!-- = (contain other inline tags and special tags) = -->
 343 <!-- ================================================ -->
 344
 345 <xsl:template mode="inline"
 346     match="pa|pe|pr|pt|mat|didask_tekst|slowo_obce|wyroznienie|osoba|punkt|www">
 347     <cmd>
 348         <xsl:attribute name="name">
 349             <xsl:value-of select="wl:texcommand(name())" />
 350         </xsl:attribute>
 351         <parm><xsl:apply-templates mode="inline"/></parm>
 352     </cmd>
 353 </xsl:template>
 354
 355
 356
 357 <xsl:template match="tytul_dziela" mode="inline">
 358     <cmd name="tytuldziela"><parm>
 359         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 360     </parm></cmd>
 361 </xsl:template>
 362
 363
 364
 365 <!-- ============================================== -->
 366 <!-- = STANDALONE TAGS                            = -->
 367 <!-- = (cannot contain any other tags)            = -->
 368 <!-- ============================================== -->
 369 <xsl:template
 370     match="sekcja_swiatlo|sekcja_asterysk|separator_linia">
 371     <cmd>
 372         <xsl:attribute name="name">
 373             <xsl:value-of select="wl:texcommand(name())" />
 374         </xsl:attribute>
 375     </cmd>
 376 </xsl:template>
 377
 378 <xsl:strip-space elements="ilustr"/>
 379 <xsl:template match="ilustr">
 380     <cmd>
 381         <xsl:attribute name="name">
 382             <xsl:value-of select="wl:texcommand(name())" />
 383         </xsl:attribute>
 384         <parm><TeXML escape="0"><xsl:value-of select="normalize-space(@src)" /></TeXML></parm>
 385         <parm><xsl:apply-templates mode="inline" /></parm>
 386     </cmd>
 387 </xsl:template>
 388
 389 <xsl:template match="@*|node()" mode="identity">
 390   <xsl:copy>
 391     <xsl:apply-templates select="@*|node()" mode="identity"/>
 392   </xsl:copy>
 393 </xsl:template>
 394
 395
 396
 397 <xsl:template match="dmath">
 398   <dmath>
 399     <xsl:apply-templates mode="identity"/>
 400   </dmath>
 401 </xsl:template>
 402
 403 <xsl:template match="math" mode="inline">
 404   <math>
 405     <xsl:apply-templates mode="identity"/>
 406   </math>
 407 </xsl:template>
 408
 409 <xsl:template match="latex" mode="inline">
 410   <TeXML escape="0">
 411     <xsl:apply-templates select="@*|node()" mode="identity"/>
 412   </TeXML>
 413 </xsl:template>
 414
 415 <xsl:template match="tablewrap">
 416   <cmd name="begin"><parm>table</parm><opt>h!</opt></cmd>
 417   <xsl:apply-templates select="table"/>
 418
 419   <cmd name="caption*"><parm>
 420     <xsl:apply-templates select="akap"/>
 421   </parm></cmd>
 422   <cmd name="end"><parm>table</parm></cmd>
 423 </xsl:template>
 424
 425 <xsl:template match="table">
 426   <xsl:if test="@caption">
 427
 428       <cmd name="caption*"><parm>
 429
 430         <cmd name="Large"/><xsl:value-of select="@caption"/>
 431       </parm></cmd>
 432     </xsl:if>
 433     <env name="tabularx">
 434       <parm><cmd name="textwidth"/></parm>
 435         <parm><xsl:value-of select="@spec"/></parm>
 436         <xsl:apply-templates />
 437     </env>
 438 </xsl:template>
 439
 440 <xsl:template match="r">
 441     <xsl:apply-templates />
 442     <spec cat="esc"/><spec cat="esc"/>
 443 </xsl:template>
 444 <xsl:template match="c">
 445     <cmd name="footnotesize"/>
 446     <xsl:apply-templates mode="inline"/>
 447     <xsl:if test="position() &lt; last()-1">
 448     <spec cat="align"/>
 449     </xsl:if>
 450 </xsl:template>
 451 <xsl:template match="hr">
 452   <cmd name="hline"/>
 453 </xsl:template>
 454
 455 <!-- ================ -->
 456 <!-- = SPECIAL TAGS = -->
 457 <!-- ================ -->
 458 <!-- Themes -->
 459
 460
 461 <xsl:template match="begin|end|motyw">
 462     <xsl:apply-templates select='.' mode="inline" />
 463 </xsl:template>
 464
 465 <xsl:template match="begin" mode="inline" />
 466 <xsl:template match="end" mode="inline" />
 467
 468 <xsl:template match="motyw" mode="inline">
 469     <cmd name="motyw">
 470         <xsl:if test="@moved">
 471             <opt name="moved"><xsl:value-of select="@moved" /></opt>
 472         </xsl:if>
 473         <parm><xsl:apply-templates mode="inline" /></parm>
 474     </cmd>
 475 </xsl:template>
 476
 477 <xsl:template name="authors">
 478     <xsl:for-each select=".//dc:creator_parsed">
 479         <xsl:if test="position() != 1">, </xsl:if>
 480         <xsl:apply-templates mode="inline" />
 481     </xsl:for-each>
 482 </xsl:template>
 483
 484 <xsl:template name="editors">
 485     <xsl:if test=".//dc:contributor.editor_parsed|.//dc:contributor.technical_editor_parsed">
 486         <xsl:text>Redakcja techniczna: </xsl:text>
 487         <xsl:for-each select=".//dc:contributor.editor_parsed|.//dc:contributor.technical_editor_parsed[not(.//dc:contributor.editor_parsed/text()=text())]">
 488             <!--xsl:sort select="@sortkey" /-->
 489             <xsl:if test="position() != 1">, </xsl:if>
 490             <xsl:apply-templates mode="inline" />
 491         </xsl:for-each>.
 492     </xsl:if>
 493 </xsl:template>
 494
 495 <xsl:template name="translators">
 496     <xsl:if test=".//dc:contributor.translator_parsed">
 497         <cmd name='translator'><parm>
 498             <xsl:for-each select=".//dc:contributor.translator_parsed">
 499                 <xsl:if test="position() != 1">, </xsl:if>
 500                 <xsl:apply-templates mode="inline" />
 501             </xsl:for-each>
 502         </parm></cmd>
 503     </xsl:if>
 504 </xsl:template>
 505
 506
 507 <!-- ============== -->
 508 <!-- = ADDED TAGS = -->
 509 <!-- ============== -->
 510
 511
 512 <xsl:template match="dywiz" mode="inline">
 513     <cmd name="dywiz" />
 514 </xsl:template>
 515
 516 <xsl:template match="nbsp" mode="inline">
 517     <spec cat="tilde" />
 518 </xsl:template>
 519
 520 <xsl:template match="alien" mode="inline">
 521     <group>
 522         <cmd name="alien" />
 523         <xsl:apply-templates mode="inline" />
 524     </group>
 525 </xsl:template>
 526
 527 <!-- ================ -->
 528 <!-- = IGNORED TAGS = -->
 529 <!-- ================ -->
 530 <xsl:template match="extra|uwaga" />
 531 <xsl:template match="extra|uwaga" mode="inline" />
 532
 533 <xsl:template match="nota_red" />
 534
 535 <!-- ======== -->
 536 <!-- = TEXT = -->
 537 <!-- ======== -->
 538 <xsl:template match="text()" />
 539 <xsl:template match="text()" mode="inline">
 540     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 541       <xsl:text> </xsl:text>
 542     </xsl:if>
 543
 544     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 545
 546     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 547       <xsl:text> </xsl:text>
 548     </xsl:if>
 549 </xsl:template>
 550
 551
 552 </xsl:stylesheet>