librarian/pdf/wl2tex.xslt

   1 <?xml version="1.0" encoding="utf-8"?>
   2 <!--
   3
   4    This file is part of Librarian, licensed under GNU Affero GPLv3 or later.
   5    Copyright © Fundacja Nowoczesna Polska. See NOTICE for more information.
   6
   7 -->
   8 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9     xmlns:wl="http://wolnelektury.pl/functions"
  10     xmlns:dc="http://purl.org/dc/elements/1.1/"
  11     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" >
  12
  13 <xsl:output encoding="utf-8" indent="yes" version="2.0" />
  14
  15 <xsl:template match="utwor">
  16     <TeXML xmlns="http://getfo.sourceforge.net/texml/ns1">
  17         <TeXML escape="0">
  18         \documentclass[<xsl:value-of select="@customizations"/>]{wl}
  19
  20         <!-- flags and values set on root -->
  21
  22         \newif\ifflaglessadvertising
  23         <xsl:for-each select="@*[starts-with(name(), 'flag-')]">
  24             <cmd>
  25                 <xsl:attribute name="name"><xsl:value-of select="wl:texcommand(name())" />true</xsl:attribute>
  26             </cmd>
  27         </xsl:for-each>
  28
  29         <xsl:for-each select="@*[starts-with(name(), 'data-')]">
  30             <TeXML escape="0">
  31                 \def\<xsl:value-of select="wl:texcommand(name())" />{<TeXML escape="1"><xsl:value-of select="."/></TeXML>}
  32             </TeXML>
  33         </xsl:for-each>
  34         </TeXML>
  35
  36         <xsl:choose>
  37             <xsl:when test="@morefloats = 'new'">
  38                 <TeXML escape="0">
  39                     \usepackage[maxfloats=64]{morefloats}
  40                 </TeXML>
  41             </xsl:when>
  42             <xsl:when test="@morefloats = 'old'">
  43                 <TeXML escape="0">
  44                     \usepackage{morefloats}
  45                 </TeXML>
  46             </xsl:when>
  47             <xsl:when test="@morefloats = 'none'" />
  48             <xsl:otherwise>
  49                 <TeXML escape="0">
  50                     \IfFileExists{morefloats.sty}{
  51                         \usepackage{morefloats}
  52                     }{}
  53                 </TeXML>
  54             </xsl:otherwise>
  55         </xsl:choose>
  56
  57         <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
  58         <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='titlepage' />
  59
  60         <env name="document">
  61             <xsl:if test="@data-cover-width">
  62                 <cmd name="makecover">
  63                     <parm><xsl:value-of select="210 * @data-cover-width div @data-cover-height" />mm</parm>
  64                     <parm>210mm</parm>
  65                 </cmd>
  66             </xsl:if>
  67             <cmd name="maketitle" />
  68
  69             <cmd name="tytul"><parm>
  70               <xsl:choose>
  71                 <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  72                     <!-- title in master -->
  73                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/autor_utworu" mode="title" />
  74                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/dzielo_nadrzedne" mode="title" />
  75                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
  76                     <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
  77                     <!-- dc in master or not -->
  78                     <cmd name="translatorsline" />
  79                 </xsl:when>
  80                 <xsl:otherwise>
  81                     <!-- look for author title in dc -->
  82                     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
  83                     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='firstdctitle' />
  84                 </xsl:otherwise>
  85               </xsl:choose>
  86             </parm></cmd>
  87             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
  88             <xsl:apply-templates select="utwor" mode="part" />
  89             <cmd name="editorialsection" />
  90         </env>
  91     </TeXML>
  92 </xsl:template>
  93
  94 <xsl:template match="utwor" mode="part">
  95     <cmd name="tytul"><parm>
  96       <xsl:choose>
  97         <xsl:when test="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu">
  98             <!-- title in master -->
  99             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/nazwa_utworu" mode="title" />
 100             <xsl:apply-templates select="(powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny)/podtytul" mode="title" />
 101         </xsl:when>
 102         <xsl:otherwise>
 103             <!-- look for title in dc -->
 104             <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 105             <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode='dctitle' />
 106         </xsl:otherwise>
 107       </xsl:choose>
 108     </parm></cmd>
 109
 110     <xsl:apply-templates select="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" />
 111     <xsl:apply-templates select="utwor" mode="part" />
 112 </xsl:template>
 113
 114 <!-- =================== -->
 115 <!-- = MAIN TITLE PAGE = -->
 116 <!-- = (from DC)       = -->
 117 <!-- =================== -->
 118
 119 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="titlepage">
 120     <xsl:apply-templates select="rdf:RDF" mode="titlepage" />
 121 </xsl:template>
 122
 123 <xsl:template match="rdf:RDF" mode="titlepage">
 124     <TeXML escape="0">
 125         \def\authors{<xsl:call-template name="authors" />}
 126         \author{\authors}
 127         \title{<xsl:apply-templates select=".//dc:title" mode="inline" />}
 128         \def\translatorsline{<xsl:call-template name="translators" />}
 129
 130         \def\bookurl{<xsl:value-of select=".//dc:identifier.url" />}
 131
 132         \def\rightsinfo{Ten utwór nie jest chroniony prawem autorskim i~znajduje się w~domenie
 133             publicznej, co oznacza że możesz go swobodnie wykorzystywać, publikować
 134             i~rozpowszechniać. Jeśli utwór opatrzony jest dodatkowymi materiałami
 135             (przypisy, motywy literackie etc.), które podlegają prawu autorskiemu, to
 136             te dodatkowe materiały udostępnione są na licencji
 137             \href{http://creativecommons.org/licenses/by-sa/3.0/}{Creative Commons
 138             Uznanie Autorstwa – Na Tych Samych Warunkach 3.0 PL}.}
 139         <xsl:if test=".//dc:rights.license">
 140             \def\rightsinfo{Ten utwór jest udostepniony na licencji
 141             \href{<xsl:value-of select=".//dc:rights.license" />}{<xsl:value-of select=".//dc:rights" />}.}
 142         </xsl:if>
 143
 144         \def\sourceinfo{
 145             <xsl:if test=".//dc:source">
 146                 Tekst opracowany na podstawie: <xsl:apply-templates select=".//dc:source" mode="inline" />
 147                 \vspace{.6em}
 148             </xsl:if>}
 149         \def\description{<xsl:apply-templates select=".//dc:description" mode="inline" />}
 150         \def\editors{<xsl:call-template name="editors" />}
 151     </TeXML>
 152 </xsl:template>
 153
 154
 155 <!-- ============== -->
 156 <!-- = BOOK TITLE = -->
 157 <!-- = (from DC)  = -->
 158 <!-- ============== -->
 159
 160 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="dctitle">
 161     <xsl:apply-templates select="rdf:RDF" mode="dctitle" />
 162 </xsl:template>
 163
 164 <xsl:template match="rdf:RDF" mode="dctitle">
 165     <cmd name="nazwapodutworu"><parm>
 166         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 167     </parm></cmd>
 168 </xsl:template>
 169
 170 <xsl:template match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny" mode="firstdctitle">
 171     <xsl:apply-templates select="rdf:RDF" mode="firstdctitle" />
 172 </xsl:template>
 173
 174 <xsl:template match="rdf:RDF" mode="firstdctitle">
 175     <cmd name="autorutworu"><parm><cmd name="authors"/></parm></cmd>
 176     <cmd name="nazwautworu"><parm>
 177         <xsl:apply-templates select=".//dc:title/node()" mode="inline" />
 178     </parm></cmd>
 179     <cmd name="translatorsline" />
 180 </xsl:template>
 181
 182
 183 <!-- ============================================================================== -->
 184 <!-- = MASTER TAG                                                                 = -->
 185 <!-- = (can contain block tags, paragraph tags, standalone tags and special tags) = -->
 186 <!-- ============================================================================== -->
 187 <!-- ==================================================================================== -->
 188 <!-- = BLOCK TAGS                                                                       = -->
 189 <!-- = (can contain other block tags, paragraph tags, standalone tags and special tags) = -->
 190 <!-- ==================================================================================== -->
 191
 192 <xsl:template
 193     match="powiesc|opowiadanie|liryka_l|liryka_lp|dramat_wierszowany_l|dramat_wierszowany_lp|dramat_wspolczesny|nota|dedykacja|dlugi_cytat|poezja_cyt|motto">
 194     <cmd>
 195         <xsl:attribute name="name">
 196             <xsl:value-of select="wl:texcommand(name())" />
 197         </xsl:attribute>
 198         <parm><xsl:apply-templates/></parm>
 199     </cmd>
 200 </xsl:template>
 201
 202 <xsl:template match="lista_osob">
 203     <cmd name="listaosob">
 204         <parm><xsl:apply-templates select="naglowek_listy" /></parm>
 205         <parm><xsl:apply-templates select="lista_osoba" /></parm>
 206     </cmd>
 207 </xsl:template>
 208
 209 <xsl:template match="kwestia">
 210     <cmd name="kwestia">
 211         <parm><xsl:apply-templates select="strofa|akap|didaskalia" /></parm>
 212     </cmd>
 213 </xsl:template>
 214
 215
 216 <!-- ========================================== -->
 217 <!-- = PARAGRAPH TAGS                         = -->
 218 <!-- = (can contain inline and special tags)  = -->
 219 <!-- ========================================== -->
 220
 221 <!-- only in root -->
 222 <xsl:template
 223     match="autor_utworu|dzielo_nadrzedne|nazwa_utworu|podtytul"
 224     mode="title">
 225     <cmd>
 226         <xsl:attribute name="name">
 227             <xsl:value-of select="wl:texcommand(name())" />
 228         </xsl:attribute>
 229         <parm><xsl:apply-templates mode="inline"/></parm>
 230     </cmd>
 231 </xsl:template>
 232
 233
 234 <xsl:template
 235     match="naglowek_akt|naglowek_czesc|srodtytul|naglowek_osoba|naglowek_podrozdzial|naglowek_scena|naglowek_rozdzial|miejsce_czas|didaskalia|lista_osoba|akap|akap_dialog|akap_cd|motto_podpis|naglowek_listy">
 236     <cmd>
 237         <xsl:attribute name="name">
 238             <xsl:value-of select="wl:texcommand(name())" />
 239         </xsl:attribute>
 240         <parm><xsl:apply-templates mode="inline"/></parm>
 241     </cmd>
 242 </xsl:template>
 243
 244 <xsl:template match="strofa">
 245   <cmd name="strofa"><parm>
 246     <xsl:choose>
 247         <xsl:when test="count(br) > 0">
 248             <xsl:call-template name="verse">
 249                 <xsl:with-param name="verse-content" select="br[1]/preceding-sibling::text() | br[1]/preceding-sibling::node()" />
 250                 <xsl:with-param name="verse-type" select="br[1]/preceding-sibling::*[name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd'][1]" />
 251             </xsl:call-template>
 252             <xsl:for-each select="br">
 253                 <TeXML escape="0">\\{}</TeXML>
 254                 <!-- Each BR tag "consumes" text after it -->
 255                 <xsl:variable name="lnum" select="count(preceding-sibling::br)" />
 256                 <xsl:call-template name="verse">
 257                     <xsl:with-param name="verse-content"
 258                         select="following-sibling::text()[count(preceding-sibling::br) = $lnum+1] | following-sibling::node()[count(preceding-sibling::br) = $lnum+1]" />
 259                     <xsl:with-param name="verse-type" select="following-sibling::*[count(preceding-sibling::br) = $lnum+1 and (name() = 'wers_wciety' or name() = 'wers_akap' or name() = 'wers_cd')][1]" />
 260                 </xsl:call-template>
 261             </xsl:for-each>
 262         </xsl:when>
 263         <xsl:otherwise>
 264             <xsl:call-template name="verse">
 265                 <xsl:with-param name="verse-content" select="text() | node()" />
 266                 <xsl:with-param name="verse-type" select="wers_wciety|wers_akap|wers_cd[1]" />
 267             </xsl:call-template>
 268         </xsl:otherwise>
 269     </xsl:choose>
 270   </parm></cmd>
 271 </xsl:template>
 272
 273
 274 <xsl:template name="verse">
 275     <xsl:param name="verse-content" />
 276     <xsl:param name="verse-type" />
 277
 278     <cmd>
 279         <xsl:attribute name="name">
 280             <xsl:choose>
 281                 <xsl:when test="$verse-type != ''">
 282                     <xsl:value-of select='wl:texcommand(name($verse-type))' />
 283                 </xsl:when>
 284                 <xsl:otherwise>wers</xsl:otherwise>
 285             </xsl:choose>
 286         </xsl:attribute>
 287         <xsl:if test="string($verse-content/@typ)">
 288             <opt><xsl:value-of select="$verse-content/@typ" />em</opt>
 289         </xsl:if>
 290         <parm><xsl:apply-templates select="$verse-content" mode="inline"/></parm>
 291     </cmd>
 292 </xsl:template>
 293
 294 <!-- ================================================ -->
 295 <!-- = INLINE TAGS                                  = -->
 296 <!-- = (contain other inline tags and special tags) = -->
 297 <!-- ================================================ -->
 298
 299 <xsl:template mode="inline"
 300     match="pa|pe|pr|pt|mat|didask_tekst|slowo_obce|wyroznienie|osoba">
 301     <cmd>
 302         <xsl:attribute name="name">
 303             <xsl:value-of select="wl:texcommand(name())" />
 304         </xsl:attribute>
 305         <parm><xsl:apply-templates mode="inline"/></parm>
 306     </cmd>
 307 </xsl:template>
 308
 309
 310
 311 <xsl:template match="tytul_dziela" mode="inline">
 312     <cmd name="tytuldziela"><parm>
 313         <xsl:if test="@typ = '1'">„</xsl:if><xsl:apply-templates mode="inline" /><xsl:if test="@typ = '1'">”</xsl:if>
 314     </parm></cmd>
 315 </xsl:template>
 316
 317
 318
 319 <!-- ============================================== -->
 320 <!-- = STANDALONE TAGS                            = -->
 321 <!-- = (cannot contain any other tags)            = -->
 322 <!-- ============================================== -->
 323 <xsl:template
 324     match="sekcja_swiatlo|sekcja_asterysk|separator_linia">
 325     <cmd>
 326         <xsl:attribute name="name">
 327             <xsl:value-of select="wl:texcommand(name())" />
 328         </xsl:attribute>
 329     </cmd>
 330 </xsl:template>
 331
 332
 333 <!-- ================ -->
 334 <!-- = SPECIAL TAGS = -->
 335 <!-- ================ -->
 336 <!-- Themes -->
 337
 338
 339 <xsl:template match="begin|end|motyw">
 340     <xsl:apply-templates select='.' mode="inline" />
 341 </xsl:template>
 342
 343 <xsl:template match="begin" mode="inline" />
 344 <xsl:template match="end" mode="inline" />
 345
 346 <xsl:template match="motyw" mode="inline">
 347     <cmd name="motyw">
 348         <xsl:if test="@moved">
 349             <opt name="moved"><xsl:value-of select="@moved" /></opt>
 350         </xsl:if>
 351         <parm><xsl:apply-templates mode="inline" /></parm>
 352     </cmd>
 353 </xsl:template>
 354
 355 <xsl:template name="authors">
 356     <xsl:for-each select=".//dc:creator_parsed">
 357         <xsl:if test="position() != 1">, </xsl:if>
 358         <xsl:apply-templates mode="inline" />
 359     </xsl:for-each>
 360 </xsl:template>
 361
 362 <xsl:template name="editors">
 363     <xsl:if test="//dc:contributor.editor_parsed|//dc:contributor.technical_editor_parsed">
 364         <xsl:text>Opracowanie redakcyjne i przypisy: </xsl:text>
 365         <xsl:for-each select="//dc:contributor.editor_parsed|//dc:contributor.technical_editor_parsed[not(//dc:contributor.editor_parsed/text()=text())]">
 366             <xsl:sort select="@sortkey" />
 367             <xsl:if test="position() != 1">, </xsl:if>
 368             <xsl:apply-templates mode="inline" />
 369         </xsl:for-each>.
 370     </xsl:if>
 371 </xsl:template>
 372
 373 <xsl:template name="translators">
 374     <xsl:if test=".//dc:contributor.translator_parsed">
 375         <cmd name='translator'><parm>
 376             <xsl:for-each select=".//dc:contributor.translator_parsed">
 377                 <xsl:if test="position() != 1">, </xsl:if>
 378                 <xsl:apply-templates mode="inline" />
 379             </xsl:for-each>
 380         </parm></cmd>
 381     </xsl:if>
 382 </xsl:template>
 383
 384
 385 <!-- ============== -->
 386 <!-- = ADDED TAGS = -->
 387 <!-- ============== -->
 388
 389
 390 <xsl:template match="dywiz" mode="inline">
 391     <cmd name="dywiz" />
 392 </xsl:template>
 393
 394 <xsl:template match="nbsp" mode="inline">
 395     <spec cat="tilde" />
 396 </xsl:template>
 397
 398 <xsl:template match="alien" mode="inline">
 399     <group>
 400         <cmd name="alien" />
 401         <xsl:apply-templates mode="inline" />
 402     </group>
 403 </xsl:template>
 404
 405 <!-- ================ -->
 406 <!-- = IGNORED TAGS = -->
 407 <!-- ================ -->
 408 <xsl:template match="extra|uwaga" />
 409 <xsl:template match="extra|uwaga" mode="inline" />
 410
 411 <xsl:template match="nota_red" />
 412
 413 <!-- ======== -->
 414 <!-- = TEXT = -->
 415 <!-- ======== -->
 416 <xsl:template match="text()" />
 417 <xsl:template match="text()" mode="inline">
 418     <xsl:if test="preceding-sibling::node() and wl:starts_white(.)">
 419       <xsl:text> </xsl:text>
 420     </xsl:if>
 421
 422     <xsl:value-of select="wl:substitute_entities(wl:strip(.))" />
 423
 424     <xsl:if test="following-sibling::node() and wl:ends_white(.)">
 425       <xsl:text> </xsl:text>
 426     </xsl:if>
 427 </xsl:template>
 428
 429
 430 </xsl:stylesheet>